lib/Packages/Page.pm

   1 package Packages::Page;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use Deb::Versions;
   8 use Packages::CGI;
   9 use IO::String;
  10
  11 our $ARCHIVE_DEFAULT = '';
  12 our $SECTION_DEFAULT = 'main';
  13 our $SUBSECTION_DEFAULT = 'unknown';
  14 our $PRIORITY_DEFAULT = 'unknown';
  15 our $ESSENTIAL_DEFAULT = 'no';
  16 our $MAINTAINER_DEFAULT = 'unknown <unknown@email.invalid>';
  17
  18 sub new {
  19     my $classname = shift;
  20     my $name = shift || '';
  21     my $config = shift || {};
  22
  23     my $self = {};
  24     bless( $self, $classname );
  25
  26     $self->{package} = $name;
  27     $self->{config} = $config;
  28
  29     return $self;
  30 }
  31
  32 sub merge_data {
  33     my ($self, $pkg, $version, $architecture, $data) = @_;
  34
  35     local $/ = "";
  36     my $strio = IO::String->new($data);
  37     my $merged = 0;
  38     while (<$strio>) {
  39         next if /^\s*$/;
  40         my %data = ( package => $pkg,
  41                      version => $version,
  42                      architecture => $architecture );
  43         chomp;
  44         s/\n /\377/g;
  45         while (/^(\S+):\s*(.*)\s*$/mg) {
  46             my ($key, $value) = ($1, $2);
  47             $value =~ s/\377/\n /g;
  48             $key =~ tr [A-Z] [a-z];
  49             $data{$key} = $value;
  50         }
  51 #       debug( "Merge package:\n".Dumper(\%data), 3 );
  52         $merged += $self->merge_package( \%data );
  53     }
  54     close DATA;
  55     return $merged;
  56 }
  57
  58 sub gettext { return $_[0]; }
  59 sub split_name_mail {
  60     my $string = shift;
  61     my ( $name, $email );
  62     if ($string =~ /(.*?)\s*<(.*)>/o) {
  63         $name =  $1;
  64         $email = $2;
  65     } elsif ($string =~ /^[\w.-]*@[\w.-]*$/o) {
  66         $name =  $string;
  67         $email = $string;
  68     } else {
  69         $name = gettext( 'package has bad maintainer field' );
  70         $email = '';
  71     }
  72     $name =~ s/\s+$//o;
  73     return ($name, $email);
  74 }
  75
  76 sub add_src_data {
  77     my ($self, $src, $version, $data) = @_;
  78
  79     local $/ = "";
  80     my $strio = IO::String->new($data);
  81     my %data;
  82     while (<$strio>) {
  83         next if /^\s*$/;
  84         chomp;
  85         %data = ();
  86         s/\n /\377/g;
  87         while (/^(\S+):\s*(.*)\s*$/mg) {
  88             my ($key, $value) = ($1, $2);
  89             $value =~ s/\377/\n /g;
  90             $key =~ tr [A-Z] [a-z];
  91             $data{$key} = $value;
  92         }
  93     }
  94     close DATA;
  95
  96     $self->{src}{name} = $src;
  97     $self->{src}{version} = $version;
  98     if ($data{files}) {
  99         $data{files} =~ s/\A\s*//o; # remove leading spaces
 100         $self->{src}{files} = [];
 101         foreach my $sf ( split( /\n\s*/, $data{files} ) ) {
 102             # md5, size, name
 103             push @{$self->{src}{files}}, [ split( /\s+/, $sf) ];
 104         }
 105     }
 106     my @uploaders;
 107     if ($data{maintainer} ||= '') {
 108         push @uploaders, [ split_name_mail( $data{maintainer} ) ];
 109     }
 110     if ($data{uploaders}) {
 111         my @up_tmp = split( /\s*,\s*/,
 112                             $data{uploaders} );
 113         foreach my $up (@up_tmp) {
 114             if ($up ne $data{maintainer}) { # weed out duplicates
 115                 push @uploaders, [ split_name_mail( $up ) ];
 116             }
 117         }
 118     }
 119     $self->{src}{uploaders} = \@uploaders;
 120
 121     return 1;
 122 }
 123
 124 our @TAKE_NEWEST = qw( description essential priority section subsection tag
 125                        archive source source-version );
 126 our @STORE_ALL = qw( version source source-version installed-size size
 127                      filename md5sum
 128                      origin bugs suite archive section );
 129 our @DEP_FIELDS = qw( depends pre-depends recommends suggests enhances
 130                       provides conflicts );
 131 sub merge_package {
 132     my ($self, $data) = @_;
 133
 134     ($data->{package} && $data->{version} && $data->{architecture}) || return;
 135     $self->{package} ||= $data->{package};
 136     ($self->{package} eq $data->{package}) || return;
 137     debug( "merge package $data->{package}/$data->{version}/$data->{architecture} into $self (".($self->{newest}||'').")", 2 );
 138
 139     unless ($self->{newest}) {
 140         debug( "package $data->{package}/$data->{version}/$data->{architecture} is first to merge", 3 );
 141         foreach my $key (@TAKE_NEWEST) {
 142             $self->{data}{$key} = $data->{$key};
 143         }
 144         foreach my $key (@STORE_ALL) {
 145             $self->{versions}{$data->{architecture}}{$key}
 146             = $data->{$key};
 147         }
 148         foreach my $key (@DEP_FIELDS) {
 149             $self->normalize_dependencies($key, $data);
 150         }
 151         $self->{newest} = $data->{version};
 152
 153         return 1;
 154     }
 155
 156     debug( "package $data->{package}/$data->{version}/$data->{architecture} is subsequent merge", 3 );
 157     my $is_newest;
 158     if ($is_newest =
 159         (version_cmp( $data->{version}, $self->{newest} ) > 0)) {
 160         $self->{newest} = $data->{version};
 161         foreach my $key (@TAKE_NEWEST) {
 162             $self->{data}{$key} = $data->{$key};
 163         }
 164     }
 165     debug( "is_newest= ".($is_newest||0), 3 );
 166     if (!$self->{versions}{$data->{architecture}}
 167         || $is_newest
 168         || (version_cmp( $data->{version},
 169                          $self->{versions}{$data->{architecture}} ) > 0)) {
 170         foreach my $key (@STORE_ALL) {
 171             $self->{versions}{$data->{architecture}}{$key}
 172             = $data->{$key};
 173         }
 174         foreach my $key (@DEP_FIELDS) {
 175             $self->normalize_dependencies($key, $data);
 176         }
 177     }
 178
 179     return 1;
 180 }
 181
 182 sub normalize_dependencies {
 183     my ($self, $dep_field, $data) = @_;
 184
 185     my ($deps_norm, $deps) = parse_deps( $data->{$dep_field}||'' );
 186     $self->{dep_fields}{$data->{architecture}}{$dep_field} =
 187         [ $deps_norm, $deps ];
 188 }
 189
 190 sub parse_deps {
 191     my ($dep_str) = @_;
 192
 193     my (@dep_and_norm, @dep_and);
 194     foreach my $dep_and (split( /\s*,\s*/m, $dep_str )) {
 195         next if $dep_and =~ /^\s*$/;
 196         my (@dep_or_norm, @dep_or);
 197         foreach my $dep_or (split( /\s*\|\s*/m, $dep_and )) {
 198             my ($pkg, $relation, $version, @arches) = ('','','');
 199             $pkg = $1 if $dep_or =~ s/^([a-zA-Z0-9][a-zA-Z0-9+._-]*)\s*//m;
 200             ($relation, $version) = ($1, $2)
 201                 if $dep_or =~ s/^\(\s*(=|<=|>=|<<?|>>?)\s*([^\)]+).*\)\s*//m;
 202             @arches = split(/\s+/m, $1) if $dep_or =~ s/^\[([^\]]+)\]\s*//m;
 203             push @dep_or_norm, "$pkg($relation$version)[".
 204                 join(" ",sort(@arches))."]";
 205             push @dep_or, [ $pkg, $relation, $version, \@arches ];
 206         }
 207         push @dep_and_norm, join('|',@dep_or_norm);
 208         push @dep_and, \@dep_or;
 209     }
 210     return (\@dep_and_norm, \@dep_and);
 211 }
 212
 213 sub get_newest {
 214     my ($self, $field) = @_;
 215
 216     return $self->{data}{$field};
 217 }
 218 sub get_src {
 219     my ($self, $field) = @_;
 220
 221     return $self->{src}{$field};
 222 }
 223
 224 sub get_architectures {
 225     my ($self) = @_;
 226
 227     return keys %{$self->{versions}};
 228 }
 229
 230 sub get_arch_field {
 231     my ($self, $field) = @_;
 232
 233     my %result;
 234     foreach (sort keys %{$self->{versions}}) {
 235         $result{$_} = $self->{versions}{$_}{$field}
 236         if $self->{versions}{$_}{$field};
 237     }
 238
 239     return \%result;
 240 }
 241
 242 sub get_versions {
 243     my ($self) = @_;
 244
 245     my %versions;
 246     foreach (keys %{$self->{versions}}) {
 247         my $version = $self->{versions}{$_}{version};
 248         $versions{$version} ||= [];
 249         push @{$versions{$version}}, $_;
 250     }
 251
 252     return \%versions;
 253 }
 254
 255 sub get_version_string {
 256     my ($self) = @_;
 257
 258     my $versions = $self->get_versions;
 259     my @versions = version_sort keys %$versions;
 260     my (@v_str, $v_str, $v_str_arch);
 261     if ( scalar @versions == 1 ) {
 262         @v_str = ( [ $versions[0], undef ] );
 263         $v_str = $versions[0];
 264         $v_str_arch = $versions[0];
 265     } else {
 266         my @v_str_arch;
 267         foreach ( @versions ) {
 268             push @v_str, [ $_, $versions->{$_} ];
 269             push @v_str_arch, "$_ [".join(', ', @{$versions->{$_}})."]";
 270         }
 271         $v_str_arch = join( ", ", @v_str_arch );
 272         $v_str = join( ", ",  @versions );
 273     }
 274
 275     return ($v_str, $v_str_arch, \@v_str);
 276 }
 277
 278 sub get_dep_field {
 279     my ($self, $dep_field) = @_;
 280
 281     my @architectures = $self->get_architectures;
 282
 283     my ( %dep_pkgs, %arch_deps );
 284     foreach my $a ( @architectures ) {
 285         next unless exists $self->{dep_fields}{$a}{$dep_field};
 286         my ($a_deps_norm, $a_deps) = @{$self->{dep_fields}{$a}{$dep_field}};
 287 #       debug( "get_dep_field: $dep_field/$a: ".Dumper($a_deps_norm,$a_deps), 3 );
 288         for ( my $i=0; $i < @$a_deps; $i++ ) { # splitted by ,
 289             $dep_pkgs{$a_deps_norm->[$i]} = $a_deps->[$i];
 290             $arch_deps{$a}{$a_deps_norm->[$i]}++;
 291         }
 292     }
 293     @architectures = sort keys %arch_deps;
 294  #   debug( "get_dep_field called:\n ".Dumper( \%dep_pkgs, \%arch_deps ), 3 );
 295
 296     my @deps;
 297     if ( %dep_pkgs ) {
 298         my $old_pkgs = '';
 299         my $is_old_pkgs = 0;
 300         foreach my $dp ( sort keys %dep_pkgs ) {
 301             my @dp_alts = @{$dep_pkgs{$dp}};
 302             my ( @pkgs, $pkgs );
 303             foreach (@dp_alts) { push @pkgs, $_->[0]; }
 304             $pkgs = "@pkgs";
 305
 306             unless ( $is_old_pkgs = ($pkgs eq $old_pkgs) ) {
 307                 $old_pkgs = $pkgs;
 308             }
 309
 310             my ($arch_neg, $arch_str) = _compute_arch_str ( $dp, \%arch_deps,
 311                                                             \@architectures );
 312
 313             my @res_pkgs; my $pkg_ix = 0;
 314             foreach my $p_name ( @pkgs ) {
 315                 if ( $pkg_ix > 0 ) { $arch_str = ""; }
 316
 317                 my $pkg_version = "";
 318                 $pkg_version = "$dep_pkgs{$dp}[$pkg_ix][1] $dep_pkgs{$dp}[$pkg_ix][2]"
 319                     if $dep_pkgs{$dp}[$pkg_ix][1];
 320
 321
 322                 push @res_pkgs, [ $p_name, $pkg_version, $arch_neg,
 323                                   $arch_str ];
 324                 $pkg_ix++;
 325             }
 326             push @deps, [ $is_old_pkgs, @res_pkgs ];
 327         }
 328     }
 329     return \@deps;
 330 }
 331
 332 sub _compute_arch_str {
 333     my ( $dp, $arch_deps, $all_archs, $is_src_dep ) = @_;
 334
 335     my ( @dependend_archs, @not_dependend_archs );
 336     my $arch_str;
 337     foreach my $a ( @$all_archs ) {
 338         if ( exists $arch_deps->{$a}{$dp} ) {
 339             push @dependend_archs, $a;
 340         } else {
 341             push @not_dependend_archs, $a;
 342         }
 343     }
 344     my $arch_neg = 0;
 345     if ( @dependend_archs == @$all_archs ) {
 346         $arch_str = "";
 347     } else {
 348         if ( @dependend_archs > (@$all_archs/2) ) {
 349             $arch_neg = 1;
 350             $arch_str = join( ", ", @not_dependend_archs);
 351         } else {
 352             $arch_str = join( ", ", @dependend_archs);
 353         }
 354     }
 355     return my @ret = ( $arch_neg, $arch_str );
 356 }
 357
 358 1;