lib/Packages/Page.pm

   1 package Packages::Page;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use Exporter;
   8 use Deb::Versions;
   9 use Packages::CGI;
  10
  11 our @ISA = qw( Exporter );
  12 our @EXPORT_OK = qw( split_name_mail parse_deps );
  13 our %EXPORT_TAGS = ( all => [ @EXPORT_OK ] );
  14
  15 our $ARCHIVE_DEFAULT = '';
  16 our $SECTION_DEFAULT = 'main';
  17 our $SUBSECTION_DEFAULT = 'unknown';
  18 our $PRIORITY_DEFAULT = 'unknown';
  19 our $ESSENTIAL_DEFAULT = 'no';
  20 our $MAINTAINER_DEFAULT = 'unknown <unknown@email.invalid>';
  21
  22 sub new {
  23     my $classname = shift;
  24     my $name = shift || '';
  25     my $config = shift || {};
  26
  27     my $self = {};
  28     bless( $self, $classname );
  29
  30     $self->{package} = $name;
  31     $self->{config} = $config;
  32
  33     return $self;
  34 }
  35
  36 sub gettext { return $_[0]; }
  37 sub split_name_mail {
  38     my $string = shift;
  39     my ( $name, $email );
  40     if ($string =~ /(.*?)\s*<(.*)>/o) {
  41         $name =  $1;
  42         $email = $2;
  43     } elsif ($string =~ /^[\w.-]*@[\w.-]*$/o) {
  44         $name =  $string;
  45         $email = $string;
  46     } else {
  47         $name = gettext( 'package has bad maintainer field' );
  48         $email = '';
  49     }
  50     $name =~ s/\s+$//o;
  51     return ($name, $email);
  52 }
  53
  54 sub add_src_data {
  55     my ($self, $src, $data) = @_;
  56
  57     my %data = split /\00/o, $data;
  58
  59     $self->{src}{package} = $src;
  60     $self->{src}{version} = $data{version};
  61     if ($data{files}) {
  62         my @files = split /\01/so, $data{files};
  63         $self->{src}{files} = \@files;
  64         print @{$self->{src}{files}};
  65     }
  66     $self->{src}{directory} = $data{directory};
  67     my @uploaders;
  68     if ($data{maintainer} ||= '') {
  69         push @uploaders, [ split_name_mail( $data{maintainer} ) ];
  70     }
  71     if ($data{uploaders}) {
  72         my @up_tmp = split( /\s*,\s*/,
  73                             $data{uploaders} );
  74         foreach my $up (@up_tmp) {
  75             if ($up ne $data{maintainer}) { # weed out duplicates
  76                 push @uploaders, [ split_name_mail( $up ) ];
  77             }
  78         }
  79     }
  80     $self->{src}{uploaders} = \@uploaders;
  81
  82     return 1;
  83 }
  84
  85 our @TAKE_NEWEST = qw( description essential priority section subsection tag
  86                        archive source source-version );
  87 our @STORE_ALL = qw( version source source-version installed-size size
  88                      filename md5sum
  89                      origin bugs suite archive section );
  90 our @DEP_FIELDS = qw( depends pre-depends recommends suggests enhances
  91                       provides conflicts );
  92 sub merge_package {
  93     my ($self, $data) = @_;
  94
  95     ($data->{package} && $data->{version} && $data->{architecture}) || return;
  96     $self->{package} ||= $data->{package};
  97     ($self->{package} eq $data->{package}) || return;
  98     debug( "merge package $data->{package}/$data->{version}/$data->{architecture} into $self (".($self->{newest}||'').")", 2 );
  99
 100     unless ($self->{newest}) {
 101         debug( "package $data->{package}/$data->{version}/$data->{architecture} is first to merge", 3 );
 102         foreach my $key (@TAKE_NEWEST) {
 103             $self->{data}{$key} = $data->{$key};
 104         }
 105         foreach my $key (@STORE_ALL) {
 106             $self->{versions}{$data->{architecture}}{$key}
 107             = $data->{$key};
 108         }
 109         foreach my $key (@DEP_FIELDS) {
 110             $self->normalize_dependencies($key, $data);
 111         }
 112         $self->{newest} = $data->{version};
 113
 114         return 1;
 115     }
 116
 117     debug( "package $data->{package}/$data->{version}/$data->{architecture} is subsequent merge", 3 );
 118     my $is_newest;
 119     if ($is_newest =
 120         (version_cmp( $data->{version}, $self->{newest} ) > 0)) {
 121         $self->{newest} = $data->{version};
 122         foreach my $key (@TAKE_NEWEST) {
 123             $self->{data}{$key} = $data->{$key};
 124         }
 125     }
 126     debug( "is_newest= ".($is_newest||0), 3 );
 127     if (!$self->{versions}{$data->{architecture}}
 128         || $is_newest
 129         || (version_cmp( $data->{version},
 130                          $self->{versions}{$data->{architecture}}{version} ) > 0)) {
 131         foreach my $key (@STORE_ALL) {
 132             $self->{versions}{$data->{architecture}}{$key}
 133             = $data->{$key};
 134         }
 135         foreach my $key (@DEP_FIELDS) {
 136             $self->normalize_dependencies($key, $data);
 137         }
 138     }
 139
 140     return 1;
 141 }
 142
 143 sub normalize_dependencies {
 144     my ($self, $dep_field, $data) = @_;
 145
 146     my ($deps_norm, $deps) = parse_deps( $data->{$dep_field}||'' );
 147     $self->{dep_fields}{$data->{architecture}}{$dep_field} =
 148         [ $deps_norm, $deps ];
 149 }
 150
 151 sub parse_deps {
 152     my ($dep_str) = @_;
 153
 154     my (@dep_and_norm, @dep_and);
 155     foreach my $dep_and (split( /\s*,\s*/m, $dep_str )) {
 156         next if $dep_and =~ /^\s*$/;
 157         my (@dep_or_norm, @dep_or);
 158         foreach my $dep_or (split( /\s*\|\s*/m, $dep_and )) {
 159             my ($pkg, $relation, $version, @arches) = ('','','');
 160             $pkg = $1 if $dep_or =~ s/^([a-zA-Z0-9][a-zA-Z0-9+._-]*)\s*//m;
 161             ($relation, $version) = ($1, $2)
 162                 if $dep_or =~ s/^\(\s*(=|<=|>=|<<?|>>?)\s*([^\)]+).*\)\s*//m;
 163             @arches = split(/\s+/m, $1) if $dep_or =~ s/^\[([^\]]+)\]\s*//m;
 164             push @dep_or_norm, "$pkg($relation$version)[".
 165                 join(" ",sort(@arches))."]";
 166             push @dep_or, [ $pkg, $relation, $version, \@arches ];
 167         }
 168         push @dep_and_norm, join('|',@dep_or_norm);
 169         push @dep_and, \@dep_or;
 170     }
 171     return (\@dep_and_norm, \@dep_and);
 172 }
 173
 174 sub get_newest {
 175     my ($self, $field) = @_;
 176
 177     return $self->{data}{$field};
 178 }
 179 sub get_src {
 180     my ($self, $field) = @_;
 181
 182     return $self->{src}{$field};
 183 }
 184
 185 sub get_architectures {
 186     my ($self) = @_;
 187
 188     return keys %{$self->{versions}};
 189 }
 190
 191 sub get_arch_field {
 192     my ($self, $field) = @_;
 193
 194     my %result;
 195     foreach (sort keys %{$self->{versions}}) {
 196         $result{$_} = $self->{versions}{$_}{$field}
 197         if $self->{versions}{$_}{$field};
 198     }
 199
 200     return \%result;
 201 }
 202
 203 sub get_versions {
 204     my ($self) = @_;
 205
 206     my %versions;
 207     foreach (keys %{$self->{versions}}) {
 208         my $version = $self->{versions}{$_}{version};
 209         $versions{$version} ||= [];
 210         push @{$versions{$version}}, $_;
 211     }
 212
 213     return \%versions;
 214 }
 215
 216 sub get_version_string {
 217     my ($self) = @_;
 218
 219     my $versions = $self->get_versions;
 220     my @versions = version_sort keys %$versions;
 221     my (@v_str, $v_str, $v_str_arch);
 222     if ( scalar @versions == 1 ) {
 223         @v_str = ( [ $versions[0], undef ] );
 224         $v_str = $versions[0];
 225         $v_str_arch = $versions[0];
 226     } else {
 227         my @v_str_arch;
 228         foreach ( @versions ) {
 229             push @v_str, [ $_, $versions->{$_} ];
 230             push @v_str_arch, "$_ [".join(', ', @{$versions->{$_}})."]";
 231         }
 232         $v_str_arch = join( ", ", @v_str_arch );
 233         $v_str = join( ", ",  @versions );
 234     }
 235
 236     return ($v_str, $v_str_arch, \@v_str);
 237 }
 238
 239 sub get_dep_field {
 240     my ($self, $dep_field) = @_;
 241
 242     my @architectures = $self->get_architectures;
 243
 244     my ( %dep_pkgs, %arch_deps );
 245     foreach my $a ( @architectures ) {
 246         next unless exists $self->{dep_fields}{$a}{$dep_field};
 247         my ($a_deps_norm, $a_deps) = @{$self->{dep_fields}{$a}{$dep_field}};
 248 #       debug( "get_dep_field: $dep_field/$a: ".Dumper($a_deps_norm,$a_deps), 3 );
 249         for ( my $i=0; $i < @$a_deps; $i++ ) { # splitted by ,
 250             $dep_pkgs{$a_deps_norm->[$i]} = $a_deps->[$i];
 251             $arch_deps{$a}{$a_deps_norm->[$i]}++;
 252         }
 253     }
 254     @architectures = sort keys %arch_deps;
 255  #   debug( "get_dep_field called:\n ".Dumper( \%dep_pkgs, \%arch_deps ), 3 );
 256
 257     my @deps;
 258     if ( %dep_pkgs ) {
 259         my $old_pkgs = '';
 260         my $is_old_pkgs = 0;
 261         foreach my $dp ( sort keys %dep_pkgs ) {
 262             my @dp_alts = @{$dep_pkgs{$dp}};
 263             my ( @pkgs, $pkgs );
 264             foreach (@dp_alts) { push @pkgs, $_->[0]; }
 265             $pkgs = "@pkgs";
 266
 267             unless ( $is_old_pkgs = ($pkgs eq $old_pkgs) ) {
 268                 $old_pkgs = $pkgs;
 269             }
 270
 271             my ($arch_neg, $arch_str) = _compute_arch_str ( $dp, \%arch_deps,
 272                                                             \@architectures );
 273
 274             my @res_pkgs; my $pkg_ix = 0;
 275             foreach my $p_name ( @pkgs ) {
 276                 if ( $pkg_ix > 0 ) { $arch_str = ""; }
 277
 278                 my $pkg_version = "";
 279                 $pkg_version = "$dep_pkgs{$dp}[$pkg_ix][1] $dep_pkgs{$dp}[$pkg_ix][2]"
 280                     if $dep_pkgs{$dp}[$pkg_ix][1];
 281
 282
 283                 push @res_pkgs, [ $p_name, $pkg_version, $arch_neg,
 284                                   $arch_str ];
 285                 $pkg_ix++;
 286             }
 287             push @deps, [ $is_old_pkgs, @res_pkgs ];
 288         }
 289     }
 290     return \@deps;
 291 }
 292
 293 sub _compute_arch_str {
 294     my ( $dp, $arch_deps, $all_archs, $is_src_dep ) = @_;
 295
 296     my ( @dependend_archs, @not_dependend_archs );
 297     my $arch_str;
 298     foreach my $a ( @$all_archs ) {
 299         if ( exists $arch_deps->{$a}{$dp} ) {
 300             push @dependend_archs, $a;
 301         } else {
 302             push @not_dependend_archs, $a;
 303         }
 304     }
 305     my $arch_neg = 0;
 306     if ( @dependend_archs == @$all_archs ) {
 307         $arch_str = "";
 308     } else {
 309         if ( @dependend_archs > (@$all_archs/2) ) {
 310             $arch_neg = 1;
 311             $arch_str = join( ", ", @not_dependend_archs);
 312         } else {
 313             $arch_str = join( ", ", @dependend_archs);
 314         }
 315     }
 316     return my @ret = ( $arch_neg, $arch_str );
 317 }
 318
 319 1;