Restores $plugin_dir as the main plugin location. Tries to prevent possible name...
[pkg/blosxom.git] / blosxom.cgi
1 #!/usr/bin/perl
2
3 # Blosxom
4 # Author: Rael Dornfest <rael@oreilly.com>
5 # Version: 2.0.2
6 # Home/Docs/Licensing: http://blosxom.sourceforge.net/
7 # Development/Downloads: http://sourceforge.net/projects/blosxom
8
9 package blosxom;
10
11 # --- Configurable variables -----
12
13 # What's this blog's title?
14 $blog_title = "My Weblog";
15
16 # What's this blog's description (for outgoing RSS feed)?
17 $blog_description = "Yet another Blosxom weblog.";
18
19 # What's this blog's primary language (for outgoing RSS feed)?
20 $blog_language = "en";
21
22 # What's this blog's text encoding ?
23 $blog_encoding = "UTF-8";
24
25 # Where are this blog's entries kept?
26 $datadir = "/Library/WebServer/Documents/blosxom";
27
28 # What's my preferred base URL for this blog (leave blank for automatic)?
29 $url = "";
30
31 # Should I stick only to the datadir for items or travel down the
32 # directory hierarchy looking for items?  If so, to what depth?
33 # 0 = infinite depth (aka grab everything), 1 = datadir only, n = n levels down
34 $depth = 0;
35
36 # How many entries should I show on the home page?
37 $num_entries = 40;
38
39 # What file extension signifies a blosxom entry?
40 $file_extension = "txt";
41
42 # What is the default flavour?
43 $default_flavour = "html";
44
45 # Should I show entries from the future (i.e. dated after now)?
46 $show_future_entries = 0;
47
48 # --- Plugins (Optional) -----
49
50 # File listing plugins blosxom should load
51 # (if empty blosxom will load all plugins in $plugin_dir and $plugin_path directories)
52 $plugin_list = "";
53
54 # Where are my plugins kept?
55 $plugin_dir = "";
56
57 # Where should my plugins keep their state information?
58 $plugin_state_dir = "$plugin_dir/state";
59
60 # Additional plugins location
61 # List of directories, separated by ';' on windows, ':' everywhere else
62 $plugin_path = "";
63
64 # --- Static Rendering -----
65
66 # Where are this blog's static files to be created?
67 $static_dir = "/Library/WebServer/Documents/blog";
68
69 # What's my administrative password (you must set this for static rendering)?
70 $static_password = "";
71
72 # What flavours should I generate statically?
73 @static_flavours = qw/html rss/;
74
75 # Should I statically generate individual entries?
76 # 0 = no, 1 = yes
77 $static_entries = 0;
78
79 # --------------------------------
80
81 use vars
82     qw! $version $blog_title $blog_description $blog_language $blog_encoding $datadir $url %template $template $depth $num_entries $file_extension $default_flavour $static_or_dynamic $config_dir $plugin_list $plugin_path $plugin_dir $plugin_state_dir @plugins %plugins $static_dir $static_password @static_flavours $static_entries $path_info $path_info_yr $path_info_mo $path_info_da $path_info_mo_num $flavour $static_or_dynamic %month2num @num2month $interpolate $entries $output $header $show_future_entries %files %indexes %others !;
83
84 use strict;
85 use FileHandle;
86 use File::Find;
87 use File::stat;
88 use Time::Local;
89 use CGI qw/:standard :netscape/;
90
91 $version = "2.0.2";
92
93 # Load configuration from $ENV{BLOSXOM_CONFIG_DIR}/blosxom.conf, if it exists
94 my $blosxom_config;
95 if ( $ENV{BLOSXOM_CONFIG_FILE} && -r $ENV{BLOSXOM_CONFIG_FILE} ) {
96     $blosxom_config = $ENV{BLOSXOM_CONFIG_FILE};
97     ( $config_dir = $blosxom_config ) =~ s! / [^/]* $ !!x;
98 }
99 else {
100     for my $blosxom_config_dir ( $ENV{BLOSXOM_CONFIG_DIR}, '/etc/blosxom',
101         '/etc' )
102     {
103         if ( -r "$blosxom_config_dir/blosxom.conf" ) {
104             $config_dir     = $blosxom_config_dir;
105             $blosxom_config = "$blosxom_config_dir/blosxom.conf";
106             last;
107         }
108     }
109 }
110
111 # Load $blosxom_config
112 if ($blosxom_config) {
113     if ( -r $blosxom_config ) {
114         eval { require $blosxom_config }
115             or warn "Error reading blosxom config file '$blosxom_config'"
116             . ( $@ ? ": $@" : '' );
117     }
118     else {
119         warn "Cannot find or read blosxom config file '$blosxom_config'";
120     }
121 }
122
123 my $fh = new FileHandle;
124
125 %month2num = (
126     nil => '00',
127     Jan => '01',
128     Feb => '02',
129     Mar => '03',
130     Apr => '04',
131     May => '05',
132     Jun => '06',
133     Jul => '07',
134     Aug => '08',
135     Sep => '09',
136     Oct => '10',
137     Nov => '11',
138     Dec => '12'
139 );
140 @num2month = sort { $month2num{$a} <=> $month2num{$b} } keys %month2num;
141
142 # Use the stated preferred URL or figure it out automatically
143 $url ||= url( -path_info => 1 );
144 $url =~ s/^included:/http:/ if $ENV{SERVER_PROTOCOL} eq 'INCLUDED';
145
146 # NOTE: Since v3.12, it looks as if CGI.pm misbehaves for SSIs and
147 # always appends path_info to the url. To fix this, we always
148 # request an url with path_info, and always remove it from the end of the
149 # string.
150 my $pi_len = length $ENV{PATH_INFO};
151 my $might_be_pi = substr( $url, -$pi_len );
152 substr( $url, -length $ENV{PATH_INFO} ) = ''
153     if $might_be_pi eq $ENV{PATH_INFO};
154
155 $url =~ s!/$!!;
156
157 # Drop ending any / from dir settings
158 $datadir    =~ s!/$!!;
159 $plugin_dir =~ s!/$!!;
160 $static_dir =~ s!/$!!;
161
162 # Fix depth to take into account datadir's path
163 $depth += ( $datadir =~ tr[/][] ) - 1 if $depth;
164
165 # Global variable to be used in head/foot.{flavour} templates
166 $path_info = '';
167
168 if (    !$ENV{GATEWAY_INTERFACE}
169     and param('-password')
170     and $static_password
171     and param('-password') eq $static_password )
172 {
173     $static_or_dynamic = 'static';
174 }
175 else {
176     $static_or_dynamic = 'dynamic';
177     param( -name => '-quiet', -value => 1 );
178 }
179
180 # Path Info Magic
181 # Take a gander at HTTP's PATH_INFO for optional blog name, archive yr/mo/day
182 my @path_info = split m{/}, path_info() || param('path');
183 shift @path_info;
184
185 while ( $path_info[0]
186     and $path_info[0] =~ /^[a-zA-Z].*$/
187     and $path_info[0] !~ /(.*)\.(.*)/ )
188 {
189     $path_info .= '/' . shift @path_info;
190 }
191
192 # Flavour specified by ?flav={flav} or index.{flav}
193 $flavour = '';
194
195 if ( $path_info[$#path_info] =~ /(.+)\.(.+)$/ ) {
196     $flavour = $2;
197     $path_info .= "/$1.$2" if $1 ne 'index';
198     pop @path_info;
199 }
200 else {
201     $flavour = param('flav') || $default_flavour;
202 }
203
204 # Strip spurious slashes
205 $path_info =~ s!(^/*)|(/*$)!!g;
206
207 # Date fiddling
208 ( $path_info_yr, $path_info_mo, $path_info_da ) = @path_info;
209 $path_info_mo_num
210     = $path_info_mo
211     ? ( $path_info_mo =~ /\d{2}/
212     ? $path_info_mo
213     : ( $month2num{ ucfirst( lc $path_info_mo ) } || undef ) )
214     : undef;
215
216 # Define standard template subroutine, plugin-overridable at Plugins: Template
217 $template = sub {
218     my ( $path, $chunk, $flavour ) = @_;
219
220     do {
221         return join '', <$fh>
222             if $fh->open("< $datadir/$path/$chunk.$flavour");
223     } while ( $path =~ s/(\/*[^\/]*)$// and $1 );
224
225     # Check for definedness, since flavour can be the empty string
226     if ( defined $template{$flavour}{$chunk} ) {
227         return $template{$flavour}{$chunk};
228     }
229     elsif ( defined $template{error}{$chunk} ) {
230         return $template{error}{$chunk};
231     }
232     else {
233         return '';
234     }
235 };
236
237 # Bring in the templates
238 %template = ();
239 while (<DATA>) {
240     last if /^(__END__)$/;
241     my ( $ct, $comp, $txt ) = /^(\S+)\s(\S+)(?:\s(.*))?$/ or next;
242     $txt =~ s/\\n/\n/mg;
243     $template{$ct}{$comp} .= $txt . "\n";
244 }
245
246 # Plugins: Start
247 my $path_sep = $^O eq 'MSWin32' ? ';' : ':';
248 my @plugin_dirs = split /$path_sep/, $plugin_path;
249 unshift @plugin_dirs, $plugin_dir;
250 my @plugin_list = ();
251 my %plugin_hash = ();
252
253 # If $plugin_list is set, read plugins to use from that file
254 $plugin_list = "$config_dir/$plugin_list"
255     if $plugin_list && $plugin_list !~ m!^\s*/!;
256 if ( $plugin_list and -r $plugin_list and $fh->open("< $plugin_list") ) {
257     @plugin_list = map { chomp $_; $_ } grep { /\S/ && !/^#/ } <$fh>;
258     $fh->close;
259 }
260
261 # Otherwise walk @plugin_dirs to get list of plugins to use
262 elsif (@plugin_dirs) {
263     for my $plugin_dir (@plugin_dirs) {
264         next unless -d $plugin_dir;
265         if ( opendir PLUGINS, $plugin_dir ) {
266             for my $plugin (
267                 grep { /^[\w:]+$/ && !/~$/ && -f "$plugin_dir/$_" }
268                 readdir(PLUGINS) )
269             {
270
271                 # Ignore duplicates
272                 next if $plugin_hash{$plugin};
273
274                 # Add to @plugin_list and %plugin_hash
275                 $plugin_hash{$plugin} = "$plugin_dir/$plugin";
276                 push @plugin_list, $plugin;
277             }
278             closedir PLUGINS;
279         }
280     }
281     @plugin_list = sort @plugin_list;
282 }
283
284 # Load all plugins in @plugin_list
285 unshift @INC, @plugin_dirs;
286 foreach my $plugin (@plugin_list) {
287     my ( $plugin_name, $off ) = $plugin =~ /^\d*([\w:]+?)(_?)$/;
288     my $on_off = $off eq '_' ? -1 : 1;
289
290     # Allow perl module plugins
291     if ( $plugin =~ m/::/ && -z $plugin_hash{$plugin} ) {
292
293      # For Blosxom::Plugin::Foo style plugins, we need to use a string require
294         eval "require $plugin_name";
295     }
296     else
297     { # we try first to load from $plugin_dir before attempting from $plugin_path
298         eval        { require "$plugin_dir/$plugin" }
299             or eval { require $plugin };
300     }
301
302     if ($@) {
303         warn "error finding or loading blosxom plugin '$plugin_name': $@";
304         next;
305     }
306     if ( $plugin_name->start() and ( $plugins{$plugin_name} = $on_off ) ) {
307         push @plugins, $plugin_name;
308     }
309
310 }
311 shift @INC foreach @plugin_dirs;
312
313 # Plugins: Template
314 # Allow for the first encountered plugin::template subroutine to override the
315 # default built-in template subroutine
316 foreach my $plugin (@plugins) {
317     if ( $plugins{$plugin} > 0 and $plugin->can('template') ) {
318         if ( my $tmp = $plugin->template() ) {
319             $template = $tmp;
320             last;
321         }
322     }
323 }
324
325 # Provide backward compatibility for Blosxom < 2.0rc1 plug-ins
326 sub load_template {
327     return &$template(@_);
328 }
329
330 # Define default entries subroutine
331 $entries = sub {
332     my ( %files, %indexes, %others );
333     find(
334         sub {
335             my $d;
336             my $curr_depth = $File::Find::dir =~ tr[/][];
337             return if $depth and $curr_depth > $depth;
338
339             if (
340
341                 # a match
342                 $File::Find::name
343                 =~ m!^$datadir/(?:(.*)/)?(.+)\.$file_extension$!
344
345                 # not an index, .file, and is readable
346                 and $2 ne 'index' and $2 !~ /^\./ and ( -r $File::Find::name )
347                 )
348             {
349
350                 # read modification time
351                 my $mtime = stat($File::Find::name)->mtime or return;
352
353                 # to show or not to show future entries
354                 return unless ( $show_future_entries or $mtime < time );
355
356                 # add the file and its associated mtime to the list of files
357                 $files{$File::Find::name} = $mtime;
358
359                 # static rendering bits
360                 my $static_file
361                     = "$static_dir/$1/index." . $static_flavours[0];
362                 if (   param('-all')
363                     or !-f $static_file
364                     or stat($static_file)->mtime < $mtime )
365                 {
366                     $indexes{$1} = 1;
367                     $d = join( '/', ( nice_date($mtime) )[ 5, 2, 3 ] );
368                     $indexes{$d} = $d;
369                     $indexes{ ( $1 ? "$1/" : '' ) . "$2.$file_extension" } = 1
370                         if $static_entries;
371                 }
372             }
373
374             # not an entries match
375             elsif ( !-d $File::Find::name and -r $File::Find::name ) {
376                 $others{$File::Find::name} = stat($File::Find::name)->mtime;
377             }
378         },
379         $datadir
380     );
381
382     return ( \%files, \%indexes, \%others );
383 };
384
385 # Plugins: Entries
386 # Allow for the first encountered plugin::entries subroutine to override the
387 # default built-in entries subroutine
388 foreach my $plugin (@plugins) {
389     if ( $plugins{$plugin} > 0 and $plugin->can('entries') ) {
390         if ( my $tmp = $plugin->entries() ) {
391             $entries = $tmp;
392             last;
393         }
394     }
395 }
396
397 my ( $files, $indexes, $others ) = &$entries();
398 %indexes = %$indexes;
399
400 # Static
401 if (    !$ENV{GATEWAY_INTERFACE}
402     and param('-password')
403     and $static_password
404     and param('-password') eq $static_password )
405 {
406
407     param('-quiet') or print "Blosxom is generating static index pages...\n";
408
409     # Home Page and Directory Indexes
410     my %done;
411     foreach my $path ( sort keys %indexes ) {
412         my $p = '';
413         foreach ( ( '', split /\//, $path ) ) {
414             $p .= "/$_";
415             $p =~ s!^/!!;
416             next if $done{$p}++;
417             mkdir "$static_dir/$p", 0755
418                 unless ( -d "$static_dir/$p" or $p =~ /\.$file_extension$/ );
419             foreach $flavour (@static_flavours) {
420                 my $content_type
421                     = ( &$template( $p, 'content_type', $flavour ) );
422                 $content_type =~ s!\n.*!!s;
423                 my $fn = $p =~ m!^(.+)\.$file_extension$! ? $1 : "$p/index";
424                 param('-quiet') or print "$fn.$flavour\n";
425                 my $fh_w = new FileHandle "> $static_dir/$fn.$flavour"
426                     or die "Couldn't open $static_dir/$p for writing: $!";
427                 $output = '';
428                 if ( $indexes{$path} == 1 ) {
429
430                     # category
431                     $path_info = $p;
432
433                     # individual story
434                     $path_info =~ s!\.$file_extension$!\.$flavour!;
435                     print $fh_w &generate( 'static', $path_info, '', $flavour,
436                         $content_type );
437                 }
438                 else {
439
440                     # date
441                     local (
442                         $path_info_yr, $path_info_mo,
443                         $path_info_da, $path_info
444                     ) = split /\//, $p, 4;
445                     unless ( defined $path_info ) { $path_info = "" }
446                     print $fh_w &generate( 'static', '', $p, $flavour,
447                         $content_type );
448                 }
449                 $fh_w->close;
450             }
451         }
452     }
453 }
454
455 # Dynamic
456 else {
457     my $content_type = ( &$template( $path_info, 'content_type', $flavour ) );
458     $content_type =~ s!\n.*!!s;
459
460     $content_type =~ s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
461     $header = { -type => $content_type };
462
463     print generate( 'dynamic', $path_info,
464         "$path_info_yr/$path_info_mo_num/$path_info_da",
465         $flavour, $content_type );
466 }
467
468 # Plugins: End
469 foreach my $plugin (@plugins) {
470     if ( $plugins{$plugin} > 0 and $plugin->can('end') ) {
471         $entries = $plugin->end();
472     }
473 }
474
475 # Generate
476 sub generate {
477     my ( $static_or_dynamic, $currentdir, $date, $flavour, $content_type )
478         = @_;
479
480     %files = %$files;
481     %others = ref $others ? %$others : ();
482
483     # Plugins: Filter
484     foreach my $plugin (@plugins) {
485         if ( $plugins{$plugin} > 0 and $plugin->can('filter') ) {
486             $entries = $plugin->filter( \%files, \%others );
487         }
488     }
489
490     my %f = %files;
491
492     # Plugins: Skip
493     # Allow plugins to decide if we can cut short story generation
494     my $skip;
495     foreach my $plugin (@plugins) {
496         if ( $plugins{$plugin} > 0 and $plugin->can('skip') ) {
497             if ( my $tmp = $plugin->skip() ) {
498                 $skip = $tmp;
499                 last;
500             }
501         }
502     }
503
504     # Define default interpolation subroutine
505     $interpolate = sub {
506
507         package blosxom;
508         my $template = shift;
509         $template =~ s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
510         return $template;
511     };
512
513     unless ( defined($skip) and $skip ) {
514
515         # Plugins: Interpolate
516         # Allow for the first encountered plugin::interpolate subroutine to
517         # override the default built-in interpolate subroutine
518         foreach my $plugin (@plugins) {
519             if ( $plugins{$plugin} > 0 and $plugin->can('interpolate') ) {
520                 if ( my $tmp = $plugin->interpolate() ) {
521                     $interpolate = $tmp;
522                     last;
523                 }
524             }
525         }
526
527         # Head
528         my $head = ( &$template( $currentdir, 'head', $flavour ) );
529
530         # Plugins: Head
531         foreach my $plugin (@plugins) {
532             if ( $plugins{$plugin} > 0 and $plugin->can('head') ) {
533                 $entries = $plugin->head( $currentdir, \$head );
534             }
535         }
536
537         $head = &$interpolate($head);
538
539         $output .= $head;
540
541         # Stories
542         my $curdate = '';
543         my $ne      = $num_entries;
544
545         if ( $currentdir =~ /(.*?)([^\/]+)\.(.+)$/ and $2 ne 'index' ) {
546             $currentdir = "$1$2.$file_extension";
547             %f = ( "$datadir/$currentdir" => $files{"$datadir/$currentdir"} )
548                 if $files{"$datadir/$currentdir"};
549         }
550         else {
551             $currentdir =~ s!/index\..+$!!;
552         }
553
554         # Define a default sort subroutine
555         my $sort = sub {
556             my ($files_ref) = @_;
557             return
558                 sort { $files_ref->{$b} <=> $files_ref->{$a} }
559                 keys %$files_ref;
560         };
561
562      # Plugins: Sort
563      # Allow for the first encountered plugin::sort subroutine to override the
564      # default built-in sort subroutine
565         foreach my $plugin (@plugins) {
566             if ( $plugins{$plugin} > 0 and $plugin->can('sort') ) {
567                 if ( my $tmp = $plugin->sort() ) {
568                     $sort = $tmp;
569                     last;
570                 }
571             }
572         }
573
574         foreach my $path_file ( &$sort( \%f, \%others ) ) {
575             last if $ne <= 0 && $date !~ /\d/;
576             use vars qw/ $path $fn /;
577             ( $path, $fn )
578                 = $path_file =~ m!^$datadir/(?:(.*)/)?(.*)\.$file_extension!;
579
580             # Only stories in the right hierarchy
581             $path =~ /^$currentdir/
582                 or $path_file eq "$datadir/$currentdir"
583                 or next;
584
585             # Prepend a slash for use in templates only if a path exists
586             $path &&= "/$path";
587
588             # Date fiddling for by-{year,month,day} archive views
589             use vars
590                 qw/ $dw $mo $mo_num $da $ti $yr $hr $min $hr12 $ampm $utc_offset/;
591             ( $dw, $mo, $mo_num, $da, $ti, $yr, $utc_offset )
592                 = nice_date( $files{"$path_file"} );
593             ( $hr, $min ) = split /:/, $ti;
594             ( $hr12, $ampm ) = $hr >= 12 ? ( $hr - 12, 'pm' ) : ( $hr, 'am' );
595             $hr12 =~ s/^0//;
596             if ( $hr12 == 0 ) { $hr12 = 12 }
597
598             # Only stories from the right date
599             my ( $path_info_yr, $path_info_mo_num, $path_info_da )
600                 = split /\//, $date;
601             next if $path_info_yr     && $yr != $path_info_yr;
602             last if $path_info_yr     && $yr < $path_info_yr;
603             next if $path_info_mo_num && $mo ne $num2month[$path_info_mo_num];
604             next if $path_info_da     && $da != $path_info_da;
605             last if $path_info_da     && $da < $path_info_da;
606
607             # Date
608             my $date = ( &$template( $path, 'date', $flavour ) );
609
610             # Plugins: Date
611             foreach my $plugin (@plugins) {
612                 if ( $plugins{$plugin} > 0 and $plugin->can('date') ) {
613                     $entries
614                         = $plugin->date( $currentdir, \$date,
615                         $files{$path_file}, $dw, $mo, $mo_num, $da, $ti,
616                         $yr );
617                 }
618             }
619
620             $date = &$interpolate($date);
621
622             if ( $date && $curdate ne $date ) {
623                 $curdate = $date;
624                 $output .= $date;
625             }
626
627             use vars qw/ $title $body $raw /;
628             if ( -f "$path_file" && $fh->open("< $path_file") ) {
629                 chomp( $title = <$fh> );
630                 chomp( $body = join '', <$fh> );
631                 $fh->close;
632                 $raw = "$title\n$body";
633             }
634             my $story = ( &$template( $path, 'story', $flavour ) );
635
636             # Plugins: Story
637             foreach my $plugin (@plugins) {
638                 if ( $plugins{$plugin} > 0 and $plugin->can('story') ) {
639                     $entries = $plugin->story( $path, $fn, \$story, \$title,
640                         \$body );
641                 }
642             }
643
644             if ( $content_type =~ m{\bxml\b} ) {
645
646                 # Escape <, >, and &, and to produce valid RSS
647                 my %escape = (
648                     '<' => '&lt;',
649                     '>' => '&gt;',
650                     '&' => '&amp;',
651                     '"' => '&quot;'
652                 );
653                 my $escape_re = join '|' => keys %escape;
654                 $title =~ s/($escape_re)/$escape{$1}/g;
655                 $body  =~ s/($escape_re)/$escape{$1}/g;
656             }
657
658             $story = &$interpolate($story);
659
660             $output .= $story;
661             $fh->close;
662
663             $ne--;
664         }
665
666         # Foot
667         my $foot = ( &$template( $currentdir, 'foot', $flavour ) );
668
669         # Plugins: Foot
670         foreach my $plugin (@plugins) {
671             if ( $plugins{$plugin} > 0 and $plugin->can('foot') ) {
672                 $entries = $plugin->foot( $currentdir, \$foot );
673             }
674         }
675
676         $foot = &$interpolate($foot);
677         $output .= $foot;
678
679         # Plugins: Last
680         foreach my $plugin (@plugins) {
681             if ( $plugins{$plugin} > 0 and $plugin->can('last') ) {
682                 $entries = $plugin->last();
683             }
684         }
685
686     }    # End skip
687
688     # Finally, add the header, if any and running dynamically
689     $output = header($header) . $output
690         if ( $static_or_dynamic eq 'dynamic' and $header );
691
692     $output;
693 }
694
695 sub nice_date {
696     my ($unixtime) = @_;
697
698     my $c_time = CORE::localtime($unixtime);
699     my ( $dw, $mo, $da, $hr, $min, $yr )
700         = ( $c_time
701             =~ /(\w{3}) +(\w{3}) +(\d{1,2}) +(\d{2}):(\d{2}):\d{2} +(\d{4})$/
702         );
703     $ti = "$hr:$min";
704     $da = sprintf( "%02d", $da );
705     my $mo_num = $month2num{$mo};
706
707     my $offset
708         = timegm( 00, $min, $hr, $da, $mo_num - 1, $yr - 1900 ) - $unixtime;
709     my $utc_offset = sprintf( "%+03d", int( $offset / 3600 ) )
710         . sprintf( "%02d", ( $offset % 3600 ) / 60 );
711
712     return ( $dw, $mo, $mo_num, $da, $ti, $yr, $utc_offset );
713 }
714
715 # Default HTML and RSS template bits
716 __DATA__
717 html content_type text/html; charset=$blog_encoding
718
719 html head <html>
720 html head     <head>
721 html head         <meta http-equiv="content-type" content="text/html;charset=$blog_encoding" />
722 html head         <link rel="alternate" type="type="application/rss+xml" title="RSS" href="$url/index.rss" />
723 html head         <title>$blog_title $path_info_da $path_info_mo $path_info_yr
724 html head         </title>
725 html head     </head>
726 html head     <body>
727 html head         <center>
728 html head             <font size="+3">$blog_title</font><br />
729 html head             $path_info_da $path_info_mo $path_info_yr
730 html head         </center>
731 html head         <p />
732
733 html story        <p>
734 html story            <a name="$fn"><b>$title</b></a><br />
735 html story            $body<br />
736 html story            <br />
737 html story            posted at: $ti | path: <a href="$url$path">$path </a> | <a href="$url/$yr/$mo_num/$da#$fn">permanent link to this entry</a>
738 html story        </p>
739
740 html date         <h3>$dw, $da $mo $yr</h3>
741
742 html foot
743 html foot         <p />
744 html foot         <center>
745 html foot             <a href="http://blosxom.sourceforge.net/"><img src="http://blosxom.sourceforge.net/images/pb_blosxom.gif" border="0" /></a>
746 html foot         </center>
747 html foot     </body>
748 html foot </html>
749
750 rss content_type text/xml; charset=$blog_encoding
751
752 rss head <?xml version="1.0" encoding="$blog_encoding"?>
753 rss head <rss version="2.0">
754 rss head   <channel>
755 rss head     <title>$blog_title</title>
756 rss head     <link>$url/$path_info</link>
757 rss head     <description>$blog_description</description>
758 rss head     <language>$blog_language</language>
759 rss head     <docs>http://blogs.law.harvard.edu/tech/rss</docs>
760 rss head     <generator>blosxom/$version</generator>
761
762 rss story   <item>
763 rss story     <title>$title</title>
764 rss story     <pubDate>$dw, $da $mo $yr $ti:00 $utc_offset</pubDate>
765 rss story     <link>$url/$yr/$mo_num/$da#$fn</link>
766 rss story     <category>$path</category>
767 rss story     <guid isPermaLink="false">$path/$fn</guid>
768 rss story     <description>$body</description>
769 rss story   </item>
770
771 rss date 
772
773 rss foot   </channel>
774 rss foot </rss>
775
776 error content_type text/html
777
778 error head <html>
779 error head <body>
780 error head     <p><font color="red">Error: I'm afraid this is the first I've heard of a "$flavour" flavoured Blosxom.  Try dropping the "/+$flavour" bit from the end of the URL.</font></p>
781
782
783 error story <p><b>$title</b><br />
784 error story $body <a href="$url/$yr/$mo_num/$da#fn.$default_flavour">#</a></p>
785
786 error date <h3>$dw, $da $mo $yr</h3>
787
788 error foot     </body>
789 error foot </html>
790 __END__
791