lib/Packages/DoSearch.pm

   1 package Packages::DoSearch;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Benchmark ':hireswallclock';
   7 use DB_File;
   8 use Exporter;
   9 our @ISA = qw( Exporter );
  10 our @EXPORT = qw( do_search );
  11
  12 use Deb::Versions;
  13 use Packages::I18N::Locale;
  14 use Packages::Search qw( :all );
  15 use Packages::CGI qw( :DEFAULT );
  16 use Packages::DB;
  17 use Packages::Config qw( $DBDIR @SUITES @ARCHIVES $ROOT );
  18
  19 sub do_search {
  20     my ($params, $opts, $page_content) = @_;
  21     my $cat = $opts->{cat};
  22
  23     $Params::Search::too_many_hits = 0;
  24
  25     if ($params->{errors}{keywords}) {
  26         fatal_error( $cat->g( "keyword not valid or missing" ) );
  27         $opts->{keywords} = [];
  28     } elsif (grep { length($_) < 2 } @{$opts->{keywords}}) {
  29         fatal_error( $cat->g( "keyword too short (keywords need to have at least two characters)" ) );
  30     }
  31
  32     my @keywords = @{$opts->{keywords}};
  33     my $searchon = $opts->{searchon};
  34     $page_content->{search_keywords} = \@keywords;
  35
  36     my $st0 = new Benchmark;
  37     my (@results, @non_results);
  38
  39     unless (@Packages::CGI::fatal_errors) {
  40
  41         if ($searchon eq 'names') {
  42             if ($opts->{source}) {
  43                 do_names_search( [ @keywords ], \%sources, $sp_obj,
  44                                  \&read_src_entry_all, $opts,
  45                                  \@results, \@non_results );
  46             } else {
  47                 do_names_search( [ @keywords ], \%packages, $p_obj,
  48                                  \&read_entry_all, $opts,
  49                                  \@results, \@non_results );
  50             }
  51         } else {
  52             do_names_search( [ @keywords ], \%packages, $p_obj,
  53                              \&read_entry_all, $opts,
  54                              \@results, \@non_results );
  55             my $fts1 = new Benchmark;
  56             do_xapian_search( [ @keywords ], "$DBDIR/xapian/",
  57                                 \%did2pkg, \%packages,
  58                                 \&read_entry_all, $opts,
  59                                 \@results, \@non_results );
  60             my $fts2 = new Benchmark;
  61             my $fts_xapian = timediff($fts2,$fts1);
  62             debug( "Fulltext search took ".timestr($fts_xapian) )
  63                 if DEBUG;
  64         }
  65     }
  66
  67 #    use Data::Dumper;
  68 #    debug( join( "", Dumper( \@results, \@non_results )) ) if DEBUG;
  69     my $st1 = new Benchmark;
  70     my $std = timediff($st1, $st0);
  71     debug( "Search took ".timestr($std) ) if DEBUG;
  72
  73     $page_content->{too_many_hits} = $Packages::Search::too_many_hits;
  74     #FIXME: non_results can't be compared to results since it is
  75     # not normalized to unique packages
  76     $page_content->{non_results} = scalar @non_results;
  77
  78     if (@results) {
  79         my (%pkgs, %subsect, %sect, %archives, %desc, %binaries, %provided_by);
  80
  81         my %sort_by_relevance;
  82         for (1 ... scalar @results) {
  83 #           debug("$results[$_][0] => $_", 4) if DEBUG;
  84             $sort_by_relevance{$results[$_-1][0]} = $_;
  85         }
  86 #       use Data::Dumper;
  87 #       debug( "sort_by_relevance=".Dumper(\%sort_by_relevance), 4);
  88
  89         unless ($opts->{source}) {
  90             foreach (@results) {
  91                 my ($pkg_t, $archive, $suite, $arch, $section, $subsection,
  92                     $priority, $version, $desc_md5, $desc) = @$_;
  93
  94                 my ($pkg) = $pkg_t =~ m/^(.+)/; # untaint
  95                 if ($arch ne 'virtual') {
  96                     $pkgs{$pkg}{$suite}{$version}{$arch} = 1;
  97                     $subsect{$pkg}{$suite}{$version} = $subsection;
  98                     $sect{$pkg}{$suite}{$version} = $section;
  99                     $archives{$pkg}{$suite}{$version} ||= $archive;
 100
 101                     $desc{$pkg}{$suite}{$version} = [ $desc_md5, $desc ];
 102                 } else {
 103                     $provided_by{$pkg}{$suite} = [ split /\s+/, $desc ];
 104                 }
 105             }
 106
 107             my %uniq_pkgs = map { $_ => 1 } (keys %pkgs, keys %provided_by);
 108             my @pkgs;
 109             if ($searchon eq 'names') {
 110                 @pkgs = sort keys %uniq_pkgs;
 111             } else {
 112                 @pkgs = sort { $sort_by_relevance{$a} <=> $sort_by_relevance{$b} } keys %uniq_pkgs;
 113             }
 114             process_packages( $page_content, 'packages', \%pkgs, \@pkgs,
 115                               $opts, \@keywords,
 116                               \&process_package, \%provided_by,
 117                               \%archives, \%sect, \%subsect,
 118                               \%desc );
 119
 120         } else { # unless $opts->{source}
 121             foreach (@results) {
 122                 my ($pkg, $archive, $suite, $section, $subsection, $priority,
 123                     $version) = @$_;
 124
 125                 my $real_archive = '';
 126                 if ($archive eq 'security') {
 127                     $real_archive = $archive;
 128                     $archive = 'us';
 129                 }
 130                 if (($real_archive eq $archive) &&
 131                     $pkgs{$pkg}{$suite}{$archive} &&
 132                     (version_cmp( $pkgs{$pkg}{$suite}{$archive}, $version ) >= 0)) {
 133                     next;
 134                 }
 135                 $pkgs{$pkg}{$suite}{$archive} = $version;
 136                 $subsect{$pkg}{$suite}{$archive}{source} = $subsection;
 137                 $sect{$pkg}{$suite}{$archive}{source} = $section
 138                     unless $section eq 'main';
 139                 $archives{$pkg}{$suite}{$archive}{source} = $real_archive
 140                     if $real_archive;
 141
 142                 $binaries{$pkg}{$suite}{$archive} = find_binaries( $pkg, $archive, $suite, \%src2bin );
 143             }
 144
 145             my @pkgs = sort keys %pkgs;
 146             process_packages( $page_content, 'src_packages', \%pkgs, \@pkgs,
 147                               $opts, \@keywords,
 148                               \&process_src_package, \%archives,
 149                               \%sect, \%subsect, \%binaries );
 150         } # else unless $opts->{source}
 151     } # if @results
 152 } # sub do_search
 153
 154 sub process_packages {
 155     my ($content, $target, $pkgs, $pkgs_list, $opts, $keywords, $print_func, @func_args) = @_;
 156
 157     my @categories;
 158     $content->{results} = scalar @$pkgs_list;
 159
 160     my $keyword;
 161     $keyword = $keywords->[0] if @$keywords == 1;
 162
 163     my $have_exact;
 164     if ($keyword && grep { $_ eq $keyword } @$pkgs_list) {
 165         $have_exact = 1;
 166         $categories[0]{name} = $opts->{cat}->g( "Exact hits" );
 167
 168         $categories[0]{$target} = [ &$print_func( $opts, $keyword,
 169                                                   $pkgs->{$keyword}||{},
 170                                                   map { $_->{$keyword}||{} } @func_args ) ];
 171         @$pkgs_list = grep { $_ ne $keyword } @$pkgs_list;
 172     }
 173
 174     if (@$pkgs_list && (($opts->{searchon} ne 'names') || !$opts->{exact})) {
 175         my %cat;
 176         $cat{name} = $opts->{cat}->g( 'Other hits' ) if $have_exact;
 177
 178         $cat{packages} = [];
 179         foreach my $pkg (@$pkgs_list) {
 180             push @{$cat{$target}}, &$print_func( $opts, $pkg, $pkgs->{$pkg}||{},
 181                                                  map { $_->{$pkg}||{} } @func_args );
 182         }
 183         push @categories, \%cat;
 184     } elsif (@$pkgs_list) {
 185         $content->{skipped} = scalar @$pkgs_list;
 186     }
 187
 188     $content->{categories} = \@categories;
 189 }
 190
 191 sub process_package {
 192     my ($opts, $pkg, $pkgs, $provided_by,
 193         $archives, $sect, $subsect, $desc) = @_;
 194
 195     my %pkg = ( pkg => $pkg,
 196                 suites => [] );
 197
 198     foreach my $suite (@SUITES) {
 199         my %suite = ( suite => $suite );
 200         if (exists $pkgs->{$suite}) {
 201             my %archs_printed;
 202             my @versions = version_sort keys %{$pkgs->{$suite}};
 203             $suite{section} = $sect->{$suite}{$versions[0]};
 204             $suite{subsection} = $subsect->{$suite}{$versions[0]};
 205             my $desc_md5 = $desc->{$suite}{$versions[0]}[0];
 206             $suite{desc} = $desc->{$suite}{$versions[0]}[1];
 207             $suite{versions} = [];
 208
 209             my $trans_desc = $desctrans{$desc_md5};
 210             my %sdescs;
 211             if ($trans_desc) {
 212                 my %trans_desc = split /\000|\001/, $trans_desc;
 213                 while (my ($l, $d) = each %trans_desc) {
 214                     $d =~ s/\n.*//os;
 215
 216                     $sdescs{$l} = $d;
 217                 }
 218                 $suite{trans_desc} = \%sdescs;
 219             }
 220
 221             foreach my $v (@versions) {
 222                 my %version;
 223                 $version{version} = $v;
 224                 $version{archive} = $archives->{$suite}{$v};
 225
 226                 $version{architectures} = [ grep { !$archs_printed{$_} } sort keys %{$pkgs->{$suite}{$v}} ];
 227                 push @{$suite{versions}}, \%version if @{$version{architectures}};
 228
 229                 $archs_printed{$_}++ foreach @{$version{architectures}};
 230             }
 231             if (my $p =  $provided_by->{$suite}) {
 232                 $suite{providers} = $p;
 233             }
 234         } elsif (my $p =  $provided_by->{$suite}) {
 235             $suite{desc} = $opts->{cat}->g('Virtual package');
 236             $suite{providers} = $p;
 237         }
 238         push @{$pkg{suites}}, \%suite if $suite{versions} || $suite{providers};
 239     }
 240
 241     return \%pkg;
 242 }
 243
 244 sub process_src_package {
 245     my ($opts, $pkg, $pkgs, $archives, $sect, $subsect, $binaries) = @_;
 246
 247     my %pkg = ( pkg => $pkg,
 248                 origins => [] );
 249
 250     foreach my $suite (@SUITES) {
 251         foreach my $archive (@ARCHIVES) {
 252             if (exists $pkgs->{$suite}{$archive}) {
 253                 my %origin;
 254                 $origin{version} = $pkgs->{$suite}{$archive};
 255                 $origin{suite} = $suite;
 256                 $origin{archive} = $archive;
 257                 $origin{section} = $sect->{$suite}{$archive}{source};
 258                 $origin{subsection} = $subsect->{$suite}{$archive}{source};
 259                 $origin{real_archive} = $archives->{$suite}{$archive}{source};
 260
 261                 $origin{binaries} = $binaries->{$suite}{$archive};
 262                 push @{$pkg{origins}}, \%origin;
 263             }
 264         }
 265     }
 266
 267     return \%pkg;
 268 }
 269
 270 1;