lib/Packages/Dispatcher.pm

   1 #!/usr/bin/perl -T
   2 # Packages::Dispatcher -- CGI interface for packages.debian.org
   3 #
   4 # Copyright (C) 2004-2008 Frank Lichtenheld
   5 #
   6 #    This program is free software; you can redistribute it and/or modify
   7 #    it under the terms of the GNU General Public License as published by
   8 #    the Free Software Foundation; either version 1 of the License, or
   9 #    (at your option) any later version.
  10 #
  11 #    This program is distributed in the hope that it will be useful,
  12 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #    GNU General Public License for more details.
  15 #
  16 #    You should have received a copy of the GNU General Public License
  17 #    along with this program; if not, write to the Free Software
  18 #    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 package Packages::Dispatcher;
  21
  22 use strict;
  23 use warnings;
  24
  25 use CGI;
  26 use POSIX;
  27 use File::Basename;
  28 use Template;
  29 use DB_File;
  30 use URI::Escape;
  31 use Benchmark ':hireswallclock';
  32 use I18N::AcceptLanguage;
  33 use Date::Parse;
  34
  35 use Deb::Versions;
  36 use Packages::Config qw( $DBDIR $ROOT $TEMPLATEDIR $CACHEDIR
  37                          @SUITES @SECTIONS @ARCHIVES @ARCHITECTURES @PRIORITIES
  38                          @LANGUAGES @DDTP_LANGUAGES );
  39 use Packages::CGI qw( :DEFAULT error get_all_messages );
  40 use Packages::DB;
  41 use Packages::Search qw( :all );
  42 use Packages::Template ();
  43 use Packages::Sections;
  44 use Packages::I18N::Locale;
  45
  46 use Packages::DoSearch;
  47 use Packages::DoSearchContents;
  48 use Packages::DoShow;
  49 use Packages::DoIndex;
  50 use Packages::DoNewPkg;
  51 use Packages::DoDownload;
  52 use Packages::DoFilelist;
  53
  54
  55 sub do_dispatch {
  56
  57     &Packages::CGI::reset;
  58     $Packages::Search::too_many_hits = 0;
  59
  60     # clean up env
  61     $ENV{PATH} = "/bin:/usr/bin";
  62     delete $ENV{'LANGUAGE'};
  63     delete $ENV{'LANG'};
  64     delete $ENV{'LC_ALL'};
  65     delete $ENV{'LC_MESSAGES'};
  66
  67     my %SUITES_ALIAS = ( oldstable => 'sarge',
  68                          stable => 'etch',
  69                          testing => 'lenny',
  70                          unstable => 'sid',
  71                          '3.1' => 'sarge',
  72                          '4.0' => 'etch' );
  73
  74     # Read in all the variables set by the form
  75     my $input;
  76     if ($ARGV[0] && ($ARGV[0] eq 'php')) {
  77         $input = new CGI(\*STDIN);
  78     } else {
  79         $input = new CGI;
  80     }
  81     my $cgi_error = $input->cgi_error;
  82     if ($cgi_error) {
  83         fatal_error( "Error parsing the request", $cgi_error );
  84     }
  85
  86     my $pet0 = new Benchmark;
  87     my $tet0 = new Benchmark;
  88     my $debug = DEBUG && $input->param("debug");
  89     $debug = 0 if !defined($debug) || $debug !~ /^\d+$/o;
  90     $Packages::CGI::debug = $debug;
  91
  92     my $homedir = dirname($ENV{SCRIPT_FILENAME}).'/../';
  93     &Packages::Config::init( $homedir );
  94     &Packages::DB::init();
  95     my $last_modified = $Packages::DB::db_read_time;
  96     my $now = time;
  97     my $expires = $last_modified + (12*3600);
  98     $expires = $now + 3600 if $expires < $now;
  99     # allow some fudge, since the db mod time is not the end of
 100     # the cron job
 101     $last_modified = $now if $now - $last_modified < 3600;
 102
 103     if ($input->http('If-Modified-Since') and
 104         (my $modtime = str2time($input->http('If-Modified-Since'), 'UTC'))) {
 105         if ($modtime <= $last_modified) {
 106             print $input->header(-status => 304);
 107             exit;
 108         }
 109     }
 110
 111     my %PO_LANGUAGES = map { $_ => 1 } @LANGUAGES;
 112     my %DDTP_LANGUAGES = map { $_ => 1 } @DDTP_LANGUAGES;
 113     my $acc = I18N::AcceptLanguage->new(defaultLanguage => 'en');
 114     my $ddtp_lang = $acc->accepts( $input->http("Accept-Language"),
 115                                    \@DDTP_LANGUAGES );
 116     my $po_lang = $acc->accepts( $input->http("Accept-Language"),
 117                                  \@LANGUAGES );
 118     debug( "LANGS=@LANGUAGES DDTP_LANGS=@DDTP_LANGUAGES header=".
 119            ($input->http("Accept-Language")||'').
 120            " po_lang=$po_lang ddtp_lang=$ddtp_lang", 1 ) if DEBUG;
 121
 122     # backwards compatibility stuff
 123     debug( "SCRIPT_URL=$ENV{SCRIPT_URL} SCRIPT_URI=$ENV{SCRIPT_URI}" ) if DEBUG;
 124
 125     if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_|) {
 126         error( "You reached this site over an old URL. ".
 127                "Depending on the exact parameters your search might work or not." );
 128         # contents search changed a lot
 129         if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_contents|) {
 130             $input->param('keywords',$input->param('word')) if $input->param('word');
 131             $input->param('searchon','contents');
 132             for ($input->param('searchmode')) {
 133                 /^searchfiles/ && do {
 134                     $input->param('mode','filename');
 135                     last;
 136                 };
 137                 /^filelist/ && do {
 138                     $ENV{PATH_INFO} = '/'.join('/',($input->param('version')||'stable',
 139                                                     $input->param('keywords'),
 140                                                     $input->param('arch')||'i386',
 141                                                     'filelist' ));
 142                     $input->delete('searchon','version','keywords','arch');
 143                     last;
 144                 };
 145             }
 146         }
 147     }
 148     if ($ENV{is_reportbug}) {
 149         $input->param('exact', 1);
 150         debug( "reportbug detected, set paramater exact to '1'" ) if DEBUG;
 151     }
 152
 153     my $what_to_do = 'show';
 154     my $source = 0;
 155     if (my $path = $ENV{'PATH_INFO'} || $input->param('PATH_INFO')) {
 156         my @components = grep { $_ } map { lc $_ } split /\/+/, $path;
 157
 158         debug( "PATH_INFO=$path components=@components", 3) if DEBUG;
 159
 160         push @components, 'index' if @components && $path =~ m,/$,;
 161
 162         my %LANGUAGES = map { $_ => 1 } (@LANGUAGES, @DDTP_LANGUAGES);
 163         if (@components > 1 and $LANGUAGES{$components[0]}
 164             and !$input->param('lang')) {
 165             $input->param( 'lang', shift(@components) );
 166         }
 167         if (@components > 1 and $components[0] eq 'source') {
 168             shift @components;
 169             $input->param( 'source', 1 );
 170         }
 171         if (@components > 0 and $components[0] eq 'search') {
 172             shift @components;
 173             $what_to_do = 'search';
 174             # Done
 175             fatal_error( "search doesn't take any more path elements" )
 176                 if @components;
 177         } elsif (@components == 0) {
 178             fatal_error( "We're supposed to display the homepage here, instead of getting dispatch.pl" );
 179         } elsif (@components == 1) {
 180             $what_to_do = 'search';
 181         } else {
 182
 183             for ($components[-1]) {
 184                 /^(index|allpackages|newpkg|changelog|copyright|download|filelist)$/ && do {
 185                     pop @components;
 186                     $what_to_do = $1;
 187                     last;
 188                 };
 189             }
 190
 191             my %SUITES = map { $_ => 1 } @SUITES;
 192             my %SECTIONS = map { $_ => 1 } @SECTIONS;
 193             my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
 194             my %ARCHITECTURES = map { $_ => 1 } (@ARCHITECTURES, 'all', 'any');
 195             my %PRIORITIES = map { $_ => 1 } @PRIORITIES;
 196             my %params_set;
 197             sub set_param_once {
 198                 my ($cgi, $params_set, $key, $val) = @_;
 199                 debug("set_param_once key=$key val=$val",4) if DEBUG;
 200                 if ($params_set->{$key}++) {
 201                     fatal_error( "$key set more than once in path" );
 202                 } else {
 203                     $cgi->param( $key, $val );
 204                 }
 205             }
 206
 207             my (@pkg, $need_pkg);
 208             foreach (reverse @components) {
 209                 $need_pkg = !@pkg
 210                     && ($what_to_do !~ /^(index|allpackages|newpkg)$/);
 211                 debug("need_pkg=$need_pkg component=$_",4) if DEBUG;
 212                 if (!$need_pkg && $SUITES{$_}) {
 213                     set_param_once( $input, \%params_set, 'suite', $_);
 214                 } elsif (!$need_pkg && (my $s = $SUITES_ALIAS{$_})) {
 215                     set_param_once( $input, \%params_set, 'suite', $s);
 216                 } elsif (!$need_pkg && $SECTIONS{$_}) {
 217                     set_param_once( $input, \%params_set, 'section', $_);
 218                 } elsif (!$need_pkg && $sections_descs{$_}) {
 219                     set_param_once( $input, \%params_set, 'subsection', $_);
 220                 } elsif (!$need_pkg && ($_ eq 'source')) {
 221                     set_param_once( $input, \%params_set, 'source', 1);
 222                 } elsif ($ARCHITECTURES{$_}) {
 223                     set_param_once( $input, \%params_set, 'arch', $_)
 224                         unless $_ eq 'any';
 225                 } elsif (!$need_pkg && $ARCHIVES{$_}) {
 226                     set_param_once( $input, \%params_set, 'archive', $_);
 227                 } elsif ($PRIORITIES{$_}) {
 228                     set_param_once( $input, \%params_set, 'priority', $_);
 229                 } else {
 230                     push @pkg, $_;
 231                 }
 232             }
 233             @components = @pkg;
 234
 235             if (@components > 1) {
 236                 fatal_error( "two or more packages specified (@components)" );
 237             }
 238         } # else if (@components == 1)
 239
 240         if (@components) {
 241             my $c = uri_unescape($components[0]);
 242             $input->param( 'keywords', $c );
 243             $input->param( 'package', $c );
 244         }
 245     }
 246
 247     my ( $pkg, @suites, @sections, @subsections, @archives, @archs );
 248
 249     my %params_def = ( keywords => { default => undef,
 250                                      array => '\s+',
 251                                      match => '^([-+\@\w\/.:]+)$',
 252                                  },
 253                        'package' => { default => undef,
 254                                       match => '^([\w.+-]+)$',
 255                                       var => \$pkg },
 256                        suite => { default => 'default', match => '^([\w-]+)$',
 257                                   array => ',', var => \@suites,
 258                                   replace => { all => \@SUITES,
 259                                                default => \@SUITES,
 260                                                %SUITES_ALIAS } },
 261                        archive => { default => ($what_to_do eq 'search') ?
 262                                         'all' : 'default',
 263                                         match => '^([\w-]+)$',
 264                                         array => ',', var => \@archives,
 265                                         replace => { all => \@ARCHIVES,
 266                                                      default => \@ARCHIVES} },
 267                        exact => { default => 0, match => '^(\w+)$',  },
 268                        lang => { default => undef, match => '^([\w-]+)$',  },
 269                        source => { default => 0, match => '^(\d+)$',  },
 270                        debug => { default => 0, match => '^(\d+)$',  },
 271                        searchon => { default => 'names', match => '^(\w+)$', },
 272                        section => { default => 'all', match => '^([\w-]+)$',
 273                                     alias => 'release', array => ',',
 274                                     var => \@sections,
 275                                     replace => { all => \@SECTIONS } },
 276                        subsection => { default => 'default', match => '^([\w-]+)$',
 277                                        array => ',', var => \@subsections,
 278                                        replace => { default => [] } },
 279                        priority => { default => 'default', match => '^([\w-]+)$',
 280                                      array => ',',
 281                                      replace => { default => [] } },
 282                        arch => { default => 'any', match => '^([\w-]+)$',
 283                                  array => ',', var => \@archs, replace =>
 284                                  { any => \@ARCHITECTURES } },
 285                        'format' => { default => 'html', match => '^([\w.]+)$',  },
 286                        mode => { default => '', match => '^(\w+)$',  },
 287                        sort_by => { default => 'file', match => '^(\w+)$', },
 288                        );
 289     my %opts;
 290     my %params = Packages::CGI::parse_params( $input, \%params_def, \%opts );
 291     Packages::CGI::init_url( $input, \%params, \%opts );
 292
 293     if (defined($opts{lang})) {
 294         $opts{po_lang} = $PO_LANGUAGES{$opts{lang}} ? $opts{lang} : 'en';
 295         $opts{ddtp_lang} = $DDTP_LANGUAGES{$opts{lang}} ? $opts{lang} : 'en';
 296     } else {
 297         $opts{po_lang} = $po_lang;
 298         $opts{ddtp_lang} = $ddtp_lang;
 299     }
 300     my $charset = "UTF-8";
 301     my $cat = Packages::I18N::Locale->get_handle( $opts{po_lang}, 'en' )
 302         or die "get_handle failed for $opts{po_lang}";
 303     $opts{cat} = $cat;
 304
 305     $opts{h_suites} = { map { $_ => 1 } @suites };
 306     $opts{h_sections} = { map { $_ => 1 } @sections };
 307     $opts{h_archives} = { map { $_ => 1 } @archives };
 308     $opts{h_archs} = { map { $_ => 1 } @archs };
 309
 310     if ((($opts{searchon} eq 'names') && $opts{source}) ||
 311         ($opts{searchon} eq 'sourcenames')) {
 312         $opts{source} = 1;
 313         $opts{searchon} = 'names',
 314         $opts{searchon_form} = 'sourcenames';
 315     } else {
 316         $opts{searchon_form} = $opts{searchon};
 317     }
 318     if ($opts{searchon} eq 'contents' or $opts{searchon} eq 'filenames') {
 319         $what_to_do = 'search_contents';
 320     }
 321
 322     my $pet1 = new Benchmark;
 323     my $petd = timediff($pet1, $pet0);
 324     debug( "Parameter evaluation took ".timestr($petd) ) if DEBUG;
 325
 326     my $template = new Packages::Template( $TEMPLATEDIR, $opts{format},
 327                                            { po_lang => $opts{po_lang}, ddtp_lang => $opts{ddtp_lang},
 328                                              charset => $charset, cat => $cat,
 329                                              debug => ( DEBUG ? $opts{debug} : 0 ) },
 330                                            ( $CACHEDIR ? { COMPILE_DIR => $CACHEDIR } : {} ) );
 331
 332     #FIXME: ugly hack
 333     unless (($what_to_do eq 'allpackages' and $opts{format} =~ /^(html|txt\.gz)/)
 334             || ($what_to_do eq 'index' and $opts{format} eq 'html')
 335             || -e "$TEMPLATEDIR/$opts{format}/${what_to_do}.tmpl") {
 336         fatal_error( $cat->g("requested format not available for this document"),
 337                      "406 requested format not available");
 338     }
 339
 340     my (%page_content);
 341     unless (@Packages::CGI::fatal_errors) {
 342         no strict 'refs';
 343         &{"do_$what_to_do"}( \%params, \%opts, \%page_content );
 344     }
 345
 346     $page_content{opts} = \%opts;
 347     $page_content{params} = \%params;
 348
 349     unless (@Packages::CGI::fatal_errors) {
 350         print $input->header(-charset => $charset,
 351                              -type => get_mime($opts{format}),
 352                              -vary => 'negotiate,accept-language',
 353                              -last_modified => strftime("%a, %d %b %Y %T %z",
 354                                                         localtime($last_modified)),
 355                              -expires => strftime("%a, %d %b %Y %T %z",
 356                                                   localtime($expires)),
 357                              );
 358         #use Data::Dumper;
 359         #print '<pre>'.Dumper(\%ENV, \%page_content, get_all_messages()).'</pre>';
 360         print $template->page( $what_to_do, { %page_content, %{ get_all_messages() } } );
 361     } elsif ($Packages::CGI::http_code && $Packages::CGI::http_code !~ /^2\d\d/) {
 362         print $input->header( -charset => $charset, -status => $Packages::CGI::http_code );
 363     } else {
 364         # We currently have only an error page in html
 365         # so no format support here
 366         print $input->header( -charset => $charset );
 367         print $template->error_page( get_all_messages() );
 368     }
 369 }
 370
 371 1;
 372 # vim: ts=8 sw=4