Avoid "conditional and" for running plugins "end"
[pkg/blosxom.git] / blosxom.cgi
1 #!/usr/bin/perl
2
3 # Blosxom
4 # Author: Rael Dornfest <rael@oreilly.com>
5 # Version: 2.0.2
6 # Home/Docs/Licensing: http://blosxom.sourceforge.net/
7 # Development/Downloads: http://sourceforge.net/projects/blosxom
8
9 package blosxom;
10
11 # --- Configurable variables -----
12
13 # What's this blog's title?
14 $blog_title = "My Weblog";
15
16 # What's this blog's description (for outgoing RSS feed)?
17 $blog_description = "Yet another Blosxom weblog.";
18
19 # What's this blog's primary language (for outgoing RSS feed)?
20 $blog_language = "en";
21
22 # What's this blog's text encoding ?
23 $blog_encoding = "UTF-8";
24
25 # Where are this blog's entries kept?
26 $datadir = "/Library/WebServer/Documents/blosxom";
27
28 # What's my preferred base URL for this blog (leave blank for automatic)?
29 $url = "";
30
31 # Should I stick only to the datadir for items or travel down the
32 # directory hierarchy looking for items?  If so, to what depth?
33 # 0 = infinite depth (aka grab everything), 1 = datadir only, n = n levels down
34 $depth = 0;
35
36 # How many entries should I show on the home page?
37 $num_entries = 40;
38
39 # What file extension signifies a blosxom entry?
40 $file_extension = "txt";
41
42 # What is the default flavour?
43 $default_flavour = "html";
44
45 # Should I show entries from the future (i.e. dated after now)?
46 $show_future_entries = 0;
47
48 # --- Plugins (Optional) -----
49
50 # File listing plugins blosxom should load 
51 # (if empty blosxom will load all plugins in $plugin_path directories)
52 $plugin_list = "";
53
54 # Where are my plugins kept? 
55 # List of directories, separated by ';' on windows, ':' everywhere else
56 $plugin_path = "";
57
58 # Where should my plugins keep their state information?
59 $plugin_state_dir = "";
60 #$plugin_state_dir = "/var/lib/blosxom/state";
61
62 # --- Static Rendering -----
63
64 # Where are this blog's static files to be created?
65 $static_dir = "/Library/WebServer/Documents/blog";
66
67 # What's my administrative password (you must set this for static rendering)?
68 $static_password = "";
69
70 # What flavours should I generate statically?
71 @static_flavours = qw/html rss/;
72
73 # Should I statically generate individual entries?
74 # 0 = no, 1 = yes
75 $static_entries = 0;
76
77 # --------------------------------
78
79 use vars qw! $version $blog_title $blog_description $blog_language $blog_encoding $datadir $url %template $template $depth $num_entries $file_extension $default_flavour $static_or_dynamic $config_dir $plugin_list $plugin_path $plugin_dir $plugin_state_dir @plugins %plugins $static_dir $static_password @static_flavours $static_entries $path_info $path_info_yr $path_info_mo $path_info_da $path_info_mo_num $flavour $static_or_dynamic %month2num @num2month $interpolate $entries $output $header $show_future_entries %files %indexes %others !;
80
81 use strict;
82 use FileHandle;
83 use File::Find;
84 use File::stat;
85 use Time::localtime;
86 use Time::Local;
87 use CGI qw/:standard :netscape/;
88
89 $version = "2.0.2";
90
91 # Load configuration from $ENV{BLOSXOM_CONFIG_DIR}/blosxom.conf, if it exists
92 my $blosxom_config;
93 if ($ENV{BLOSXOM_CONFIG_FILE} && -r $ENV{BLOSXOM_CONFIG_FILE}) {
94   $blosxom_config = $ENV{BLOSXOM_CONFIG_FILE};
95   ($config_dir = $blosxom_config) =~ s! / [^/]* $ !!x;                          
96 }
97 else {
98   for my $blosxom_config_dir ($ENV{BLOSXOM_CONFIG_DIR}, '/etc/blosxom', '/etc') {
99     if (-r "$blosxom_config_dir/blosxom.conf") {
100       $config_dir = $blosxom_config_dir;
101       $blosxom_config = "$blosxom_config_dir/blosxom.conf";
102       last;
103     }
104   }
105 }
106 # Load $blosxom_config
107 if ($blosxom_config) { 
108   if (-r $blosxom_config) {
109     eval { require $blosxom_config } or
110       warn "Error reading blosxom config file '$blosxom_config'" . ($@ ? ": $@" : '');
111   }
112   else {
113     warn "Cannot find or read blosxom config file '$blosxom_config'";
114   }
115 }
116
117 my $fh = new FileHandle;
118
119 %month2num = (nil=>'00', Jan=>'01', Feb=>'02', Mar=>'03', Apr=>'04', May=>'05', Jun=>'06', Jul=>'07', Aug=>'08', Sep=>'09', Oct=>'10', Nov=>'11', Dec=>'12');
120 @num2month = sort { $month2num{$a} <=> $month2num{$b} } keys %month2num;
121
122 # Use the stated preferred URL or figure it out automatically
123 $url ||= url(-path_info => 1);
124 $url =~ s/^included:/http:/ if $ENV{SERVER_PROTOCOL} eq 'INCLUDED';
125
126 # NOTE: Since v3.12, it looks as if CGI.pm misbehaves for SSIs and
127 # always appends path_info to the url. To fix this, we always
128 # request an url with path_info, and always remove it from the end of the
129 # string.
130 my $pi_len = length $ENV{PATH_INFO};
131 my $might_be_pi = substr($url, -$pi_len);
132 substr($url, -length $ENV{PATH_INFO}) = '' if $might_be_pi eq $ENV{PATH_INFO};
133
134 $url =~ s!/$!!;
135
136 # Drop ending any / from dir settings
137 $datadir =~ s!/$!!; $plugin_dir =~ s!/$!!; $static_dir =~ s!/$!!;
138   
139 # Fix depth to take into account datadir's path
140 $depth += ($datadir =~ tr[/][]) - 1 if $depth;
141
142 # Global variable to be used in head/foot.{flavour} templates
143 $path_info = '';
144
145 if (    !$ENV{GATEWAY_INTERFACE}
146     and param('-password')
147     and $static_password
148     and param('-password') eq $static_password )
149 {
150     $static_or_dynamic = 'static';
151 }
152 else {
153     $static_or_dynamic = 'dynamic';
154     param( -name => '-quiet', -value => 1 );
155 }
156
157 # Path Info Magic
158 # Take a gander at HTTP's PATH_INFO for optional blog name, archive yr/mo/day
159 my @path_info = split m{/}, path_info() || param('path'); 
160 shift @path_info;
161
162 while ($path_info[0] and $path_info[0] =~ /^[a-zA-Z].*$/ and $path_info[0] !~ /(.*)\.(.*)/) { $path_info .= '/' . shift @path_info; }
163
164 # Flavour specified by ?flav={flav} or index.{flav}
165 $flavour = '';
166
167 if ( $path_info[$#path_info] =~ /(.+)\.(.+)$/ ) {
168   $flavour = $2;
169   $path_info .= "/$1.$2" if $1 ne 'index';
170   pop @path_info;
171 } else {
172   $flavour = param('flav') || $default_flavour;
173 }
174
175 # Strip spurious slashes
176 $path_info =~ s!(^/*)|(/*$)!!g;
177
178 # Date fiddling
179 ($path_info_yr,$path_info_mo,$path_info_da) = @path_info;
180 $path_info_mo_num = $path_info_mo ? ( $path_info_mo =~ /\d{2}/ ? $path_info_mo : ($month2num{ucfirst(lc $path_info_mo)} || undef) ) : undef;
181
182 # Define standard template subroutine, plugin-overridable at Plugins: Template
183 $template = 
184   sub {
185     my ($path, $chunk, $flavour) = @_;
186
187     do {
188       return join '', <$fh> if $fh->open("< $datadir/$path/$chunk.$flavour");
189     } while ($path =~ s/(\/*[^\/]*)$// and $1);
190
191     # Check for definedness, since flavour can be the empty string
192     if (defined $template{$flavour}{$chunk}) {
193         return $template{$flavour}{$chunk};
194     } elsif (defined $template{error}{$chunk}) {
195         return $template{error}{$chunk} 
196     } else {
197         return '';
198     }
199   };
200 # Bring in the templates
201 %template = ();
202 while (<DATA>) {
203   last if /^(__END__)$/;
204   my($ct, $comp, $txt) = /^(\S+)\s(\S+)(?:\s(.*))?$/ or next;
205   $txt =~ s/\\n/\n/mg;
206   $template{$ct}{$comp} .= $txt . "\n";
207 }
208
209 # Plugins: Start
210 my $path_sep = $^O eq 'MSWin32' ? ';' : ':';
211 my @plugin_dirs = split /$path_sep/, ($plugin_path || $plugin_dir);
212 my @plugin_list = ();
213 my %plugin_hash = ();
214
215 # If $plugin_list is set, read plugins to use from that file
216 $plugin_list = "$config_dir/$plugin_list"
217   if $plugin_list && $plugin_list !~ m!^\s*/!;
218 if ( $plugin_list and -r $plugin_list and $fh->open("< $plugin_list") ) {
219   @plugin_list = map { chomp $_; $_ } grep { /\S/ && ! /^#/ } <$fh>; 
220   $fh->close;
221 }
222 # Otherwise walk @plugin_dirs to get list of plugins to use
223 elsif ( @plugin_dirs ) {
224   for my $plugin_dir ( @plugin_dirs ) {
225     next unless -d $plugin_dir;
226     if ( opendir PLUGINS, $plugin_dir ) {
227       for my $plugin ( grep { /^[\w:]+$/ && ! /~$/ && -f "$plugin_dir/$_" } readdir(PLUGINS) ) {
228         # Ignore duplicates
229         next if $plugin_hash{ $plugin };
230         # Add to @plugin_list and %plugin_hash
231         $plugin_hash{ $plugin } = "$plugin_dir/$plugin";
232         push @plugin_list, $plugin;
233       }
234       closedir PLUGINS;
235     }
236   }
237   @plugin_list = sort @plugin_list;
238 }
239
240 # Load all plugins in @plugin_list
241 unshift @INC, @plugin_dirs;
242 foreach my $plugin ( @plugin_list ) {
243   my($plugin_name, $off) = $plugin =~ /^\d*([\w:]+?)(_?)$/;
244   my $on_off = $off eq '_' ? -1 : 1;
245   # Allow perl module plugins
246   if ($plugin =~ m/::/ && -z $plugin_hash{ $plugin }) {
247     # For Blosxom::Plugin::Foo style plugins, we need to use a string require
248     eval "require $plugin_name";
249   }
250   else {
251     eval { require $plugin };
252   }
253   $@ and warn "$@ error finding or loading blosxom plugin $plugin_name - skipping\n" and next;
254   $plugin_name->start() and ( $plugins{$plugin_name} = $on_off ) and push @plugins, $plugin_name;
255 }
256 shift @INC foreach @plugin_dirs;
257
258 # Plugins: Template
259 # Allow for the first encountered plugin::template subroutine to override the
260 # default built-in template subroutine
261 foreach my $plugin (@plugins) {
262     if ( $plugins{$plugin} > 0 and $plugin->can('template') ) {
263         if ( my $tmp = $plugin->template() ) {
264             $template = $tmp;
265             last;
266         }
267     }
268 }
269
270 # Provide backward compatibility for Blosxom < 2.0rc1 plug-ins
271 sub load_template {
272   return &$template(@_);
273 }
274
275 # Define default entries subroutine
276 $entries =
277   sub {
278     my(%files, %indexes, %others);
279     find(
280       sub {
281         my $d; 
282         my $curr_depth = $File::Find::dir =~ tr[/][]; 
283         return if $depth and $curr_depth > $depth; 
284      
285         if ( 
286           # a match
287           $File::Find::name =~ m!^$datadir/(?:(.*)/)?(.+)\.$file_extension$!
288           # not an index, .file, and is readable
289           and $2 ne 'index' and $2 !~ /^\./ and (-r $File::Find::name)
290         ) {
291             # read modification time
292             my $mtime = stat($File::Find::name)->mtime or return;
293
294
295             # to show or not to show future entries
296             return unless ($show_future_entries or $mtime < time);
297
298               # add the file and its associated mtime to the list of files
299             $files{$File::Find::name} = $mtime;
300
301                 # static rendering bits
302             my $static_file = "$static_dir/$1/index." . $static_flavours[0];
303             if (param('-all')
304                 or !-f $static_file
305                 or stat($static_file)->mtime < $mtime)
306              {
307               $indexes{$1} = 1;
308               $d = join('/', (nice_date($mtime))[5,2,3]);
309               $indexes{$d} = $d;
310               $indexes{ ($1 ? "$1/" : '') . "$2.$file_extension" } = 1 if $static_entries;
311               }
312           }
313           # not an entries match
314           elsif (!-d $File::Find::name and -r $File::Find::name)
315           {
316             $others{$File::Find::name} = stat($File::Find::name)->mtime;
317           }
318       }, $datadir
319     );
320
321     return (\%files, \%indexes, \%others);
322   };
323
324 # Plugins: Entries
325 # Allow for the first encountered plugin::entries subroutine to override the
326 # default built-in entries subroutine
327 foreach my $plugin (@plugins) {
328     if ( $plugins{$plugin} > 0 and $plugin->can('entries') ) {
329         if ( my $tmp = $plugin->entries() ) {
330             $entries = $tmp;
331             last;
332         }
333     }
334 }
335
336 my ($files, $indexes, $others) = &$entries();
337 %indexes = %$indexes;
338
339 # Static
340 if (!$ENV{GATEWAY_INTERFACE} and param('-password') and $static_password and param('-password') eq $static_password) {
341
342   param('-quiet') or print "Blosxom is generating static index pages...\n";
343
344   # Home Page and Directory Indexes
345   my %done;
346   foreach my $path ( sort keys %indexes) {
347     my $p = '';
348     foreach ( ('', split /\//, $path) ) {
349       $p .= "/$_";
350       $p =~ s!^/!!;
351       next if $done{$p}++;
352       mkdir "$static_dir/$p", 0755 unless (-d "$static_dir/$p" or $p =~ /\.$file_extension$/);
353       foreach $flavour ( @static_flavours ) {
354         my $content_type = (&$template($p,'content_type',$flavour));
355         $content_type =~ s!\n.*!!s;
356         my $fn = $p =~ m!^(.+)\.$file_extension$! ? $1 : "$p/index";
357         param('-quiet') or print "$fn.$flavour\n";
358         my $fh_w = new FileHandle "> $static_dir/$fn.$flavour" or die "Couldn't open $static_dir/$p for writing: $!";  
359         $output = '';
360         if ($indexes{$path} == 1) {
361           # category
362           $path_info = $p;
363           # individual story
364           $path_info =~ s!\.$file_extension$!\.$flavour!;
365           print $fh_w &generate('static', $path_info, '', $flavour, $content_type);
366         } else {
367           # date
368           local ($path_info_yr,$path_info_mo,$path_info_da, $path_info) = 
369               split /\//, $p, 4;
370           unless (defined $path_info) {$path_info = ""};
371           print $fh_w &generate('static', '', $p, $flavour, $content_type);
372         }
373         $fh_w->close;
374       }
375     }
376   }
377 }
378
379 # Dynamic
380 else {
381   my $content_type = (&$template($path_info,'content_type',$flavour));
382   $content_type =~ s!\n.*!!s;
383
384   $content_type =~ s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
385   $header = {-type=>$content_type};
386
387   print generate('dynamic', $path_info, "$path_info_yr/$path_info_mo_num/$path_info_da", $flavour, $content_type);
388 }
389
390 # Plugins: End
391 foreach my $plugin (@plugins) {
392     if ( $plugins{$plugin} > 0 and $plugin->can('end') ) {
393         $entries = $plugin->end();
394     }
395 }
396
397 # Generate 
398 sub generate {
399   my($static_or_dynamic, $currentdir, $date, $flavour, $content_type) = @_;
400
401   %files = %$files; %others = ref $others ? %$others : ();
402
403   # Plugins: Filter
404   foreach my $plugin ( @plugins ) {
405   if ($plugins{$plugin} > 0 and $plugin->can('filter')){ $entries = $plugin->filter(\%files, \%others); }
406   }
407
408   my %f = %files;
409
410   # Plugins: Skip
411   # Allow plugins to decide if we can cut short story generation
412   my $skip;
413   foreach my $plugin (@plugins) {
414       if ( $plugins{$plugin} > 0 and $plugin->can('skip') ) {
415           if ( my $tmp = $plugin->skip() ) {
416               $skip = $tmp;
417               last;
418           }
419       }
420   }
421
422   
423   # Define default interpolation subroutine
424   $interpolate = 
425     sub {
426       package blosxom;
427       my $template = shift;
428       $template =~ 
429         s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
430       return $template;
431     };  
432
433   unless (defined($skip) and $skip) {
434
435     # Plugins: Interpolate
436     # Allow for the first encountered plugin::interpolate subroutine to 
437     # override the default built-in interpolate subroutine
438     foreach my $plugin (@plugins) {
439         if ( $plugins{$plugin} > 0 and $plugin->can('interpolate') ) {
440             if ( my $tmp = $plugin->interpolate() ) {
441                 $interpolate = $tmp;
442                 last;
443             }
444         }
445     }
446         
447     # Head
448     my $head = (&$template($currentdir,'head',$flavour));
449   
450     # Plugins: Head
451     foreach my $plugin (@plugins) {
452         if ( $plugins{$plugin} > 0 and $plugin->can('head') ) {
453             $entries = $plugin->head( $currentdir, \$head );
454         }
455     }
456   
457     $head = &$interpolate($head);
458   
459     $output .= $head;
460     
461     # Stories
462     my $curdate = '';
463     my $ne = $num_entries;
464
465     if ( $currentdir =~ /(.*?)([^\/]+)\.(.+)$/ and $2 ne 'index' ) {
466       $currentdir = "$1$2.$file_extension";
467       %f = ( "$datadir/$currentdir" => $files{"$datadir/$currentdir"} ) if $files{"$datadir/$currentdir"};
468     } 
469     else { 
470       $currentdir =~ s!/index\..+$!!;
471     }
472
473     # Define a default sort subroutine
474     my $sort = sub {
475       my($files_ref) = @_;
476       return sort { $files_ref->{$b} <=> $files_ref->{$a} } keys %$files_ref;
477     };
478   
479     # Plugins: Sort
480     # Allow for the first encountered plugin::sort subroutine to override the
481     # default built-in sort subroutine
482     foreach my $plugin (@plugins) {
483         if ( $plugins{$plugin} > 0 and $plugin->can('sort') ) {
484             if ( my $tmp = $plugin->sort() ) {
485                 $sort = $tmp;
486                 last;
487             }
488         }
489     }
490   
491     foreach my $path_file ( &$sort(\%f, \%others) ) {
492       last if $ne <= 0 && $date !~ /\d/;
493       use vars qw/ $path $fn /;
494       ($path,$fn) = $path_file =~ m!^$datadir/(?:(.*)/)?(.*)\.$file_extension!;
495   
496       # Only stories in the right hierarchy
497       $path =~ /^$currentdir/ or $path_file eq "$datadir/$currentdir" or next;
498   
499       # Prepend a slash for use in templates only if a path exists
500       $path &&= "/$path";
501
502       # Date fiddling for by-{year,month,day} archive views
503       use vars qw/ $dw $mo $mo_num $da $ti $yr $hr $min $hr12 $ampm $utc_offset/;
504       ($dw,$mo,$mo_num,$da,$ti,$yr,$utc_offset) = nice_date($files{"$path_file"});
505       ($hr,$min) = split /:/, $ti;
506       ($hr12, $ampm) = $hr >= 12 ? ($hr - 12,'pm') : ($hr, 'am'); 
507       $hr12 =~ s/^0//; $hr12 == 0 and $hr12 = 12;
508   
509       # Only stories from the right date
510       my($path_info_yr,$path_info_mo_num, $path_info_da) = split /\//, $date;
511       next if $path_info_yr && $yr != $path_info_yr; last if $path_info_yr && $yr < $path_info_yr; 
512       next if $path_info_mo_num && $mo ne $num2month[$path_info_mo_num];
513       next if $path_info_da && $da != $path_info_da; last if $path_info_da && $da < $path_info_da; 
514   
515       # Date 
516       my $date = (&$template($path,'date',$flavour));
517       
518       # Plugins: Date
519       foreach my $plugin (@plugins) {
520           if ( $plugins{$plugin} > 0 and $plugin->can('date') ) {
521               $entries
522                   = $plugin->date( $currentdir, \$date, $files{$path_file}, $dw,
523                   $mo, $mo_num, $da, $ti, $yr );
524           }
525       }
526   
527       $date = &$interpolate($date);
528   
529       if ( $date && $curdate ne $date ) {
530           $curdate = $date;
531           $output .= $date;
532       }
533       
534       use vars qw/ $title $body $raw /;
535       if (-f "$path_file" && $fh->open("< $path_file")) {
536         chomp($title = <$fh>);
537         chomp($body = join '', <$fh>);
538         $fh->close;
539         $raw = "$title\n$body";
540       }
541       my $story = (&$template($path,'story',$flavour));
542   
543       # Plugins: Story
544       foreach my $plugin (@plugins) {
545           if ( $plugins{$plugin} > 0 and $plugin->can('story') ) {
546               $entries = $plugin->story( $path, $fn, \$story, \$title, \$body );
547           }
548       }
549       
550       if ($content_type =~ m{\bxml\b}) {
551         # Escape <, >, and &, and to produce valid RSS
552         my %escape = ('<'=>'&lt;', '>'=>'&gt;', '&'=>'&amp;', '"'=>'&quot;');  
553         my $escape_re  = join '|' => keys %escape;
554         $title =~ s/($escape_re)/$escape{$1}/g;
555         $body =~ s/($escape_re)/$escape{$1}/g;
556       }
557   
558       $story = &$interpolate($story);
559     
560       $output .= $story;
561       $fh->close;
562   
563       $ne--;
564     }
565   
566     # Foot
567     my $foot = (&$template($currentdir,'foot',$flavour));
568   
569     # Plugins: Foot
570     foreach my $plugin (@plugins) {
571         if ( $plugins{$plugin} > 0 and $plugin->can('foot') ) {
572             $entries = $plugin->foot( $currentdir, \$foot );
573         }
574     }
575   
576     $foot = &$interpolate($foot);
577     $output .= $foot;
578
579     # Plugins: Last
580     foreach my $plugin (@plugins) {
581         if ( $plugins{$plugin} > 0 and $plugin->can('last') ) {
582             $entries = $plugin->last();
583         }
584     }
585
586   } # End skip
587
588   # Finally, add the header, if any and running dynamically
589   $output = header($header) . $output if ($static_or_dynamic eq 'dynamic' and $header);
590   
591   $output;
592 }
593
594
595 sub nice_date {
596   my($unixtime) = @_;
597   
598   my $c_time = ctime($unixtime);
599   my($dw,$mo,$da,$hr,$min,$yr) = ( $c_time =~ /(\w{3}) +(\w{3}) +(\d{1,2}) +(\d{2}):(\d{2}):\d{2} +(\d{4})$/ );
600   $ti="$hr:$min";
601   $da = sprintf("%02d", $da);
602   my $mo_num = $month2num{$mo};
603
604   my $offset = timegm(00, $min, $hr, $da, $mo_num-1, $yr-1900)-$unixtime;  
605   my $utc_offset = sprintf("%+03d", int($offset / 3600)).sprintf("%02d", ($offset % 3600)/60) ;
606
607   return ($dw,$mo,$mo_num,$da,$ti,$yr,$utc_offset);
608 }
609
610
611 # Default HTML and RSS template bits
612 __DATA__
613 html content_type text/html; charset=$blog_encoding
614
615 html head <html>
616 html head     <head>
617 html head         <meta http-equiv="content-type" content="text/html;charset=$blog_encoding" />
618 html head         <link rel="alternate" type="type="application/rss+xml" title="RSS" href="$url/index.rss" />
619 html head         <title>$blog_title $path_info_da $path_info_mo $path_info_yr
620 html head         </title>
621 html head     </head>
622 html head     <body>
623 html head         <center>
624 html head             <font size="+3">$blog_title</font><br />
625 html head             $path_info_da $path_info_mo $path_info_yr
626 html head         </center>
627 html head         <p />
628
629 html story        <p>
630 html story            <a name="$fn"><b>$title</b></a><br />
631 html story            $body<br />
632 html story            <br />
633 html story            posted at: $ti | path: <a href="$url$path">$path </a> | <a href="$url/$yr/$mo_num/$da#$fn">permanent link to this entry</a>
634 html story        </p>
635
636 html date         <h3>$dw, $da $mo $yr</h3>
637
638 html foot
639 html foot         <p />
640 html foot         <center>
641 html foot             <a href="http://blosxom.sourceforge.net/"><img src="http://blosxom.sourceforge.net/images/pb_blosxom.gif" border="0" /></a>
642 html foot         </center>
643 html foot     </body>
644 html foot </html>
645
646 rss content_type text/xml; charset=$blog_encoding
647
648 rss head <?xml version="1.0" encoding="$blog_encoding"?>
649 rss head <rss version="2.0">
650 rss head   <channel>
651 rss head     <title>$blog_title</title>
652 rss head     <link>$url/$path_info</link>
653 rss head     <description>$blog_description</description>
654 rss head     <language>$blog_language</language>
655 rss head     <docs>http://blogs.law.harvard.edu/tech/rss</docs>
656 rss head     <generator>blosxom/$version</generator>
657
658 rss story   <item>
659 rss story     <title>$title</title>
660 rss story     <pubDate>$dw, $da $mo $yr $ti:00 $utc_offset</pubDate>
661 rss story     <link>$url/$yr/$mo_num/$da#$fn</link>
662 rss story     <category>$path</category>
663 rss story     <guid isPermaLink="false">$path/$fn</guid>
664 rss story     <description>$body</description>
665 rss story   </item>
666
667 rss date 
668
669 rss foot   </channel>
670 rss foot </rss>
671
672 error content_type text/html
673
674 error head <html>
675 error head <body>
676 error head     <p><font color="red">Error: I'm afraid this is the first I've heard of a "$flavour" flavoured Blosxom.  Try dropping the "/+$flavour" bit from the end of the URL.</font></p>
677
678
679 error story <p><b>$title</b><br />
680 error story $body <a href="$url/$yr/$mo_num/$da#fn.$default_flavour">#</a></p>
681
682 error date <h3>$dw, $da $mo $yr</h3>
683
684 error foot     </body>
685 error foot </html>
686 __END__