lib/Packages/Template.pm

   1 package Packages::Template;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Template;
   7 use URI ();
   8 use HTML::Entities ();
   9 use URI::Escape ();
  10 use Benchmark ':hireswallclock';
  11
  12 use Packages::CGI;
  13 use Packages::Config qw( @LANGUAGES );
  14 use Packages::I18N::Locale;
  15 use Packages::I18N::Languages;
  16 use Packages::I18N::LanguageNames;
  17
  18 our @ISA = qw( Exporter );
  19 #our @EXPORT = qw( head );
  20
  21 use constant COMPILE => 1;
  22
  23 sub new {
  24     my ($classname, $include, $format, $vars, $options) = @_;
  25     $vars ||= {};
  26     $options ||= {};
  27
  28     my $self = {};
  29     bless( $self, $classname );
  30
  31     my @timestamp = gmtime;
  32     $vars->{timestamp} = {
  33         year => $timestamp[5]+1900,
  34         string => scalar gmtime() .' UTC',
  35     };
  36     $vars->{make_search_url} = sub { return &Packages::CGI::make_search_url(@_) };
  37     $vars->{make_url} = sub { return &Packages::CGI::make_url(@_) };
  38     if ($vars->{cat}) {
  39         $vars->{g} = sub { return Packages::I18N::Locale::g($vars->{cat}, @_) };
  40     }
  41     $vars->{extract_host} = sub { my $uri_str = $_[0];
  42                                   my $uri = URI->new($uri_str);
  43                                   if ($uri->can('host')) {
  44                                       my $host = $uri->host;
  45                                       $host .= ':'.$uri->port if $uri->port != $uri->default_port;
  46                                       return $host;
  47                                   }
  48                                   return $uri_str;
  49                               };
  50     # needed to work around the limitations of the the FILTER syntax
  51     $vars->{html_encode} = sub { return HTML::Entities::encode_entities(@_,'<>&"') };
  52     $vars->{uri_escape} = sub { return URI::Escape::uri_escape(@_) };
  53     $vars->{quotemeta} = sub { return quotemeta($_[0]) };
  54     $vars->{string2id} = sub { return &Packages::CGI::string2id(@_) };
  55
  56     $self->{template} = Template->new( {
  57         PRE_PROCESS => [ 'config.tmpl' ],
  58         INCLUDE_PATH => $include,
  59         VARIABLES => $vars,
  60         COMPILE_EXT => '.ttc',
  61         %$options,
  62     } ) or die sprintf( "Initialization of Template Engine failed: %s", $Template::ERROR );
  63     $self->{format} = $format;
  64     $self->{vars} = $vars;
  65
  66     return $self;
  67 }
  68
  69 sub process {
  70     my $self = shift;
  71     return $self->{template}->process(@_);
  72 }
  73 sub error {
  74     my $self = shift;
  75     return $self->{template}->error(@_);
  76 }
  77
  78 sub page {
  79     my ($self, $action, $page_content, $target) = @_;
  80
  81     #use Data::Dumper;
  82     #die Dumper($self, $action, $page_content);
  83     if ($page_content->{cat}) {
  84         $page_content->{g} =
  85             sub { return Packages::I18N::Locale::g($page_content->{cat}, @_) };
  86     }
  87     $page_content->{used_langs} ||= \@LANGUAGES;
  88     $page_content->{langs} = languages( $page_content->{lang}
  89                                         || $self->{vars}{lang} || 'en',
  90                                         @{$page_content->{used_langs}} );
  91
  92     my $txt;
  93     if ($target) {
  94         $self->process("$self->{format}/$action.tmpl", $page_content, $target)
  95             or die sprintf( "template error: %s", $self->error ); # too late for reporting on-line
  96     } else {
  97         $self->process("$self->{format}/$action.tmpl", $page_content, \$txt)
  98             or die sprintf( "template error: %s", $self->error );
  99     }
 100     return $txt;
 101 }
 102
 103 sub error_page {
 104     my ($self, $page_content) = @_;
 105
 106 #    use Data::Dumper;
 107 #    warn Dumper($page_content);
 108
 109     my $txt;
 110     $self->process("html/error.tmpl", $page_content, \$txt)
 111         or die sprintf( "template error: %s", $self->error ); # too late for reporting on-line
 112
 113     return $txt;
 114 }
 115
 116 sub languages {
 117     my ( $lang, @used_langs ) = @_;
 118     my $cat = Packages::I18N::Locale->get_handle($lang)
 119         || Packages::I18N::Locale->get_handle('en');
 120
 121     my @langs;
 122
 123     if (@used_langs) {
 124
 125         my @printed_langs = ();
 126         foreach (@used_langs) {
 127             next if $_ eq $lang; # Never print the current language
 128             unless (get_selfname($_)) { warn "missing language $_"; next } #DEBUG
 129             push @printed_langs, $_;
 130         }
 131         return [] unless scalar @printed_langs;
 132         # Sort on uppercase to work with languages which use lowercase initial
 133         # letters.
 134         foreach my $cur_lang (sort langcmp @printed_langs) {
 135             my %lang;
 136             $lang{lang} = $cur_lang;
 137             $lang{tooltip} = $cat->g(get_language_name($cur_lang));
 138             $lang{selfname} = get_selfname($cur_lang);
 139             $lang{transliteration} = get_transliteration($cur_lang)
 140                 if defined get_transliteration($cur_lang);
 141             push @langs, \%lang;
 142         }
 143     }
 144
 145     return \@langs;
 146 }
 147
 148 1;