lib/Packages/Page.pm

   1 package Packages::Page;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use Exporter;
   8 use Deb::Versions;
   9 use Packages::CGI;
  10 use Packages::I18N::Locale;
  11
  12 our @ISA = qw( Exporter );
  13 our @EXPORT_OK = qw( split_name_mail parse_deps );
  14 our %EXPORT_TAGS = ( all => [ @EXPORT_OK ] );
  15
  16 our $ARCHIVE_DEFAULT = '';
  17 our $SECTION_DEFAULT = 'main';
  18 our $SUBSECTION_DEFAULT = 'unknown';
  19 our $PRIORITY_DEFAULT = 'unknown';
  20 our $ESSENTIAL_DEFAULT = 'no';
  21 our $MAINTAINER_DEFAULT = 'unknown <unknown@email.invalid>';
  22
  23 sub new {
  24     my $classname = shift;
  25     my $name = shift || '';
  26     my $config = shift || {};
  27
  28     my $self = {};
  29     bless( $self, $classname );
  30
  31     $self->{package} = $name;
  32     $self->{config} = $config;
  33
  34     return $self;
  35 }
  36
  37 sub split_name_mail {
  38     my $string = shift;
  39     my ( $name, $email );
  40     if ($string =~ /(.*?)\s*<(.*)>/o) {
  41         $name =  $1;
  42         $email = $2;
  43     } elsif ($string =~ /^[\w.-]*@[\w.-]*$/o) {
  44         $name =  $string;
  45         $email = $string;
  46     } else {
  47         $name = N_( 'package has bad maintainer field' );
  48         $email = '';
  49     }
  50     $name =~ s/\s+$//o;
  51     return ($name, $email);
  52 }
  53
  54 sub override_maint {
  55     my ($self, $data) = @_;
  56
  57     return if $data->{'original-maintainer'};
  58     return unless $data->{maintainer};
  59
  60     my ($name, $mail) = split_name_mail( $data->{maintainer} );
  61
  62     # taken from etc/pkgbinarymangler/maintainermangler.overrides
  63     return if $mail =~ /\@(ubuntu\.com|canonical\.com|lists\.ubuntu\.com|lists\.canonical\.com|ubuntu\.com\.au|kubuntu\.org)^/o;
  64     return if $mail =~ /^(lamont\@debian\.org|q-funk\@iki\.fi|cjwatson\@debian\.org|patrick\.matthaei\@web\.de)^/o;
  65
  66     if ($mail eq 'adconrad@0c3.net') {
  67         $data->{maintainer} = 'Adam Conrad <adconrad@ubuntu.com>';
  68         return 1;
  69     }
  70     if ($mail eq 'mpitt@debian.org') {
  71         $data->{maintainer} = 'Martin Pitt <martin.pitt@ubuntu.com>';
  72         return 1;
  73     }
  74
  75     $data->{'original-maintainer'} = $data->{maintainer};
  76     foreach ($data->{section}) {
  77         /^(main|restricted)$/ && do {
  78             $data->{maintainer} = 'Ubuntu Core Developers <ubuntu-devel-discuss@lists.ubuntu.com>';
  79             last;
  80         };
  81         /^(uni|multi)verse$/ && do {
  82             $data->{maintainer} = 'Ubuntu MOTU Developers <ubuntu-motu@lists.ubuntu.com>';
  83             last;
  84         };
  85
  86         die 'Huh?';
  87     }
  88
  89     return 1;
  90 }
  91
  92 sub handle_maintainer_fields {
  93     my ($self, $data) = @_;
  94     my (@uploaders, @orig_uploaders);
  95
  96     if ($data->{'original-maintainer'}) {
  97         push @orig_uploaders, [ split_name_mail( $data->{'original-maintainer'} ) ];
  98
  99         $data->{uploaders} ||= '';
 100         my @up_tmp = split( /\s*,\s*/,
 101                             $data->{uploaders} );
 102         foreach my $up (@up_tmp) {
 103                 push @orig_uploaders, [ split_name_mail( $up ) ];
 104         }
 105         if ($data->{maintainer} ||= '') {
 106             push @uploaders, [ split_name_mail( $data->{maintainer} ) ];
 107         }
 108     } else {
 109         if ($data->{maintainer} ||= '') {
 110             if ($self->override_maint($data)) {
 111                 return $self->handle_maintainer_fields($data);
 112             }
 113
 114             push @uploaders, [ split_name_mail( $data->{maintainer} ) ];
 115         }
 116         if ($data->{uploaders}) {
 117             my @up_tmp = split( /\s*,\s*/,
 118                                 $data->{uploaders} );
 119             foreach my $up (@up_tmp) {
 120                 if ($up ne $data->{maintainer}) { # weed out duplicates
 121                     push @uploaders, [ split_name_mail( $up ) ];
 122                 }
 123             }
 124         }
 125     }
 126
 127     return (\@uploaders, \@orig_uploaders);
 128 }
 129
 130 sub add_src_data {
 131     my ($self, $src, $data) = @_;
 132
 133     my %data = split /\00/o, $data;
 134
 135     $self->{src}{package} = $src;
 136     $self->{src}{version} = $data{version};
 137     if ($data{files}) {
 138         my @files = split /\01/so, $data{files};
 139         $self->{src}{files} = \@files;
 140     }
 141     $self->{src}{directory} = $data{directory};
 142     my ($uploaders, $orig_uploaders) = $self->handle_maintainer_fields(\%data);
 143     $self->{src}{uploaders} = $uploaders;
 144     $self->{src}{orig_uploaders} = $orig_uploaders if @$orig_uploaders;
 145
 146     return 1;
 147 }
 148
 149 sub add_provided_by {
 150     my ($self, $provided_by) = @_;
 151
 152     $self->{provided_by} ||= [];
 153     push @{$self->{provided_by}}, @$provided_by;
 154 }
 155
 156 sub is_virtual {
 157     my ($self) = @_;
 158
 159     return (exists($self->{provided_by}) && !exists($self->{versions}));
 160 }
 161
 162 our @TAKE_NEWEST = qw( description description-md5 essential priority section subsection tag
 163                        archive source source-version homepage maintainer original-maintainer uploaders);
 164 our @STORE_ALL = qw( version source source-version installed-size size
 165                      filename md5sum sha1 sha256 task
 166                      origin bugs suite archive section );
 167 our @DEP_FIELDS = qw( depends pre-depends recommends suggests enhances
 168                       provides conflicts );
 169 sub merge_package {
 170     my ($self, $data) = @_;
 171
 172     ($data->{package} && $data->{version} && $data->{architecture}) || return;
 173     $self->{package} ||= $data->{package};
 174     ($self->{package} eq $data->{package}) || return;
 175     debug( "merge package $data->{package}/$data->{version}/$data->{architecture} into $self (".($self->{newest}||'').")", 2 ) if DEBUG;
 176
 177     (my $version = $data->{version}) =~ s/\+b\d+$//o; # strip binNMU number
 178     unless ($self->{newest}) {
 179         debug( "package $data->{package}/$data->{version}/$data->{architecture} is first to merge", 3 ) if DEBUG;
 180         foreach my $key (@TAKE_NEWEST) {
 181             $self->{data}{$key} = $data->{$key};
 182         }
 183         foreach my $key (@STORE_ALL) {
 184             $self->{versions}{$data->{architecture}}{$key}
 185             = $data->{$key};
 186         }
 187         foreach my $key (@DEP_FIELDS) {
 188             $self->normalize_dependencies($key, $data);
 189         }
 190         $self->{newest} = $version;
 191
 192         return 1;
 193     }
 194
 195     debug( "package $data->{package}/$data->{version}/$data->{architecture} is subsequent merge", 3 ) if DEBUG;
 196     my $is_newest;
 197     my $cmp = version_cmp( $version, $self->{newest} );
 198     # packages from the central archive are preferred over all
 199     # others with the same version number but from other archives
 200     if ($is_newest = ($cmp > 0)
 201         || (!$cmp && ($data->{archive} eq 'us') && ($self->{data}{archive} ne 'us'))) {
 202         $self->{newest} = $version;
 203         foreach my $key (@TAKE_NEWEST) {
 204             $self->{data}{$key} = $data->{$key};
 205         }
 206     }
 207     debug( "is_newest= ".($is_newest||0), 3 ) if DEBUG;
 208     if (!$self->{versions}{$data->{architecture}}
 209         || $is_newest
 210         || (version_cmp( $data->{version},
 211                          $self->{versions}{$data->{architecture}}{version} ) > 0)) {
 212         foreach my $key (@STORE_ALL) {
 213             $self->{versions}{$data->{architecture}}{$key}
 214             = $data->{$key};
 215         }
 216         foreach my $key (@DEP_FIELDS) {
 217             $self->normalize_dependencies($key, $data);
 218         }
 219     }
 220
 221     return 1;
 222 }
 223
 224 sub normalize_dependencies {
 225     my ($self, $dep_field, $data) = @_;
 226
 227     my ($deps_norm, $deps) = parse_deps( $data->{$dep_field}||'' );
 228     $self->{dep_fields}{$data->{architecture}}{$dep_field} =
 229         [ $deps_norm, $deps ];
 230 }
 231
 232 sub parse_deps {
 233     my ($dep_str) = @_;
 234
 235     my (@dep_and_norm, @dep_and);
 236     foreach my $dep_and (split( /\s*,\s*/m, $dep_str )) {
 237         next if $dep_and =~ /^\s*$/;
 238         my (@dep_or_norm, @dep_or);
 239         foreach my $dep_or (split( /\s*\|\s*/m, $dep_and )) {
 240             my ($pkg, $relation, $version, @arches) = ('','','');
 241             $pkg = $1 if $dep_or =~ s/^([a-zA-Z0-9][a-zA-Z0-9+._-]*)\s*//m;
 242             ($relation, $version) = ($1, $2)
 243                 if $dep_or =~ s/^\(\s*(=|<=|>=|<<?|>>?)\s*([^\)]+).*\)\s*//m;
 244             @arches = split(/\s+/m, $1) if $dep_or =~ s/^\[([^\]]+)\]\s*//m;
 245             push @dep_or_norm, "$pkg($relation$version)[".
 246                 join(" ",sort(@arches))."]";
 247             push @dep_or, [ $pkg, $relation, $version, \@arches ];
 248         }
 249         push @dep_and_norm, join('|',@dep_or_norm);
 250         push @dep_and, \@dep_or;
 251     }
 252     return (\@dep_and_norm, \@dep_and);
 253 }
 254
 255 sub get_newest {
 256     my ($self, $field) = @_;
 257
 258     return $self->{data}{$field};
 259 }
 260 sub get_src {
 261     my ($self, $field) = @_;
 262
 263     return $self->{src}{$field};
 264 }
 265
 266 sub get_architectures {
 267     my ($self) = @_;
 268
 269     return keys %{$self->{versions}};
 270 }
 271
 272 sub get_arch_field {
 273     my ($self, $field) = @_;
 274
 275     my %result;
 276     foreach (sort keys %{$self->{versions}}) {
 277         $result{$_} = $self->{versions}{$_}{$field}
 278         if $self->{versions}{$_}{$field};
 279     }
 280
 281     return \%result;
 282 }
 283
 284 sub get_versions {
 285     my ($self) = @_;
 286
 287     my %versions;
 288     foreach (keys %{$self->{versions}}) {
 289         my $version = $self->{versions}{$_}{version};
 290         $versions{$version} ||= [];
 291         push @{$versions{$version}}, $_;
 292     }
 293
 294     return \%versions;
 295 }
 296
 297 sub get_version_string {
 298     my ($self) = @_;
 299
 300     my $versions = $self->get_versions;
 301     my @versions = version_sort keys %$versions;
 302     my (@v_str, $v_str, $v_str_arch);
 303     if ( scalar @versions == 1 ) {
 304         @v_str = ( [ $versions[0], undef ] );
 305         $v_str = $versions[0];
 306         $v_str_arch = $versions[0];
 307     } else {
 308         my @v_str_arch;
 309         foreach ( @versions ) {
 310             push @v_str, [ $_, $versions->{$_} ];
 311             push @v_str_arch, "$_ [".join(', ', sort @{$versions->{$_}})."]";
 312         }
 313         $v_str_arch = join( ", ", @v_str_arch );
 314         $v_str = join( ", ",  @versions );
 315     }
 316
 317     return ($v_str, $v_str_arch, \@v_str);
 318 }
 319
 320 sub get_dep_field {
 321     my ($self, $dep_field) = @_;
 322
 323     my @architectures = $self->get_architectures;
 324
 325     my ( %dep_pkgs, %arch_deps );
 326     foreach my $a ( @architectures ) {
 327         next unless exists $self->{dep_fields}{$a}{$dep_field};
 328         my ($a_deps_norm, $a_deps) = @{$self->{dep_fields}{$a}{$dep_field}};
 329 #       debug( "get_dep_field: $dep_field/$a: ".Dumper($a_deps_norm,$a_deps), 3 ) if DEBUG;
 330         for ( my $i=0; $i < @$a_deps; $i++ ) { # splitted by ,
 331             $dep_pkgs{$a_deps_norm->[$i]} = $a_deps->[$i];
 332             $arch_deps{$a}{$a_deps_norm->[$i]}++;
 333         }
 334     }
 335     @architectures = sort keys %arch_deps;
 336  #   debug( "get_dep_field called:\n ".Dumper( \%dep_pkgs, \%arch_deps ), 3 ) if DEBUG;
 337
 338     my @deps;
 339     if ( %dep_pkgs ) {
 340         my $old_pkgs = '';
 341         my $is_old_pkgs = 0;
 342         foreach my $dp ( sort keys %dep_pkgs ) {
 343             my @dp_alts = @{$dep_pkgs{$dp}};
 344             my ( @pkgs, $pkgs );
 345             foreach (@dp_alts) { push @pkgs, $_->[0]; }
 346             $pkgs = "@pkgs";
 347
 348             unless ( $is_old_pkgs = ($pkgs eq $old_pkgs) ) {
 349                 $old_pkgs = $pkgs;
 350             }
 351
 352             my ($arch_neg, $arch_str) = _compute_arch_str ( $dp, \%arch_deps,
 353                                                             \@architectures );
 354
 355             my @res_pkgs; my $pkg_ix = 0;
 356             foreach my $p_name ( @pkgs ) {
 357                 if ( $pkg_ix > 0 ) { $arch_str = ""; }
 358
 359                 my $pkg_version = "";
 360                 $pkg_version = "$dep_pkgs{$dp}[$pkg_ix][1] $dep_pkgs{$dp}[$pkg_ix][2]"
 361                     if $dep_pkgs{$dp}[$pkg_ix][1];
 362
 363
 364                 push @res_pkgs, [ $p_name, $pkg_version, $arch_neg,
 365                                   $arch_str ];
 366                 $pkg_ix++;
 367             }
 368             push @deps, [ $is_old_pkgs, @res_pkgs ];
 369         }
 370     }
 371     return \@deps;
 372 }
 373
 374 sub _compute_arch_str {
 375     my ( $dp, $arch_deps, $all_archs, $is_src_dep ) = @_;
 376
 377     my ( @dependend_archs, @not_dependend_archs );
 378     my $arch_str;
 379     foreach my $a ( @$all_archs ) {
 380         if ( exists $arch_deps->{$a}{$dp} ) {
 381             push @dependend_archs, $a;
 382         } else {
 383             push @not_dependend_archs, $a;
 384         }
 385     }
 386     my $arch_neg = 0;
 387     if ( @dependend_archs == @$all_archs ) {
 388         $arch_str = "";
 389     } else {
 390         if ( @dependend_archs > (@$all_archs/2) ) {
 391             $arch_neg = 1;
 392             $arch_str = join( ", ", @not_dependend_archs);
 393         } else {
 394             $arch_str = join( ", ", @dependend_archs);
 395         }
 396     }
 397     return my @ret = ( $arch_neg, $arch_str );
 398 }
 399
 400 1;