lib/Packages/Page.pm

   1 package Packages::Page;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use Exporter;
   8 use Locale::gettext;
   9 use Deb::Versions;
  10 use Packages::CGI;
  11
  12 our @ISA = qw( Exporter );
  13 our @EXPORT_OK = qw( split_name_mail parse_deps );
  14 our %EXPORT_TAGS = ( all => [ @EXPORT_OK ] );
  15
  16 our $ARCHIVE_DEFAULT = '';
  17 our $SECTION_DEFAULT = 'main';
  18 our $SUBSECTION_DEFAULT = 'unknown';
  19 our $PRIORITY_DEFAULT = 'unknown';
  20 our $ESSENTIAL_DEFAULT = 'no';
  21 our $MAINTAINER_DEFAULT = 'unknown <unknown@email.invalid>';
  22
  23 sub new {
  24     my $classname = shift;
  25     my $name = shift || '';
  26     my $config = shift || {};
  27
  28     my $self = {};
  29     bless( $self, $classname );
  30
  31     $self->{package} = $name;
  32     $self->{config} = $config;
  33
  34     return $self;
  35 }
  36
  37 sub split_name_mail {
  38     my $string = shift;
  39     my ( $name, $email );
  40     if ($string =~ /(.*?)\s*<(.*)>/o) {
  41         $name =  $1;
  42         $email = $2;
  43     } elsif ($string =~ /^[\w.-]*@[\w.-]*$/o) {
  44         $name =  $string;
  45         $email = $string;
  46     } else {
  47         $name = gettext( 'package has bad maintainer field' );
  48         $email = '';
  49     }
  50     $name =~ s/\s+$//o;
  51     return ($name, $email);
  52 }
  53
  54 sub add_src_data {
  55     my ($self, $src, $data) = @_;
  56
  57     my %data = split /\00/o, $data;
  58
  59     $self->{src}{package} = $src;
  60     $self->{src}{version} = $data{version};
  61     if ($data{files}) {
  62         my @files = split /\01/so, $data{files};
  63         $self->{src}{files} = \@files;
  64     }
  65     $self->{src}{directory} = $data{directory};
  66     my @uploaders;
  67     if ($data{maintainer} ||= '') {
  68         push @uploaders, [ split_name_mail( $data{maintainer} ) ];
  69     }
  70     if ($data{uploaders}) {
  71         my @up_tmp = split( /\s*,\s*/,
  72                             $data{uploaders} );
  73         foreach my $up (@up_tmp) {
  74             if ($up ne $data{maintainer}) { # weed out duplicates
  75                 push @uploaders, [ split_name_mail( $up ) ];
  76             }
  77         }
  78     }
  79     $self->{src}{uploaders} = \@uploaders;
  80
  81     return 1;
  82 }
  83
  84 sub add_provided_by {
  85     my ($self, $provided_by) = @_;
  86
  87     $self->{provided_by} ||= [];
  88     push @{$self->{provided_by}}, @$provided_by;
  89 }
  90
  91 sub is_virtual {
  92     my ($self) = @_;
  93
  94     return (exists($self->{provided_by}) && !exists($self->{versions}));
  95 }
  96
  97 our @TAKE_NEWEST = qw( description essential priority section subsection tag
  98                        archive source source-version );
  99 our @STORE_ALL = qw( version source source-version installed-size size
 100                      filename md5sum
 101                      origin bugs suite archive section );
 102 our @DEP_FIELDS = qw( depends pre-depends recommends suggests enhances
 103                       provides conflicts );
 104 sub merge_package {
 105     my ($self, $data) = @_;
 106
 107     ($data->{package} && $data->{version} && $data->{architecture}) || return;
 108     $self->{package} ||= $data->{package};
 109     ($self->{package} eq $data->{package}) || return;
 110     debug( "merge package $data->{package}/$data->{version}/$data->{architecture} into $self (".($self->{newest}||'').")", 2 ) if DEBUG;
 111
 112     unless ($self->{newest}) {
 113         debug( "package $data->{package}/$data->{version}/$data->{architecture} is first to merge", 3 ) if DEBUG;
 114         foreach my $key (@TAKE_NEWEST) {
 115             $self->{data}{$key} = $data->{$key};
 116         }
 117         foreach my $key (@STORE_ALL) {
 118             $self->{versions}{$data->{architecture}}{$key}
 119             = $data->{$key};
 120         }
 121         foreach my $key (@DEP_FIELDS) {
 122             $self->normalize_dependencies($key, $data);
 123         }
 124         $self->{newest} = $data->{version};
 125
 126         return 1;
 127     }
 128
 129     debug( "package $data->{package}/$data->{version}/$data->{architecture} is subsequent merge", 3 ) if DEBUG;
 130     my $is_newest;
 131     if ($is_newest =
 132         (version_cmp( $data->{version}, $self->{newest} ) > 0)) {
 133         $self->{newest} = $data->{version};
 134         foreach my $key (@TAKE_NEWEST) {
 135             $self->{data}{$key} = $data->{$key};
 136         }
 137     }
 138     debug( "is_newest= ".($is_newest||0), 3 ) if DEBUG;
 139     if (!$self->{versions}{$data->{architecture}}
 140         || $is_newest
 141         || (version_cmp( $data->{version},
 142                          $self->{versions}{$data->{architecture}}{version} ) > 0)) {
 143         foreach my $key (@STORE_ALL) {
 144             $self->{versions}{$data->{architecture}}{$key}
 145             = $data->{$key};
 146         }
 147         foreach my $key (@DEP_FIELDS) {
 148             $self->normalize_dependencies($key, $data);
 149         }
 150     }
 151
 152     return 1;
 153 }
 154
 155 sub normalize_dependencies {
 156     my ($self, $dep_field, $data) = @_;
 157
 158     my ($deps_norm, $deps) = parse_deps( $data->{$dep_field}||'' );
 159     $self->{dep_fields}{$data->{architecture}}{$dep_field} =
 160         [ $deps_norm, $deps ];
 161 }
 162
 163 sub parse_deps {
 164     my ($dep_str) = @_;
 165
 166     my (@dep_and_norm, @dep_and);
 167     foreach my $dep_and (split( /\s*,\s*/m, $dep_str )) {
 168         next if $dep_and =~ /^\s*$/;
 169         my (@dep_or_norm, @dep_or);
 170         foreach my $dep_or (split( /\s*\|\s*/m, $dep_and )) {
 171             my ($pkg, $relation, $version, @arches) = ('','','');
 172             $pkg = $1 if $dep_or =~ s/^([a-zA-Z0-9][a-zA-Z0-9+._-]*)\s*//m;
 173             ($relation, $version) = ($1, $2)
 174                 if $dep_or =~ s/^\(\s*(=|<=|>=|<<?|>>?)\s*([^\)]+).*\)\s*//m;
 175             @arches = split(/\s+/m, $1) if $dep_or =~ s/^\[([^\]]+)\]\s*//m;
 176             push @dep_or_norm, "$pkg($relation$version)[".
 177                 join(" ",sort(@arches))."]";
 178             push @dep_or, [ $pkg, $relation, $version, \@arches ];
 179         }
 180         push @dep_and_norm, join('|',@dep_or_norm);
 181         push @dep_and, \@dep_or;
 182     }
 183     return (\@dep_and_norm, \@dep_and);
 184 }
 185
 186 sub get_newest {
 187     my ($self, $field) = @_;
 188
 189     return $self->{data}{$field};
 190 }
 191 sub get_src {
 192     my ($self, $field) = @_;
 193
 194     return $self->{src}{$field};
 195 }
 196
 197 sub get_architectures {
 198     my ($self) = @_;
 199
 200     return keys %{$self->{versions}};
 201 }
 202
 203 sub get_arch_field {
 204     my ($self, $field) = @_;
 205
 206     my %result;
 207     foreach (sort keys %{$self->{versions}}) {
 208         $result{$_} = $self->{versions}{$_}{$field}
 209         if $self->{versions}{$_}{$field};
 210     }
 211
 212     return \%result;
 213 }
 214
 215 sub get_dep_field {
 216     my ($self, $dep_field) = @_;
 217
 218     my @architectures = $self->get_architectures;
 219
 220     my ( %dep_pkgs, %arch_deps );
 221     foreach my $a ( @architectures ) {
 222         next unless exists $self->{dep_fields}{$a}{$dep_field};
 223         my ($a_deps_norm, $a_deps) = @{$self->{dep_fields}{$a}{$dep_field}};
 224 #       debug( "get_dep_field: $dep_field/$a: ".Dumper($a_deps_norm,$a_deps), 3 ) if DEBUG;
 225         for ( my $i=0; $i < @$a_deps; $i++ ) { # splitted by ,
 226             $dep_pkgs{$a_deps_norm->[$i]} = $a_deps->[$i];
 227             $arch_deps{$a}{$a_deps_norm->[$i]}++;
 228         }
 229     }
 230     @architectures = sort keys %arch_deps;
 231  #   debug( "get_dep_field called:\n ".Dumper( \%dep_pkgs, \%arch_deps ), 3 ) if DEBUG;
 232
 233     my @deps;
 234     if ( %dep_pkgs ) {
 235         my $old_pkgs = '';
 236         my $is_old_pkgs = 0;
 237         foreach my $dp ( sort keys %dep_pkgs ) {
 238             my @dp_alts = @{$dep_pkgs{$dp}};
 239             my ( @pkgs, $pkgs );
 240             foreach (@dp_alts) { push @pkgs, $_->[0]; }
 241             $pkgs = "@pkgs";
 242
 243             unless ( $is_old_pkgs = ($pkgs eq $old_pkgs) ) {
 244                 $old_pkgs = $pkgs;
 245             }
 246
 247             my ($arch_neg, $arch_str) = _compute_arch_str ( $dp, \%arch_deps,
 248                                                             \@architectures );
 249
 250             my @res_pkgs; my $pkg_ix = 0;
 251             foreach my $p_name ( @pkgs ) {
 252                 if ( $pkg_ix > 0 ) { $arch_str = ""; }
 253
 254                 my $pkg_version = "";
 255                 $pkg_version = "$dep_pkgs{$dp}[$pkg_ix][1] $dep_pkgs{$dp}[$pkg_ix][2]"
 256                     if $dep_pkgs{$dp}[$pkg_ix][1];
 257
 258
 259                 push @res_pkgs, [ $p_name, $pkg_version, $arch_neg,
 260                                   $arch_str ];
 261                 $pkg_ix++;
 262             }
 263             push @deps, [ $is_old_pkgs, @res_pkgs ];
 264         }
 265     }
 266     return \@deps;
 267 }
 268
 269 sub _compute_arch_str {
 270     my ( $dp, $arch_deps, $all_archs, $is_src_dep ) = @_;
 271
 272     my ( @dependend_archs, @not_dependend_archs );
 273     my $arch_str;
 274     foreach my $a ( @$all_archs ) {
 275         if ( exists $arch_deps->{$a}{$dp} ) {
 276             push @dependend_archs, $a;
 277         } else {
 278             push @not_dependend_archs, $a;
 279         }
 280     }
 281     my $arch_neg = 0;
 282     if ( @dependend_archs == @$all_archs ) {
 283         $arch_str = "";
 284     } else {
 285         if ( @dependend_archs > (@$all_archs/2) ) {
 286             $arch_neg = 1;
 287             $arch_str = join( ", ", @not_dependend_archs);
 288         } else {
 289             $arch_str = join( ", ", @dependend_archs);
 290         }
 291     }
 292     return my @ret = ( $arch_neg, $arch_str );
 293 }
 294
 295 1;