Test suite updates.
[pkg/blosxom.git] / blosxom.cgi
1 #!/usr/bin/perl
2
3 # Blosxom
4 # Author: Rael Dornfest <rael@oreilly.com>
5 # Version: 2.0.2
6 # Home/Docs/Licensing: http://blosxom.sourceforge.net/
7 # Development/Downloads: http://sourceforge.net/projects/blosxom
8
9 package blosxom;
10
11 # --- Configurable variables -----
12
13 # What's this blog's title?
14 $blog_title = "My Weblog";
15
16 # What's this blog's description (for outgoing RSS feed)?
17 $blog_description = "Yet another Blosxom weblog.";
18
19 # What's this blog's primary language (for outgoing RSS feed)?
20 $blog_language = "en";
21
22 # What's this blog's text encoding ?
23 $blog_encoding = "UTF-8";
24
25 # Where are this blog's entries kept?
26 $datadir = "/Library/WebServer/Documents/blosxom";
27
28 # What's my preferred base URL for this blog (leave blank for automatic)?
29 $url = "";
30
31 # Should I stick only to the datadir for items or travel down the
32 # directory hierarchy looking for items?  If so, to what depth?
33 # 0 = infinite depth (aka grab everything), 1 = datadir only, n = n levels down
34 $depth = 0;
35
36 # How many entries should I show on the home page?
37 $num_entries = 40;
38
39 # What file extension signifies a blosxom entry?
40 $file_extension = "txt";
41
42 # What is the default flavour?
43 $default_flavour = "html";
44
45 # Should I show entries from the future (i.e. dated after now)?
46 $show_future_entries = 0;
47
48 # --- Plugins (Optional) -----
49
50 # File listing plugins blosxom should load
51 # (if empty blosxom will load all plugins in $plugin_dir and $plugin_path directories)
52 $plugin_list = "";
53
54 # Where are my plugins kept?
55 $plugin_dir = "";
56
57 # Where should my plugins keep their state information?
58 $plugin_state_dir = "$plugin_dir/state";
59
60 # Additional plugins location
61 # List of directories, separated by ';' on windows, ':' everywhere else
62 $plugin_path = "";
63
64 # --- Static Rendering -----
65
66 # Where are this blog's static files to be created?
67 $static_dir = "/Library/WebServer/Documents/blog";
68
69 # What's my administrative password (you must set this for static rendering)?
70 $static_password = "";
71
72 # What flavours should I generate statically?
73 @static_flavours = qw/html rss/;
74
75 # Should I statically generate individual entries?
76 # 0 = no, 1 = yes
77 $static_entries = 0;
78
79 # --------------------------------
80
81 use vars
82     qw! $version $blog_title $blog_description $blog_language $blog_encoding $datadir $url %template $template $depth $num_entries $file_extension $default_flavour $static_or_dynamic $config_dir $plugin_list $plugin_path $plugin_dir $plugin_state_dir @plugins %plugins $static_dir $static_password @static_flavours $static_entries $path_info_full $path_info $path_info_yr $path_info_mo $path_info_da $path_info_mo_num $flavour $static_or_dynamic %month2num @num2month $interpolate $entries $output $header $show_future_entries %files %indexes %others $encode_xml_entities !;
83
84 use strict;
85 use FileHandle;
86 use File::Find;
87 use File::stat;
88 use Time::Local;
89 use CGI qw/:standard :netscape/;
90
91 $version = "2.0.2";
92
93 # Should I encode entities for xml content-types? (plugins can turn this off if they do it themselves)
94 $encode_xml_entities = 1;
95
96 # Load configuration from $ENV{BLOSXOM_CONFIG_DIR}/blosxom.conf, if it exists
97 my $blosxom_config;
98 if ( $ENV{BLOSXOM_CONFIG_FILE} && -r $ENV{BLOSXOM_CONFIG_FILE} ) {
99     $blosxom_config = $ENV{BLOSXOM_CONFIG_FILE};
100     ( $config_dir = $blosxom_config ) =~ s! / [^/]* $ !!x;
101 }
102 else {
103     for my $blosxom_config_dir ( $ENV{BLOSXOM_CONFIG_DIR}, '/etc/blosxom',
104         '/etc' )
105     {
106         if ( -r "$blosxom_config_dir/blosxom.conf" ) {
107             $config_dir     = $blosxom_config_dir;
108             $blosxom_config = "$blosxom_config_dir/blosxom.conf";
109             last;
110         }
111     }
112 }
113
114 # Load $blosxom_config
115 if ($blosxom_config) {
116     if ( -r $blosxom_config ) {
117         eval { require $blosxom_config }
118             or warn "Error reading blosxom config file '$blosxom_config'"
119             . ( $@ ? ": $@" : '' );
120     }
121     else {
122         warn "Cannot find or read blosxom config file '$blosxom_config'";
123     }
124 }
125
126 my $fh = new FileHandle;
127
128 %month2num = (
129     nil => '00',
130     Jan => '01',
131     Feb => '02',
132     Mar => '03',
133     Apr => '04',
134     May => '05',
135     Jun => '06',
136     Jul => '07',
137     Aug => '08',
138     Sep => '09',
139     Oct => '10',
140     Nov => '11',
141     Dec => '12'
142 );
143 @num2month = sort { $month2num{$a} <=> $month2num{$b} } keys %month2num;
144
145 # Use the stated preferred URL or figure it out automatically
146 $url ||= url( -path_info => 1 );
147 $url =~ s/^included:/http:/ if $ENV{SERVER_PROTOCOL} eq 'INCLUDED';
148
149 # NOTE: Since v3.12, it looks as if CGI.pm misbehaves for SSIs and
150 # always appends path_info to the url. To fix this, we always
151 # request an url with path_info, and always remove it from the end of the
152 # string.
153 my $pi_len = length $ENV{PATH_INFO};
154 my $might_be_pi = substr( $url, -$pi_len );
155 substr( $url, -length $ENV{PATH_INFO} ) = ''
156     if $might_be_pi eq $ENV{PATH_INFO};
157
158 $url =~ s!/$!!;
159
160 # Drop ending any / from dir settings
161 $datadir    =~ s!/$!!;
162 $plugin_dir =~ s!/$!!;
163 $static_dir =~ s!/$!!;
164
165 # Fix depth to take into account datadir's path
166 $depth += ( $datadir =~ tr[/][] ) - 1 if $depth;
167
168 # Global variable to be used in head/foot.{flavour} templates
169 $path_info = '';
170
171 if (    !$ENV{GATEWAY_INTERFACE}
172     and param('-password')
173     and $static_password
174     and param('-password') eq $static_password )
175 {
176     $static_or_dynamic = 'static';
177 }
178 else {
179     $static_or_dynamic = 'dynamic';
180     param( -name => '-quiet', -value => 1 );
181 }
182
183 # Path Info Magic
184 # Take a gander at HTTP's PATH_INFO for optional blog name, archive yr/mo/day
185 my @path_info = split m{/}, path_info() || param('path');
186 $path_info_full = join '/', @path_info;      # Equivalent to $ENV{PATH_INFO}
187 shift @path_info;
188
189 while ( $path_info[0]
190     and $path_info[0] =~ /^[a-zA-Z].*$/
191     and $path_info[0] !~ /(.*)\.(.*)/ )
192 {
193     $path_info .= '/' . shift @path_info;
194 }
195
196 # Flavour specified by ?flav={flav} or index.{flav}
197 $flavour = '';
198
199 if ( $path_info[$#path_info] =~ /(.+)\.(.+)$/ ) {
200     $flavour = $2;
201     $path_info .= "/$1.$2" if $1 ne 'index';
202     pop @path_info;
203 }
204 else {
205     $flavour = param('flav') || $default_flavour;
206 }
207
208 # Strip spurious slashes
209 $path_info =~ s!(^/*)|(/*$)!!g;
210
211 # Date fiddling
212 ( $path_info_yr, $path_info_mo, $path_info_da ) = @path_info;
213 $path_info_mo_num
214     = $path_info_mo
215     ? ( $path_info_mo =~ /\d{2}/
216     ? $path_info_mo
217     : ( $month2num{ ucfirst( lc $path_info_mo ) } || undef ) )
218     : undef;
219
220 # Define standard template subroutine, plugin-overridable at Plugins: Template
221 $template = sub {
222     my ( $path, $chunk, $flavour ) = @_;
223
224     do {
225         return join '', <$fh>
226             if $fh->open("< $datadir/$path/$chunk.$flavour");
227     } while ( $path =~ s/(\/*[^\/]*)$// and $1 );
228
229     # Check for definedness, since flavour can be the empty string
230     if ( defined $template{$flavour}{$chunk} ) {
231         return $template{$flavour}{$chunk};
232     }
233     elsif ( defined $template{error}{$chunk} ) {
234         return $template{error}{$chunk};
235     }
236     else {
237         return '';
238     }
239 };
240
241 # Bring in the templates
242 %template = ();
243 while (<DATA>) {
244     last if /^(__END__)$/;
245     my ( $ct, $comp, $txt ) = /^(\S+)\s(\S+)(?:\s(.*))?$/ or next;
246     $txt =~ s/\\n/\n/mg;
247     $template{$ct}{$comp} .= $txt . "\n";
248 }
249
250 # Plugins: Start
251 my $path_sep = $^O eq 'MSWin32' ? ';' : ':';
252 my @plugin_dirs = split /$path_sep/, $plugin_path;
253 unshift @plugin_dirs, $plugin_dir;
254 my @plugin_list = ();
255 my %plugin_hash = ();
256
257 # If $plugin_list is set, read plugins to use from that file
258 if ( $plugin_list ) {
259     if ( -r $plugin_list and $fh->open("< $plugin_list") ) {
260         @plugin_list = map { chomp $_; $_ } grep { /\S/ && !/^#/ } <$fh>;
261         $fh->close;
262     }
263     else {
264         warn "unable to read or open plugin_list '$plugin_list': $!";
265         $plugin_list = '';
266     }
267 }
268
269 # Otherwise walk @plugin_dirs to get list of plugins to use
270 if ( ! @plugin_list && @plugin_dirs ) {
271     for my $plugin_dir (@plugin_dirs) {
272         next unless -d $plugin_dir;
273         if ( opendir PLUGINS, $plugin_dir ) {
274             for my $plugin (
275                 grep { /^[\w:]+$/ && !/~$/ && -f "$plugin_dir/$_" }
276                 readdir(PLUGINS) )
277             {
278
279                 # Ignore duplicates
280                 next if $plugin_hash{$plugin};
281
282                 # Add to @plugin_list and %plugin_hash
283                 $plugin_hash{$plugin} = "$plugin_dir/$plugin";
284                 push @plugin_list, $plugin;
285             }
286             closedir PLUGINS;
287         }
288     }
289     @plugin_list = sort @plugin_list;
290 }
291
292 # Load all plugins in @plugin_list
293 unshift @INC, @plugin_dirs;
294 foreach my $plugin (@plugin_list) {
295     my ( $plugin_name, $off ) = $plugin =~ /^\d*([\w:]+?)(_?)$/;
296     my $plugin_file = $plugin_list ? $plugin_name : $plugin;
297     my $on_off = $off eq '_' ? -1 : 1;
298
299     # Allow perl module plugins
300     # The -z test is a hack to allow a zero-length placeholder file in a 
301     #   $plugin_path directory to indicate an @INC module should be loaded
302     if ( $plugin =~ m/::/ && ( $plugin_list || -z $plugin_hash{$plugin} ) ) {
303
304      # For Blosxom::Plugin::Foo style plugins, we need to use a string require
305         eval "require $plugin_file";
306     }
307     else
308     { # we try first to load from $plugin_dir before attempting from $plugin_path
309         eval        { require "$plugin_dir/$plugin_file" }
310             or eval { require $plugin_file };
311     }
312
313     if ($@) {
314         warn "error finding or loading blosxom plugin '$plugin_name': $@";
315         next;
316     }
317     if ( $plugin_name->start() and ( $plugins{$plugin_name} = $on_off ) ) {
318         push @plugins, $plugin_name;
319     }
320
321 }
322 shift @INC foreach @plugin_dirs;
323
324 # Plugins: Template
325 # Allow for the first encountered plugin::template subroutine to override the
326 # default built-in template subroutine
327 foreach my $plugin (@plugins) {
328     if ( $plugins{$plugin} > 0 and $plugin->can('template') ) {
329         if ( my $tmp = $plugin->template() ) {
330             $template = $tmp;
331             last;
332         }
333     }
334 }
335
336 # Provide backward compatibility for Blosxom < 2.0rc1 plug-ins
337 sub load_template {
338     return &$template(@_);
339 }
340
341 # Define default entries subroutine
342 $entries = sub {
343     my ( %files, %indexes, %others );
344     find(
345         sub {
346             my $d;
347             my $curr_depth = $File::Find::dir =~ tr[/][];
348             return if $depth and $curr_depth > $depth;
349
350             if (
351
352                 # a match
353                 $File::Find::name
354                 =~ m!^$datadir/(?:(.*)/)?(.+)\.$file_extension$!
355
356                 # not an index, .file, and is readable
357                 and $2 ne 'index' and $2 !~ /^\./ and ( -r $File::Find::name )
358                 )
359             {
360
361                 # read modification time
362                 my $mtime = stat($File::Find::name)->mtime or return;
363
364                 # to show or not to show future entries
365                 return unless ( $show_future_entries or $mtime < time );
366
367                 # add the file and its associated mtime to the list of files
368                 $files{$File::Find::name} = $mtime;
369
370                 # static rendering bits
371                 my $static_file
372                     = "$static_dir/$1/index." . $static_flavours[0];
373                 if (   param('-all')
374                     or !-f $static_file
375                     or stat($static_file)->mtime < $mtime )
376                 {
377                     $indexes{$1} = 1;
378                     $d = join( '/', ( nice_date($mtime) )[ 5, 2, 3 ] );
379                     $indexes{$d} = $d;
380                     $indexes{ ( $1 ? "$1/" : '' ) . "$2.$file_extension" } = 1
381                         if $static_entries;
382                 }
383             }
384
385             # not an entries match
386             elsif ( !-d $File::Find::name and -r $File::Find::name ) {
387                 $others{$File::Find::name} = stat($File::Find::name)->mtime;
388             }
389         },
390         $datadir
391     );
392
393     return ( \%files, \%indexes, \%others );
394 };
395
396 # Plugins: Entries
397 # Allow for the first encountered plugin::entries subroutine to override the
398 # default built-in entries subroutine
399 foreach my $plugin (@plugins) {
400     if ( $plugins{$plugin} > 0 and $plugin->can('entries') ) {
401         if ( my $tmp = $plugin->entries() ) {
402             $entries = $tmp;
403             last;
404         }
405     }
406 }
407
408 my ( $files, $indexes, $others ) = &$entries();
409 %indexes = %$indexes;
410
411 # Static
412 if (    !$ENV{GATEWAY_INTERFACE}
413     and param('-password')
414     and $static_password
415     and param('-password') eq $static_password )
416 {
417
418     param('-quiet') or print "Blosxom is generating static index pages...\n";
419
420     # Home Page and Directory Indexes
421     my %done;
422     foreach my $path ( sort keys %indexes ) {
423         my $p = '';
424         foreach ( ( '', split /\//, $path ) ) {
425             $p .= "/$_";
426             $p =~ s!^/!!;
427             next if $done{$p}++;
428             mkdir "$static_dir/$p", 0755
429                 unless ( -d "$static_dir/$p" or $p =~ /\.$file_extension$/ );
430             foreach $flavour (@static_flavours) {
431                 my $content_type
432                     = ( &$template( $p, 'content_type', $flavour ) );
433                 $content_type =~ s!\n.*!!s;
434                 my $fn = $p =~ m!^(.+)\.$file_extension$! ? $1 : "$p/index";
435                 param('-quiet') or print "$fn.$flavour\n";
436                 my $fh_w = new FileHandle "> $static_dir/$fn.$flavour"
437                     or die "Couldn't open $static_dir/$p for writing: $!";
438                 $output = '';
439                 if ( $indexes{$path} == 1 ) {
440
441                     # category
442                     $path_info = $p;
443
444                     # individual story
445                     $path_info =~ s!\.$file_extension$!\.$flavour!;
446                     print $fh_w &generate( 'static', $path_info, '', $flavour,
447                         $content_type );
448                 }
449                 else {
450
451                     # date
452                     local (
453                         $path_info_yr, $path_info_mo,
454                         $path_info_da, $path_info
455                     ) = split /\//, $p, 4;
456                     unless ( defined $path_info ) { $path_info = "" }
457                     print $fh_w &generate( 'static', '', $p, $flavour,
458                         $content_type );
459                 }
460                 $fh_w->close;
461             }
462         }
463     }
464 }
465
466 # Dynamic
467 else {
468     my $content_type = ( &$template( $path_info, 'content_type', $flavour ) );
469     $content_type =~ s!\n.*!!s;
470
471     $content_type =~ s/(\$\w+(?:::\w+)*)/"defined $1 ? $1 : ''"/gee;
472     $header = { -type => $content_type };
473
474     print generate( 'dynamic', $path_info,
475         "$path_info_yr/$path_info_mo_num/$path_info_da",
476         $flavour, $content_type );
477 }
478
479 # Plugins: End
480 foreach my $plugin (@plugins) {
481     if ( $plugins{$plugin} > 0 and $plugin->can('end') ) {
482         $entries = $plugin->end();
483     }
484 }
485
486 # Generate
487 sub generate {
488     my ( $static_or_dynamic, $currentdir, $date, $flavour, $content_type )
489         = @_;
490
491     %files = %$files;
492     %others = ref $others ? %$others : ();
493
494     # Plugins: Filter
495     foreach my $plugin (@plugins) {
496         if ( $plugins{$plugin} > 0 and $plugin->can('filter') ) {
497             $entries = $plugin->filter( \%files, \%others );
498         }
499     }
500
501     my %f = %files;
502
503     # Plugins: Skip
504     # Allow plugins to decide if we can cut short story generation
505     my $skip;
506     foreach my $plugin (@plugins) {
507         if ( $plugins{$plugin} > 0 and $plugin->can('skip') ) {
508             if ( my $tmp = $plugin->skip() ) {
509                 $skip = $tmp;
510                 last;
511             }
512         }
513     }
514
515     # Define default interpolation subroutine
516     $interpolate = sub {
517         package blosxom;
518         my $template = shift;
519         # Interpolate scalars, namespaced scalars, and hash/hashref scalars
520         $template =~ s/(\$\w+(?:::\w+)*(?:(?:->)?{(['"]?)[-\w]+\2})?)/"defined $1 ? $1 : ''"/gee;
521         return $template;
522     };
523
524     unless ( defined($skip) and $skip ) {
525
526         # Plugins: Interpolate
527         # Allow for the first encountered plugin::interpolate subroutine to
528         # override the default built-in interpolate subroutine
529         foreach my $plugin (@plugins) {
530             if ( $plugins{$plugin} > 0 and $plugin->can('interpolate') ) {
531                 if ( my $tmp = $plugin->interpolate() ) {
532                     $interpolate = $tmp;
533                     last;
534                 }
535             }
536         }
537
538         # Head
539         my $head = ( &$template( $currentdir, 'head', $flavour ) );
540
541         # Plugins: Head
542         foreach my $plugin (@plugins) {
543             if ( $plugins{$plugin} > 0 and $plugin->can('head') ) {
544                 $entries = $plugin->head( $currentdir, \$head );
545             }
546         }
547
548         $head = &$interpolate($head);
549
550         $output .= $head;
551
552         # Stories
553         my $curdate = '';
554         my $ne      = $num_entries;
555
556         if ( $currentdir =~ /(.*?)([^\/]+)\.(.+)$/ and $2 ne 'index' ) {
557             $currentdir = "$1$2.$file_extension";
558             %f = ( "$datadir/$currentdir" => $files{"$datadir/$currentdir"} )
559                 if $files{"$datadir/$currentdir"};
560         }
561         else {
562             $currentdir =~ s!/index\..+$!!;
563         }
564
565         # Define a default sort subroutine
566         my $sort = sub {
567             my ($files_ref) = @_;
568             return
569                 sort { $files_ref->{$b} <=> $files_ref->{$a} }
570                 keys %$files_ref;
571         };
572
573      # Plugins: Sort
574      # Allow for the first encountered plugin::sort subroutine to override the
575      # default built-in sort subroutine
576         foreach my $plugin (@plugins) {
577             if ( $plugins{$plugin} > 0 and $plugin->can('sort') ) {
578                 if ( my $tmp = $plugin->sort() ) {
579                     $sort = $tmp;
580                     last;
581                 }
582             }
583         }
584
585         foreach my $path_file ( &$sort( \%f, \%others ) ) {
586             last if $ne <= 0 && $date !~ /\d/;
587             use vars qw/ $path $fn /;
588             ( $path, $fn )
589                 = $path_file =~ m!^$datadir/(?:(.*)/)?(.*)\.$file_extension!;
590
591             # Only stories in the right hierarchy
592             $path =~ /^$currentdir/
593                 or $path_file eq "$datadir/$currentdir"
594                 or next;
595
596             # Prepend a slash for use in templates only if a path exists
597             $path &&= "/$path";
598
599             # Date fiddling for by-{year,month,day} archive views
600             use vars
601                 qw/ $dw $mo $mo_num $da $ti $yr $hr $min $hr12 $ampm $utc_offset/;
602             ( $dw, $mo, $mo_num, $da, $ti, $yr, $utc_offset )
603                 = nice_date( $files{"$path_file"} );
604             ( $hr, $min ) = split /:/, $ti;
605             ( $hr12, $ampm ) = $hr >= 12 ? ( $hr - 12, 'pm' ) : ( $hr, 'am' );
606             $hr12 =~ s/^0//;
607             if ( $hr12 == 0 ) { $hr12 = 12 }
608
609             # Only stories from the right date
610             my ( $path_info_yr, $path_info_mo_num, $path_info_da )
611                 = split /\//, $date;
612             next if $path_info_yr     && $yr != $path_info_yr;
613             last if $path_info_yr     && $yr < $path_info_yr;
614             next if $path_info_mo_num && $mo ne $num2month[$path_info_mo_num];
615             next if $path_info_da     && $da != $path_info_da;
616             last if $path_info_da     && $da < $path_info_da;
617
618             # Date
619             my $date = ( &$template( $path, 'date', $flavour ) );
620
621             # Plugins: Date
622             foreach my $plugin (@plugins) {
623                 if ( $plugins{$plugin} > 0 and $plugin->can('date') ) {
624                     $entries
625                         = $plugin->date( $currentdir, \$date,
626                         $files{$path_file}, $dw, $mo, $mo_num, $da, $ti,
627                         $yr );
628                 }
629             }
630
631             $date = &$interpolate($date);
632
633             if ( $date && $curdate ne $date ) {
634                 $curdate = $date;
635                 $output .= $date;
636             }
637
638             use vars qw/ $title $body $raw /;
639             if ( -f "$path_file" && $fh->open("< $path_file") ) {
640                 chomp( $title = <$fh> );
641                 chomp( $body = join '', <$fh> );
642                 $fh->close;
643                 $raw = "$title\n$body";
644             }
645             my $story = ( &$template( $path, 'story', $flavour ) );
646
647             # Plugins: Story
648             foreach my $plugin (@plugins) {
649                 if ( $plugins{$plugin} > 0 and $plugin->can('story') ) {
650                     $entries = $plugin->story( $path, $fn, \$story, \$title,
651                         \$body );
652                 }
653             }
654
655             if ( $encode_xml_entities && $content_type =~ m{\bxml\b} ) {
656
657                 # Escape <, >, and &, and to produce valid RSS
658                 my %escape = (
659                     '<' => '&lt;',
660                     '>' => '&gt;',
661                     '&' => '&amp;',
662                     '"' => '&quot;'
663                 );
664                 my $escape_re = join '|' => keys %escape;
665                 $title =~ s/($escape_re)/$escape{$1}/g;
666                 $body  =~ s/($escape_re)/$escape{$1}/g;
667             }
668
669             $story = &$interpolate($story);
670
671             $output .= $story;
672             $fh->close;
673
674             $ne--;
675         }
676
677         # Foot
678         my $foot = ( &$template( $currentdir, 'foot', $flavour ) );
679
680         # Plugins: Foot
681         foreach my $plugin (@plugins) {
682             if ( $plugins{$plugin} > 0 and $plugin->can('foot') ) {
683                 $entries = $plugin->foot( $currentdir, \$foot );
684             }
685         }
686
687         $foot = &$interpolate($foot);
688         $output .= $foot;
689
690         # Plugins: Last
691         foreach my $plugin (@plugins) {
692             if ( $plugins{$plugin} > 0 and $plugin->can('last') ) {
693                 $entries = $plugin->last();
694             }
695         }
696
697     }    # End skip
698
699     # Finally, add the header, if any and running dynamically
700     $output = header($header) . $output
701         if ( $static_or_dynamic eq 'dynamic' and $header );
702
703     $output;
704 }
705
706 sub nice_date {
707     my ($unixtime) = @_;
708
709     my $c_time = CORE::localtime($unixtime);
710     my ( $dw, $mo, $da, $hr, $min, $sec, $yr )
711         = ( $c_time
712             =~ /(\w{3}) +(\w{3}) +(\d{1,2}) +(\d{2}):(\d{2}):(\d{2}) +(\d{4})$/
713         );
714     $ti = "$hr:$min";
715     $da = sprintf( "%02d", $da );
716     my $mo_num = $month2num{$mo};
717
718     my $offset
719         = timegm( $sec, $min, $hr, $da, $mo_num - 1, $yr - 1900 ) - $unixtime;
720     my $utc_offset = sprintf( "%+03d", int( $offset / 3600 ) )
721         . sprintf( "%02d", ( $offset % 3600 ) / 60 );
722
723     return ( $dw, $mo, $mo_num, $da, $ti, $yr, $utc_offset );
724 }
725
726 # Default HTML and RSS template bits
727 __DATA__
728 html content_type text/html; charset=$blog_encoding
729
730 html head <html>
731 html head     <head>
732 html head         <meta http-equiv="content-type" content="text/html;charset=$blog_encoding" />
733 html head         <link rel="alternate" type="application/rss+xml" title="RSS" href="$url/index.rss" />
734 html head         <title>$blog_title $path_info_da $path_info_mo $path_info_yr
735 html head         </title>
736 html head     </head>
737 html head     <body>
738 html head         <center>
739 html head             <font size="+3">$blog_title</font><br />
740 html head             $path_info_da $path_info_mo $path_info_yr
741 html head         </center>
742 html head         <p />
743
744 html story        <p>
745 html story            <a name="$fn"><b>$title</b></a><br />
746 html story            $body<br />
747 html story            <br />
748 html story            posted at: $ti | path: <a href="$url$path">$path </a> | <a href="$url/$yr/$mo_num/$da#$fn">permanent link to this entry</a>
749 html story        </p>
750
751 html date         <h3>$dw, $da $mo $yr</h3>
752
753 html foot
754 html foot         <p />
755 html foot         <center>
756 html foot             <a href="http://blosxom.sourceforge.net/"><img src="http://blosxom.sourceforge.net/images/pb_blosxom.gif" border="0" /></a>
757 html foot         </center>
758 html foot     </body>
759 html foot </html>
760
761 rss content_type text/xml; charset=$blog_encoding
762
763 rss head <?xml version="1.0" encoding="$blog_encoding"?>
764 rss head <rss version="2.0">
765 rss head   <channel>
766 rss head     <title>$blog_title</title>
767 rss head     <link>$url/$path_info</link>
768 rss head     <description>$blog_description</description>
769 rss head     <language>$blog_language</language>
770 rss head     <docs>http://blogs.law.harvard.edu/tech/rss</docs>
771 rss head     <generator>blosxom/$version</generator>
772
773 rss story   <item>
774 rss story     <title>$title</title>
775 rss story     <pubDate>$dw, $da $mo $yr $ti:00 $utc_offset</pubDate>
776 rss story     <link>$url/$yr/$mo_num/$da#$fn</link>
777 rss story     <category>$path</category>
778 rss story     <guid isPermaLink="false">$path/$fn</guid>
779 rss story     <description>$body</description>
780 rss story   </item>
781
782 rss date 
783
784 rss foot   </channel>
785 rss foot </rss>
786
787 error content_type text/html
788
789 error head <html>
790 error head <body>
791 error head     <p><font color="red">Error: I'm afraid this is the first I've heard of a "$flavour" flavoured Blosxom.  Try dropping the "/+$flavour" bit from the end of the URL.</font></p>
792
793
794 error story <p><b>$title</b><br />
795 error story $body <a href="$url/$yr/$mo_num/$da#fn.$default_flavour">#</a></p>
796
797 error date <h3>$dw, $da $mo $yr</h3>
798
799 error foot     </body>
800 error foot </html>
801 __END__
802