lib/Packages/DoShow.pm

   1 package Packages::DoShow;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX;
   7 use URI::Escape;
   8 use HTML::Entities;
   9 use DB_File;
  10 use Benchmark ':hireswallclock';
  11 use Exporter;
  12
  13 use Deb::Versions;
  14 use Packages::Config qw( $DBDIR @SUITES @ARCHIVES @SECTIONS
  15                          @ARCHITECTURES %FTP_SITES
  16                          @LANGUAGES @DDTP_LANGUAGES);
  17 use Packages::I18N::Locale;
  18 use Packages::CGI qw( :DEFAULT make_url make_search_url );
  19 use Packages::DB;
  20 use Packages::Search qw( :all );
  21 use Packages::Page ();
  22 use Packages::SrcPage ();
  23
  24 our @ISA = qw( Exporter );
  25 our @EXPORT = qw( do_show );
  26
  27 sub do_show {
  28     my ($params, $opts, $page_contents) = @_;
  29     my $cat = $opts->{cat};
  30
  31     if ($params->{errors}{package}) {
  32         fatal_error( $cat->g( "package not valid or not specified" ) );
  33     }
  34     if ($params->{errors}{suite}) {
  35         fatal_error( $cat->g( "suite not valid or not specified" ) );
  36     }
  37     if (@{$opts->{suite}} > 1) {
  38         fatal_error( $cat->g( "more than one suite specified for show (%s)",
  39                               "@{$opts->{suite}}" ) );
  40     }
  41
  42     my %contents;
  43     $contents{make_url} = sub { return &Packages::CGI::make_url(@_) };
  44
  45     my $pkg = $opts->{package};
  46     $contents{pkg} = $pkg;
  47     my $suite = $opts->{suite}[0];
  48     $contents{suite} = $suite;
  49     my $archive = $opts->{archive}[0] ||'';
  50
  51     our (%packages_all, %sources_all);
  52     my (@results, @non_results);
  53     my $page = $opts->{source} ?
  54         new Packages::SrcPage( $pkg ) :
  55         new Packages::Page( $pkg );
  56     my ($short_desc, $version, $section, $subsection) = ("")x5;
  57
  58     my $st0 = new Benchmark;
  59     unless (@Packages::CGI::fatal_errors) {
  60         tie %packages_all, 'DB_File', "$DBDIR/packages_all_$suite.db",
  61         O_RDONLY, 0666, $DB_BTREE
  62             or die "couldn't tie DB $DBDIR/packages_all_$suite.db: $!";
  63         tie %sources_all, 'DB_File', "$DBDIR/sources_all_$suite.db",
  64         O_RDONLY, 0666, $DB_BTREE
  65             or die "couldn't tie DB $DBDIR/sources_all_$suite.db: $!";
  66
  67         unless ($opts->{source}) {
  68             read_entry_all( \%packages, $pkg, \@results, \@non_results, $opts );
  69         } else {
  70             read_src_entry_all( \%sources, $pkg, \@results, \@non_results, $opts );
  71         }
  72
  73         unless (@results || @non_results ) {
  74             fatal_error( $cat->g( "No such package.") );
  75             #sprintf( _g( '<a href="%s">Search for the package</a>' ), make_search_url('','keywords='.uri_escape($pkg)) ) );
  76         } else {
  77             my %all_suites;
  78             foreach (@results, @non_results) {
  79                 my $a = $_->[1];
  80                 my $s = $_->[2];
  81                 $all_suites{$s}++;
  82             }
  83             $contents{suites} = [ suites_sort(keys %all_suites) ];
  84
  85             unless (@results) {
  86                 fatal_error( $cat->g( "Package not available in this suite." ) );
  87             } else {
  88                 $contents{page} = $page;
  89                 unless ($opts->{source}) {
  90
  91                     for my $entry (@results) {
  92                         debug( join(":", @$entry), 1 ) if DEBUG;
  93                         my (undef, $archive, undef, $arch, $section, $subsection,
  94                             $priority, $version, undef, $provided_by) = @$entry;
  95
  96                         if ($arch ne 'virtual') {
  97                             my %data = split /\000/, $packages_all{"$pkg $arch $version"};
  98                             $data{package} = $pkg;
  99                             $data{architecture} = $arch;
 100                             $data{version} = $version;
 101                             $page->merge_package(\%data)
 102                                 or debug( "Merging $pkg $arch $version FAILED", 2 ) if DEBUG;
 103                         } else {
 104                             $page->add_provided_by([split /\s+/, $provided_by]);
 105                         }
 106                     }
 107
 108                     unless ($page->is_virtual()) {
 109                         $version = $page->{newest};
 110                         $contents{version} = $version;
 111                         my $source = $page->get_newest( 'source' );
 112                         $archive = $page->get_newest( 'archive' );
 113                         $contents{archive} = $archive;
 114
 115                         debug( "find source package: source=$source", 1) if DEBUG;
 116                         my $src_data = $sources_all{"$archive $suite $source"};
 117                         #FIXME: should be $main_archive or similar, not hardcoded "us"
 118                         $src_data = $sources_all{"us $suite $source"} unless $src_data;
 119                         $page->add_src_data( $source, $src_data )
 120                             if $src_data;
 121
 122                         my $st1 = new Benchmark;
 123                         my $std = timediff($st1, $st0);
 124                         debug( "Data search and merging took ".timestr($std) ) if DEBUG;
 125
 126                         my @similar = find_similar( $pkg, "$DBDIR/xapian/",
 127                                                     \%did2pkg );
 128                         $contents{similar} = \@similar;
 129
 130                         my $did = $page->get_newest( 'description' );
 131                         my $desc_md5 = $page->get_newest( 'description-md5' );
 132                         my @complete_tags = split(/, /, $page->get_newest( 'tag' )||'' );
 133                         my @tags;
 134                         foreach (@complete_tags) {
 135                             my ($facet, $tag) = split( /::/, $_, 2);
 136                             next if $facet =~ /^special/;
 137                             next if $tag =~ /^special:/;
 138                             push @tags, [ $facet, $tag ];
 139                         }
 140
 141                         $contents{tags} = \@tags;
 142                         $contents{debtags_voc} = \%debtags;
 143
 144                         $section = $page->get_newest( 'section' );
 145                         $contents{section} = $section;
 146                         $subsection = $page->get_newest( 'subsection' );
 147                         $contents{subsection} = $subsection;
 148
 149                         my $archives = $page->get_arch_field( 'archive' );
 150                         my $versions = $page->get_arch_field( 'version' );
 151                         my $sizes_inst = $page->get_arch_field( 'installed-size' );
 152                         my $sizes_deb = $page->get_arch_field( 'size' );
 153                         my @archs = sort $page->get_architectures;
 154
 155                         # process description
 156                         #
 157                         sub process_description {
 158                             my ($desc) = @_;
 159
 160                             my $short_desc = encode_entities( $1, "<>&\"" )
 161                                 if $desc =~ s/^(.*)$//m;
 162                             my $long_desc = encode_entities( $desc, "<>&\"" );
 163
 164                             $long_desc =~ s,((ftp|http|https)://[\S~-]+?/?)((\&gt\;)?[)]?[']?[:.\,]?(\s|$)),<a href=\"$1\">$1</a>$3,go; # syntax highlighting -> '];
 165                             $long_desc =~ s/\A //o;
 166                             $long_desc =~ s/\n /\n/sgo;
 167                             $long_desc =~ s/\n.\n/\n<p>\n/go;
 168                             $long_desc =~ s/(((\n|\A) [^\n]*)+)/\n<pre>$1\n<\/pre>/sgo;
 169
 170                             return ($short_desc, $long_desc);
 171                         }
 172
 173                         my $desc = $descriptions{$did};
 174                         my $long_desc;
 175                         ($short_desc, $long_desc) = process_description($desc);
 176
 177                         $contents{desc}{en} = { short => $short_desc,
 178                                                 long => $long_desc, };
 179
 180                         debug( "desc_md5=$desc_md5", 2)
 181                             if DEBUG;
 182                         my $trans_desc = $desctrans{$desc_md5};
 183                         if ($trans_desc) {
 184                             my %trans_desc = split /\000|\001/, $trans_desc;
 185                             my %all_langs = map { $_ => 1 } (@LANGUAGES, keys %trans_desc);
 186                             $contents{used_langs} = [ keys %all_langs ];
 187                             debug( "TRANSLATIONS: ".join(" ",keys %trans_desc), 2)
 188                                 if DEBUG;
 189                             while (my ($l, $d) = each %trans_desc) {
 190                                 my ($short_t, $long_t) = process_description($d);
 191
 192                                 $contents{desc}{$l} = { short => $short_t,
 193                                                         long => $long_t, };
 194                             }
 195                         }
 196
 197                         my $v_str = $version;
 198                         my $multiple_versions = grep { $_ ne $version } values %$versions;
 199                         $v_str .= $cat->g(" and others") if $multiple_versions;
 200                         $contents{versions} = { short => $v_str,
 201                                                 multiple => $multiple_versions };
 202
 203                         my $provided_by = $page->{provided_by};
 204                         $contents{providers} = [];
 205                         pkg_list( \%packages, $opts, $provided_by, 'en', $contents{providers} ) if $provided_by;
 206
 207                         #
 208                         # display dependencies
 209                         #
 210                         build_deps( \%packages, $opts, $pkg,
 211                                     $page->get_dep_field('pre-depends'),
 212                                     'depends', \%contents );
 213                         build_deps( \%packages, $opts, $pkg,
 214                                     $page->get_dep_field('depends'),
 215                                     'depends', \%contents );
 216                         build_deps( \%packages, $opts, $pkg,
 217                                     $page->get_dep_field('recommends'),
 218                                     'recommends', \%contents );
 219                         build_deps( \%packages, $opts, $pkg,
 220                                     $page->get_dep_field('suggests'),
 221                                     'suggests', \%contents );
 222
 223                         #
 224                         # Download package
 225                         #
 226                         my @downloads;
 227                         foreach my $a ( @archs ) {
 228                             my %d = ( arch => $a,
 229                                       pkgsize => floor(($sizes_deb->{$a}/102.4)+0.5)/10,
 230                                       instsize => $sizes_inst->{$a}, );
 231
 232                             $d{version} = $versions->{$a} if $multiple_versions;
 233                             $d{archive} = $archives->{$a};
 234                             if ( ($suite ne "experimental")
 235                                  && ($subsection ne 'debian-installer')) {
 236                                 $d{contents_avail} = 1;
 237                             }
 238                             push @downloads, \%d;
 239                         }
 240                         $contents{downloads} = \@downloads;
 241
 242                         #
 243                         # more information
 244                         #
 245                         moreinfo( name => $pkg, data => $page, vars => \%contents,
 246                                   opts => $opts,
 247                                   env => \%FTP_SITES,
 248                                   bugreports => 1, sourcedownload => 1,
 249                                   changesandcopy => 1, maintainers => 1,
 250                                   search => 1 );
 251                     } else { # unless $page->is_virtual
 252                         $contents{is_virtual} = 1;
 253                         $contents{desc}{short} = $cat->g( "virtual package" );
 254                         $contents{subsection} = 'virtual';
 255
 256                         my $provided_by = $page->{provided_by};
 257                         $contents{providers} = [];
 258                         pkg_list( \%packages, $opts, $provided_by, 'en', $contents{providers} );
 259
 260                     } # else (unless $page->is_virtual)
 261                 } else { # unless $opts->{source}
 262                     $contents{is_source} = 1;
 263
 264                     for my $entry (@results) {
 265                         debug( join(":", @$entry), 1 ) if DEBUG;
 266                         my (undef, $archive, undef, $section, $subsection,
 267                             $priority, $version) = @$entry;
 268
 269                         my $data = $sources_all{"$archive $suite $pkg"};
 270                         $page->merge_data($pkg, $suite, $archive, $data)
 271                             or debug( "Merging $pkg $version FAILED", 2 ) if DEBUG;
 272                     }
 273                     $version = $page->{version};
 274                     $contents{version} = $version;
 275
 276                     my $st1 = new Benchmark;
 277                     my $std = timediff($st1, $st0);
 278                     debug( "Data search and merging took ".timestr($std) ) if DEBUG;
 279
 280                     $archive = $page->get_newest( 'archive' );
 281                     $contents{archive} = $archive;
 282                     $section = $page->get_newest( 'section' );
 283                     $contents{section} = $section;
 284                     $subsection = $page->get_newest( 'subsection' );
 285                     $contents{subsection} = $subsection;
 286
 287                     my $binaries = find_binaries( $pkg, $archive, $suite, \%src2bin );
 288                     if ($binaries && @$binaries) {
 289                         $contents{binaries} = [];
 290                         pkg_list( \%packages, $opts, $binaries, 'en', $contents{binaries} );
 291                     }
 292
 293                     #
 294                     # display dependencies
 295                     #
 296                     build_deps( \%packages, $opts, $pkg,
 297                                 $page->get_dep_field('build-depends'),
 298                                 'build-depends', \%contents );
 299                     build_deps( \%packages, $opts, $pkg,
 300                                 $page->get_dep_field('build-depends-indep'),
 301                                 'build-depends-indep', \%contents );
 302
 303                     #
 304                     # Source package download
 305                     #
 306                     my $source_files = $page->get_src( 'files' );
 307                     my $source_dir = $page->get_src( 'directory' );
 308
 309                     $contents{srcfiles} = [];
 310                     foreach( @$source_files ) {
 311                         my ($src_file_md5, $src_file_size, $src_file_name)
 312                             = split /\s+/, $_;
 313                         my $server = $FTP_SITES{lc $archive}
 314                             || $FTP_SITES{us};
 315                         my $path = "/$source_dir/$src_file_name";
 316
 317                         push @{$contents{srcfiles}}, { server => $server, path => $path, filename => $src_file_name,
 318                                                        size => floor(($src_file_size/102.4)+0.5)/10,
 319                                                        md5sum => $src_file_md5 };
 320                     }
 321
 322                     #
 323                     # more information
 324                     #
 325                     moreinfo( name => $pkg, data => $page, vars => \%contents,
 326                               opts => $opts,
 327                               env => \%FTP_SITES,
 328                               bugreports => 1,
 329                               changesandcopy => 1, maintainers => 1,
 330                               search => 1, is_source => 1 );
 331
 332                 } # else (unless $opts->{source})
 333             } # else (unless @results)
 334         } # else (unless (@results || @non_results ))
 335     }
 336
 337 #    use Data::Dumper;
 338 #    debug( "Final page object:\n".Dumper(\%contents), 3 ) if DEBUG;
 339
 340     %$page_contents = %contents;
 341 }
 342
 343 sub moreinfo {
 344     my %info = @_;
 345
 346     my $name = $info{name} or return;
 347     my $env = $info{env} or return;
 348     my $opts = $info{opts} or return;
 349     my $page = $info{data} or return;
 350     my $contents = $info{vars} or return;
 351     my $is_source = $info{is_source};
 352     my $suite = $opts->{suite}[0];
 353
 354     my $source = $page->get_src( 'package' );
 355     my $source_version = $page->get_src( 'version' );
 356     my $src_dir = $page->get_src('directory');
 357     if ($info{sourcedownload}) {
 358         $contents->{src}{url} = make_url($source,'',{source=>'source'});
 359         $contents->{src}{pkg} = $source;
 360
 361         my @downloads;
 362         my $files = $page->get_src( 'files' );
 363         if (defined($files) and @$files) {
 364             foreach( @$files ) {
 365                 my ($src_file_md5, $src_file_size, $src_file_name) = split /\s/o, $_;
 366                 my ($server, $path);
 367                 $server = $env->{lc $page->get_newest('archive')}||$env->{us};
 368                 $path = "/$src_dir/$src_file_name";
 369                 push @downloads, { name => $src_file_name, server => $server, path => $path };
 370             }
 371         }
 372         $contents->{src}{downloads} = \@downloads;
 373     }
 374
 375     if ($info{changesandcopy}) {
 376         if ( $src_dir ) {
 377             (my $src_basename = $source_version) =~ s,^\d+:,,; # strip epoche
 378             $src_basename = "${source}_$src_basename";
 379             $src_dir =~ s,pool/updates,pool,o;
 380
 381             $contents->{files}{changelog}{path} = "$src_dir/$src_basename/changelog";
 382             $contents->{files}{copyright}{path} = "$src_dir/$src_basename/".( $is_source ? 'copyright' : "$name.copyright" );
 383         }
 384    }
 385
 386     if ($info{maintainers}) {
 387         my $uploaders = $page->get_src( 'uploaders' );
 388         if ($uploaders && @$uploaders) {
 389             my @maintainers = map { { name => $_->[0], mail => $_->[1] } } @$uploaders;
 390             $contents->{maintainers} = \@maintainers;
 391         }
 392     }
 393
 394 }
 395
 396 sub providers {
 397     my ($suite, $entry, $also) = @_;
 398     my %tmp = map { $_ => 1 } split /\s/, $entry;
 399     my @provided_by = keys %tmp; # weed out duplicates
 400     my %out = ( also => $also,
 401                 pkgs => \@provided_by );
 402     return \%out;
 403 }
 404
 405 sub build_deps {
 406     my ( $packages, $opts, $pkg, $relations, $type, $contents) = @_;
 407     my %dep_type = ('depends' => 'dep', 'recommends' => 'rec',
 408                     'suggests' => 'sug', 'build-depends' => 'adep',
 409                     'build-depends-indep' => 'idep' );
 410     my $suite = $opts->{suite}[0];
 411     my $cat = $opts->{cat};
 412
 413     my %out = ( id => $dep_type{$type}, terms => [] );
 414
 415 #    use Data::Dumper;
 416 #    debug( "print_deps called:\n".Dumper( $pkg, $relations, \$type ), 3 ) if DEBUG;
 417
 418     foreach my $rel (@$relations) {
 419         my %rel_out;
 420         $rel_out{is_old_pkgs} = $rel->[0];
 421         $rel_out{alternatives} = [];
 422
 423         foreach my $rel_alt ( @$rel ) {
 424             next unless ref($rel_alt);
 425             my ( $p_name, $pkg_version, $arch_neg,
 426                  $arch_str, $subsection, $available ) = @$rel_alt;
 427
 428             if ($arch_str ||= '') {
 429                 if ($arch_neg) {
 430                     $arch_str = $cat->g("not %s", "$arch_str" );
 431                 } else {
 432                     $arch_str = $arch_str;
 433                 }
 434             }
 435
 436             my %rel_alt_out = ( name => $p_name,
 437                                 version => $pkg_version,
 438                                 arch_str => $arch_str,
 439                                 arch_neg => $arch_neg );
 440
 441             my @results;
 442             my %entries;
 443             my $entry = $entries{$p_name} ||
 444                 read_entry_simple( $packages, $p_name, $opts->{h_archives}, $suite);
 445             my $short_desc = $entry->[-1];
 446             my $desc_md5 = $entry->[-2];
 447             my $arch = $entry->[3];
 448             my $archive = $entry->[1];
 449             my $p_suite = $entry->[2];
 450             if ( $short_desc ) {
 451                 $rel_alt_out{desc} = $short_desc;
 452                 my $trans_desc = $desctrans{$desc_md5};
 453                 if ($trans_desc) {
 454                     my %trans_desc = split /\000|\001/, $trans_desc;
 455                     my %sdescs;
 456                     while (my ($l, $d) = each %trans_desc) {
 457                         $d =~ s/\n.*//os;
 458
 459                         $sdescs{$l} = $d;
 460                     }
 461                     $rel_alt_out{trans_desc} = \%sdescs;
 462                 }
 463                 $rel_alt_out{suite} = $p_suite;
 464                 if ( $rel_out{is_old_pkgs} ) {
 465                 } elsif (defined $entry->[1]) {
 466                     $entries{$p_name} ||= $entry;
 467                     $rel_alt_out{providers} = providers( $p_suite,
 468                                                         $entry->[0],
 469                                                         1 ) if defined $entry->[0];
 470                 } elsif (defined $entry->[0]) {
 471                     $rel_alt_out{desc} = undef;
 472                     $rel_alt_out{providers} = providers( $p_suite,
 473                                                         $entry->[0] );
 474                     #FIXME: we don't handle virtual packages from
 475                     # the fallback suite correctly here
 476                     $rel_alt_out{suite} = $suite;
 477                 }
 478             } elsif ( $rel_out{is_old_pkgs} ) {
 479             } else {
 480                 $rel_alt_out{desc} = $cat->g( "Package not available" );
 481                 $rel_alt_out{suite} = '';
 482             }
 483             push @{$rel_out{alternatives}}, \%rel_alt_out;
 484         }
 485
 486         push @{$out{terms}}, \%rel_out;
 487     }
 488
 489     $contents->{relations} ||= [];
 490     push @{$contents->{relations}}, \%out if @{$out{terms}};
 491 } # end print_deps
 492
 493 sub pkg_list {
 494     my ( $packages, $opts, $pkgs, $lang, $list ) = @_;
 495     my $suite = $opts->{suite}[0];
 496
 497     foreach my $p ( sort @$pkgs ) {
 498
 499         # we don't deal with virtual packages here because for the
 500         # current uses of this function this isn't needed
 501         my $data = read_entry_simple( $packages, $p, $opts->{h_archives}, $suite);
 502         my ($desc_md5, $short_desc) = ($data->[-2],$data->[-1]);
 503
 504         if ( $short_desc ) {
 505             my $trans_desc = $desctrans{$desc_md5};
 506             my %sdescs;
 507             if ($trans_desc) {
 508                 my %trans_desc = split /\000|\001/, $trans_desc;
 509                 while (my ($l, $d) = each %trans_desc) {
 510                     $d =~ s/\n.*//os;
 511
 512                     $sdescs{$l} = $d;
 513                 }
 514             }
 515             push @$list, { name => $p, desc => $short_desc,
 516                            trans_desc => \%sdescs, available => 1 };
 517         } else {
 518             push @$list, { name => $p,
 519                            desc => $opts->{cat}->g("Not available") };
 520         }
 521     }
 522 }
 523
 524
 525 1;
 526