lib/Packages/Page.pm

   1 package Packages::Page;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use Exporter;
   8 use Deb::Versions;
   9 use Packages::CGI;
  10
  11 our @ISA = qw( Exporter );
  12 our @EXPORT_OK = qw( split_name_mail parse_deps );
  13 our %EXPORT_TAGS = ( all => [ @EXPORT_OK ] );
  14
  15 our $ARCHIVE_DEFAULT = '';
  16 our $SECTION_DEFAULT = 'main';
  17 our $SUBSECTION_DEFAULT = 'unknown';
  18 our $PRIORITY_DEFAULT = 'unknown';
  19 our $ESSENTIAL_DEFAULT = 'no';
  20 our $MAINTAINER_DEFAULT = 'unknown <unknown@email.invalid>';
  21
  22 sub new {
  23     my $classname = shift;
  24     my $name = shift || '';
  25     my $config = shift || {};
  26
  27     my $self = {};
  28     bless( $self, $classname );
  29
  30     $self->{package} = $name;
  31     $self->{config} = $config;
  32
  33     return $self;
  34 }
  35
  36 sub merge_data {
  37     my ($self, $pkg, $version, $architecture, $data) = @_;
  38
  39     my %data = ( package => $pkg,
  40                  version => $version,
  41                  architecture => $architecture );
  42     chomp($data);
  43     while ($data =~ /^(\S+):\s*(.*)\s*$/mg) {
  44         my ($key, $value) = ($1, $2);
  45         $key =~ tr [A-Z] [a-z];
  46         $data{$key} = $value;
  47     }
  48 #       debug( "Merge package:\n".Dumper(\%data), 3 );
  49     return $self->merge_package( \%data );
  50 }
  51
  52 sub gettext { return $_[0]; }
  53 sub split_name_mail {
  54     my $string = shift;
  55     my ( $name, $email );
  56     if ($string =~ /(.*?)\s*<(.*)>/o) {
  57         $name =  $1;
  58         $email = $2;
  59     } elsif ($string =~ /^[\w.-]*@[\w.-]*$/o) {
  60         $name =  $string;
  61         $email = $string;
  62     } else {
  63         $name = gettext( 'package has bad maintainer field' );
  64         $email = '';
  65     }
  66     $name =~ s/\s+$//o;
  67     return ($name, $email);
  68 }
  69
  70 sub add_src_data {
  71     my ($self, $src, $version, $data) = @_;
  72
  73     chomp($data);
  74     my %data = ();
  75     $data =~ s/\n\s+/\377/g;
  76     while ($data =~ /^(\S+):\s*(.*)\s*$/mog) {
  77         my ($key, $value) = ($1, $2);
  78         $key =~ tr [A-Z] [a-z];
  79         $data{$key} = $value;
  80     }
  81
  82     $self->{src}{package} = $src;
  83     $self->{src}{version} = $version;
  84     if ($data{files}) {
  85         $self->{src}{files} = [];
  86         foreach my $sf ( split( /\377/, $data{files} ) ) {
  87             next unless $sf;
  88             # md5, size, name
  89             push @{$self->{src}{files}}, [ split( /\s+/, $sf) ];
  90         }
  91     }
  92     $self->{src}{directory} = $data{directory};
  93     my @uploaders;
  94     if ($data{maintainer} ||= '') {
  95         push @uploaders, [ split_name_mail( $data{maintainer} ) ];
  96     }
  97     if ($data{uploaders}) {
  98         my @up_tmp = split( /\s*,\s*/,
  99                             $data{uploaders} );
 100         foreach my $up (@up_tmp) {
 101             if ($up ne $data{maintainer}) { # weed out duplicates
 102                 push @uploaders, [ split_name_mail( $up ) ];
 103             }
 104         }
 105     }
 106     $self->{src}{uploaders} = \@uploaders;
 107
 108     return 1;
 109 }
 110
 111 our @TAKE_NEWEST = qw( description essential priority section subsection tag
 112                        archive source source-version );
 113 our @STORE_ALL = qw( version source source-version installed-size size
 114                      filename md5sum
 115                      origin bugs suite archive section );
 116 our @DEP_FIELDS = qw( depends pre-depends recommends suggests enhances
 117                       provides conflicts );
 118 sub merge_package {
 119     my ($self, $data) = @_;
 120
 121     ($data->{package} && $data->{version} && $data->{architecture}) || return;
 122     $self->{package} ||= $data->{package};
 123     ($self->{package} eq $data->{package}) || return;
 124     debug( "merge package $data->{package}/$data->{version}/$data->{architecture} into $self (".($self->{newest}||'').")", 2 );
 125
 126     unless ($self->{newest}) {
 127         debug( "package $data->{package}/$data->{version}/$data->{architecture} is first to merge", 3 );
 128         foreach my $key (@TAKE_NEWEST) {
 129             $self->{data}{$key} = $data->{$key};
 130         }
 131         foreach my $key (@STORE_ALL) {
 132             $self->{versions}{$data->{architecture}}{$key}
 133             = $data->{$key};
 134         }
 135         foreach my $key (@DEP_FIELDS) {
 136             $self->normalize_dependencies($key, $data);
 137         }
 138         $self->{newest} = $data->{version};
 139
 140         return 1;
 141     }
 142
 143     debug( "package $data->{package}/$data->{version}/$data->{architecture} is subsequent merge", 3 );
 144     my $is_newest;
 145     if ($is_newest =
 146         (version_cmp( $data->{version}, $self->{newest} ) > 0)) {
 147         $self->{newest} = $data->{version};
 148         foreach my $key (@TAKE_NEWEST) {
 149             $self->{data}{$key} = $data->{$key};
 150         }
 151     }
 152     debug( "is_newest= ".($is_newest||0), 3 );
 153     if (!$self->{versions}{$data->{architecture}}
 154         || $is_newest
 155         || (version_cmp( $data->{version},
 156                          $self->{versions}{$data->{architecture}}{version} ) > 0)) {
 157         foreach my $key (@STORE_ALL) {
 158             $self->{versions}{$data->{architecture}}{$key}
 159             = $data->{$key};
 160         }
 161         foreach my $key (@DEP_FIELDS) {
 162             $self->normalize_dependencies($key, $data);
 163         }
 164     }
 165
 166     return 1;
 167 }
 168
 169 sub normalize_dependencies {
 170     my ($self, $dep_field, $data) = @_;
 171
 172     my ($deps_norm, $deps) = parse_deps( $data->{$dep_field}||'' );
 173     $self->{dep_fields}{$data->{architecture}}{$dep_field} =
 174         [ $deps_norm, $deps ];
 175 }
 176
 177 sub parse_deps {
 178     my ($dep_str) = @_;
 179
 180     my (@dep_and_norm, @dep_and);
 181     foreach my $dep_and (split( /\s*,\s*/m, $dep_str )) {
 182         next if $dep_and =~ /^\s*$/;
 183         my (@dep_or_norm, @dep_or);
 184         foreach my $dep_or (split( /\s*\|\s*/m, $dep_and )) {
 185             my ($pkg, $relation, $version, @arches) = ('','','');
 186             $pkg = $1 if $dep_or =~ s/^([a-zA-Z0-9][a-zA-Z0-9+._-]*)\s*//m;
 187             ($relation, $version) = ($1, $2)
 188                 if $dep_or =~ s/^\(\s*(=|<=|>=|<<?|>>?)\s*([^\)]+).*\)\s*//m;
 189             @arches = split(/\s+/m, $1) if $dep_or =~ s/^\[([^\]]+)\]\s*//m;
 190             push @dep_or_norm, "$pkg($relation$version)[".
 191                 join(" ",sort(@arches))."]";
 192             push @dep_or, [ $pkg, $relation, $version, \@arches ];
 193         }
 194         push @dep_and_norm, join('|',@dep_or_norm);
 195         push @dep_and, \@dep_or;
 196     }
 197     return (\@dep_and_norm, \@dep_and);
 198 }
 199
 200 sub get_newest {
 201     my ($self, $field) = @_;
 202
 203     return $self->{data}{$field};
 204 }
 205 sub get_src {
 206     my ($self, $field) = @_;
 207
 208     return $self->{src}{$field};
 209 }
 210
 211 sub get_architectures {
 212     my ($self) = @_;
 213
 214     return keys %{$self->{versions}};
 215 }
 216
 217 sub get_arch_field {
 218     my ($self, $field) = @_;
 219
 220     my %result;
 221     foreach (sort keys %{$self->{versions}}) {
 222         $result{$_} = $self->{versions}{$_}{$field}
 223         if $self->{versions}{$_}{$field};
 224     }
 225
 226     return \%result;
 227 }
 228
 229 sub get_versions {
 230     my ($self) = @_;
 231
 232     my %versions;
 233     foreach (keys %{$self->{versions}}) {
 234         my $version = $self->{versions}{$_}{version};
 235         $versions{$version} ||= [];
 236         push @{$versions{$version}}, $_;
 237     }
 238
 239     return \%versions;
 240 }
 241
 242 sub get_version_string {
 243     my ($self) = @_;
 244
 245     my $versions = $self->get_versions;
 246     my @versions = version_sort keys %$versions;
 247     my (@v_str, $v_str, $v_str_arch);
 248     if ( scalar @versions == 1 ) {
 249         @v_str = ( [ $versions[0], undef ] );
 250         $v_str = $versions[0];
 251         $v_str_arch = $versions[0];
 252     } else {
 253         my @v_str_arch;
 254         foreach ( @versions ) {
 255             push @v_str, [ $_, $versions->{$_} ];
 256             push @v_str_arch, "$_ [".join(', ', @{$versions->{$_}})."]";
 257         }
 258         $v_str_arch = join( ", ", @v_str_arch );
 259         $v_str = join( ", ",  @versions );
 260     }
 261
 262     return ($v_str, $v_str_arch, \@v_str);
 263 }
 264
 265 sub get_dep_field {
 266     my ($self, $dep_field) = @_;
 267
 268     my @architectures = $self->get_architectures;
 269
 270     my ( %dep_pkgs, %arch_deps );
 271     foreach my $a ( @architectures ) {
 272         next unless exists $self->{dep_fields}{$a}{$dep_field};
 273         my ($a_deps_norm, $a_deps) = @{$self->{dep_fields}{$a}{$dep_field}};
 274 #       debug( "get_dep_field: $dep_field/$a: ".Dumper($a_deps_norm,$a_deps), 3 );
 275         for ( my $i=0; $i < @$a_deps; $i++ ) { # splitted by ,
 276             $dep_pkgs{$a_deps_norm->[$i]} = $a_deps->[$i];
 277             $arch_deps{$a}{$a_deps_norm->[$i]}++;
 278         }
 279     }
 280     @architectures = sort keys %arch_deps;
 281  #   debug( "get_dep_field called:\n ".Dumper( \%dep_pkgs, \%arch_deps ), 3 );
 282
 283     my @deps;
 284     if ( %dep_pkgs ) {
 285         my $old_pkgs = '';
 286         my $is_old_pkgs = 0;
 287         foreach my $dp ( sort keys %dep_pkgs ) {
 288             my @dp_alts = @{$dep_pkgs{$dp}};
 289             my ( @pkgs, $pkgs );
 290             foreach (@dp_alts) { push @pkgs, $_->[0]; }
 291             $pkgs = "@pkgs";
 292
 293             unless ( $is_old_pkgs = ($pkgs eq $old_pkgs) ) {
 294                 $old_pkgs = $pkgs;
 295             }
 296
 297             my ($arch_neg, $arch_str) = _compute_arch_str ( $dp, \%arch_deps,
 298                                                             \@architectures );
 299
 300             my @res_pkgs; my $pkg_ix = 0;
 301             foreach my $p_name ( @pkgs ) {
 302                 if ( $pkg_ix > 0 ) { $arch_str = ""; }
 303
 304                 my $pkg_version = "";
 305                 $pkg_version = "$dep_pkgs{$dp}[$pkg_ix][1] $dep_pkgs{$dp}[$pkg_ix][2]"
 306                     if $dep_pkgs{$dp}[$pkg_ix][1];
 307
 308
 309                 push @res_pkgs, [ $p_name, $pkg_version, $arch_neg,
 310                                   $arch_str ];
 311                 $pkg_ix++;
 312             }
 313             push @deps, [ $is_old_pkgs, @res_pkgs ];
 314         }
 315     }
 316     return \@deps;
 317 }
 318
 319 sub _compute_arch_str {
 320     my ( $dp, $arch_deps, $all_archs, $is_src_dep ) = @_;
 321
 322     my ( @dependend_archs, @not_dependend_archs );
 323     my $arch_str;
 324     foreach my $a ( @$all_archs ) {
 325         if ( exists $arch_deps->{$a}{$dp} ) {
 326             push @dependend_archs, $a;
 327         } else {
 328             push @not_dependend_archs, $a;
 329         }
 330     }
 331     my $arch_neg = 0;
 332     if ( @dependend_archs == @$all_archs ) {
 333         $arch_str = "";
 334     } else {
 335         if ( @dependend_archs > (@$all_archs/2) ) {
 336             $arch_neg = 1;
 337             $arch_str = join( ", ", @not_dependend_archs);
 338         } else {
 339             $arch_str = join( ", ", @dependend_archs);
 340         }
 341     }
 342     return my @ret = ( $arch_neg, $arch_str );
 343 }
 344
 345 1;