cgi-bin/search_packages.pl

   1 #!/usr/bin/perl -wT
   2 #
   3 # search_packages.pl -- CGI interface to the Packages files on packages.debian.org
   4 #
   5 # Copyright (C) 1998 James Treacy
   6 # Copyright (C) 2000, 2001 Josip Rodin
   7 # Copyright (C) 2001 Adam Heath
   8 # Copyright (C) 2004 Martin Schulze
   9 # Copyright (C) 2004-2006 Frank Lichtenheld
  10 #
  11 # use is allowed under the terms of the GNU Public License (GPL)
  12 # see http://www.fsf.org/copyleft/gpl.html for a copy of the license
  13
  14 use strict;
  15 use CGI qw( -oldstyle_urls );
  16 use CGI::Carp qw( fatalsToBrowser );
  17 use POSIX;
  18 use URI::Escape;
  19 use HTML::Entities;
  20 use DB_File;
  21 use Benchmark;
  22
  23 use lib "../lib";
  24
  25 use Deb::Versions;
  26 use Packages::Search qw( :all );
  27 use Packages::HTML ();
  28
  29 my $thisscript = $Packages::HTML::SEARCH_CGI;
  30 my $HOME = "http://www.debian.org";
  31 my $ROOT = "";
  32 my $SEARCHPAGE = "http://packages.debian.org/";
  33 my @SUITES = qw( oldstable stable testing unstable experimental );
  34 my @DISTS = @SUITES;
  35 my @SECTIONS = qw( main contrib non-free );
  36 my @ARCHIVES = qw( us security installer );
  37 my @ARCHITECTURES = qw( alpha amd64 arm hppa hurd-i386 i386 ia64
  38                         kfreebsd-i386 mips mipsel powerpc s390 sparc );
  39 my %SUITES = map { $_ => 1 } @SUITES;
  40 my %SECTIONS = map { $_ => 1 } @SECTIONS;
  41 my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
  42 my %ARCHITECTURES = map { $_ => 1 } @ARCHITECTURES;
  43
  44 $ENV{PATH} = "/bin:/usr/bin";
  45
  46 # Read in all the variables set by the form
  47 my $input;
  48 if ($ARGV[0] eq 'php') {
  49         $input = new CGI(\*STDIN);
  50 } else {
  51         $input = new CGI;
  52 }
  53
  54 my $pet0 = new Benchmark;
  55 # use this to disable debugging in production mode completly
  56 my $debug_allowed = 1;
  57 my $debug = $debug_allowed && $input->param("debug");
  58 $debug = 0 if not defined($debug);
  59 $Search::Param::debug = 1 if $debug > 1;
  60
  61 # If you want, just print out a list of all of the variables and exit.
  62 print $input->header if $debug;
  63 # print $input->dump;
  64 # exit;
  65
  66 if (my $path = $input->param('path')) {
  67     my @components = map { lc $_ } split /\//, $path;
  68
  69     foreach (@components) {
  70         if ($SUITES{$_}) {
  71             $input->param('suite', $_);
  72         } elsif ($SECTIONS{$_}) {
  73             $input->param('section', $_);
  74         } elsif ($ARCHIVES{$_}) {
  75             $input->param('archive', $_);
  76         }elsif ($ARCHITECTURES{$_}) {
  77             $input->param('arch', $_);
  78         }
  79     }
  80 }
  81
  82 my %params_def = ( keywords => { default => undef, match => '^\s*([-+\@\w\/.:]+)\s*$' },
  83                    suite => { default => 'stable', match => '^(\w+)$',
  84                               alias => 'version', array => ',',
  85                               replace => { all => \@SUITES } },
  86                    case => { default => 'insensitive', match => '^(\w+)$' },
  87                    official => { default => 0, match => '^(\w+)$' },
  88                    use_cache => { default => 1, match => '^(\w+)$' },
  89                    subword => { default => 0, match => '^(\w+)$' },
  90                    exact => { default => undef, match => '^(\w+)$' },
  91                    searchon => { default => 'all', match => '^(\w+)$' },
  92                    section => { default => 'all', match => '^([\w-]+)$',
  93                                 alias => 'release', array => ',',
  94                                 replace => { all => \@SECTIONS } },
  95                    arch => { default => 'any', match => '^(\w+)$',
  96                              array => ',', replace =>
  97                              { any => \@ARCHITECTURES } },
  98                    archive => { default => 'all', match => '^(\w+)$',
  99                                 array => ',', replace =>
 100                                 { all => \@ARCHIVES } },
 101                    format => { default => 'html', match => '^(\w+)$' },
 102                    );
 103 my %params = Packages::Search::parse_params( $input, \%params_def );
 104
 105 my $format = $params{values}{format}{final};
 106 #XXX: Don't use alternative output formats yet
 107 $format = 'html';
 108
 109 if ($format eq 'html') {
 110     print $input->header;
 111 } elsif ($format eq 'xml') {
 112 #    print $input->header( -type=>'application/rdf+xml' );
 113     print $input->header( -type=>'text/plain' );
 114 }
 115
 116 if ($params{errors}{keywords}) {
 117     print "Error: keyword not valid or missing" if $format eq 'html';
 118     exit 0;
 119 }
 120 my $keyword = $params{values}{keywords}{final};
 121 my @suites = @{$params{values}{suite}{final}};
 122 my $official = $params{values}{official}{final};
 123 my $use_cache = $params{values}{use_cache}{final};
 124 my $case = $params{values}{case}{final};
 125 my $case_bool = ( $case !~ /insensitive/ );
 126 my $subword = $params{values}{subword}{final};
 127 my $exact = $params{values}{exact}{final};
 128 $exact = !$subword unless defined $exact;
 129 my $searchon = $params{values}{searchon}{final};
 130 my @sections = @{$params{values}{section}{final}};
 131 my @archs = @{$params{values}{arch}{final}};
 132 my $page = $params{values}{page}{final};
 133 my $results_per_page = $params{values}{number}{final};
 134
 135 # for URL construction
 136 my $suites_param = join ',', @{$params{values}{suite}{no_replace}};
 137 my $sections_param = join ',', @{$params{values}{section}{no_replace}};
 138 my $archs_param = join ',', @{$params{values}{arch}{no_replace}};
 139
 140 # for output
 141 my $keyword_enc = encode_entities $keyword;
 142 my $searchon_enc = encode_entities $searchon;
 143 my $suites_enc = encode_entities join ', ', @{$params{values}{suite}{no_replace}};
 144 my $sections_enc = encode_entities join ', ', @{$params{values}{section}{no_replace}};
 145 my $archs_enc = encode_entities join ', ',  @{$params{values}{arch}{no_replace}};
 146 my $pet1 = new Benchmark;
 147 my $petd = timediff($pet1, $pet0);
 148 print "DEBUG: Parameter evaluation took ".timestr($petd)."<br>" if $debug;
 149
 150 if ($format eq 'html') {
 151 print Packages::HTML::header( title => 'Package Search Results' ,
 152                               lang => 'en',
 153                               title_tag => 'Debian Package Search Results',
 154                               print_title_above => 1,
 155                               print_search_field => 'packages',
 156                               search_field_values => {
 157                                   keywords => $keyword_enc,
 158                                   searchon => $searchon,
 159                                   arch => $archs_enc,
 160                                   suite => $suites_enc,
 161                                   section => $sections_enc,
 162                                   subword => $subword,
 163                                   exact => $exact,
 164                                   case => $case,
 165                                   },
 166                               );
 167 }
 168
 169 # read the configuration
 170 my $topdir;
 171 if (!open (C, "../config.sh")) {
 172     print "\nInternal Error: Cannot open configuration file.\n\n"
 173 if $format eq 'html';
 174     exit 0;
 175 }
 176 while (<C>) {
 177     $topdir = $1 if (/^\s*topdir="?(.*)"?\s*$/);
 178 }
 179 close (C);
 180
 181 my $DBDIR = $topdir . "/files/db";
 182 my $search_on_sources = 0;
 183
 184 my $st0 = new Benchmark;
 185 my @results;
 186 my $too_much_hits;
 187 if ($searchon eq 'sourcenames') {
 188     $search_on_sources = 1;
 189 }
 190
 191 my %suites = map { $_ => 1 } @suites;
 192 my %sections = map { $_ => 1 } @sections;
 193 my %archs = map { $_ => 1 } @archs;
 194
 195 print "DEBUG: suites=@suites, sections=@sections, archs=@archs<br>" if $debug > 2;
 196
 197 sub read_entry {
 198     my ($hash, $key, $results) = @_;
 199     my $result = $hash->{$key};
 200     foreach (split /\000/, $result) {
 201         my @data = split ( /\s/, $_, 7 );
 202         print "DEBUG: Considering entry ".join( ':', @data)."<br>" if $debug > 2;
 203         if ($suites{$data[0]} && ($archs{$data[1]} || $data[1] eq 'all')
 204             && $sections{$data[2]}) {
 205             print "DEBUG: Using entry ".join( ':', @data)."<br>" if $debug > 2;
 206             push @$results, [ $key, @data ];
 207         }
 208     }
 209 }
 210 sub read_src_entry {
 211     my ($hash, $key, $results) = @_;
 212     my $result = $hash->{$key};
 213
 214     foreach (split /\000/, $result) {
 215         my @data = split ( /\s/, $_, 5 );
 216         print "DEBUG: Considering entry ".join( ':', @data)."<br>" if $debug > 2;
 217         if ($suites{$data[0]} && $sections{$data[1]}) {
 218             print "DEBUG: Using entry ".join( ':', @data)."<br>" if $debug > 2;
 219             push @$results, [ $key, @data ];
 220         }
 221     }
 222 }
 223 sub do_names_search {
 224     my ($keyword, $file, $postfix_file, $read_entry) = @_;
 225
 226     $keyword = lc $keyword unless $case_bool;
 227
 228     my $obj = tie my %packages, 'DB_File', "$DBDIR/$file", O_RDONLY, 0666, $DB_BTREE
 229         or die "couldn't tie DB $DBDIR/$file: $!";
 230
 231     if ($exact) {
 232         &$read_entry( \%packages, $keyword, \@results );
 233     } else {
 234         my ($key, $prefixes) = ($keyword, '');
 235         my %pkgs;
 236         my $p_obj = tie my %pref, 'DB_File', "$DBDIR/$postfix_file", O_RDONLY, 0666, $DB_BTREE
 237             or die "couldn't tie postfix db $DBDIR/$postfix_file: $!";
 238         $p_obj->seq( $key, $prefixes, R_CURSOR );
 239         while (index($key, $keyword) >= 0) {
 240             if ($prefixes =~ /^\001(\d+)/o) {
 241                 $too_much_hits += $1;
 242             } else {
 243                 foreach (split /\000/o, $prefixes) {
 244                     $_ = '' if $_ eq '^';
 245                     print "DEBUG: add word $_$key<br>" if $debug > 2;
 246                     $pkgs{$_.$key}++;
 247                 }
 248             }
 249             last if $p_obj->seq( $key, $prefixes, R_NEXT ) != 0;
 250             last if $too_much_hits;
 251             last if keys %pkgs < 100;
 252         }
 253
 254         my $no_results = keys %pkgs;
 255         if ($too_much_hits || ($no_results >= 100)) {
 256             $too_much_hits += $no_results;
 257             %pkgs = ( $keyword => 1 );
 258         }
 259         foreach my $pkg (sort keys %pkgs) {
 260             &$read_entry( \%packages, $pkg, \@results );
 261         }
 262     }
 263 }
 264
 265 if ($searchon eq 'names') {
 266     do_names_search( $keyword, 'packages_small.db',
 267                      'package_postfixes.db', \&read_entry );
 268 } elsif ($searchon eq 'sourcenames') {
 269     do_names_search( $keyword, 'sources_small.db',
 270                      'source_postfixes.db', \&read_src_entry );
 271 } else {
 272
 273     my @lines;
 274     my $regex;
 275     if ($case_bool) {
 276         if ($exact) {
 277             $regex = qr/\b\Q$keyword\E\b/o;
 278         } else {
 279             $regex = qr/\Q$keyword\E/o;
 280         }
 281     } else {
 282         if ($exact) {
 283             $regex = qr/\b\Q$keyword\E\b/io;
 284         } else {
 285             $regex = qr/\Q$keyword\E/io;
 286         }
 287     }
 288
 289     open DESC, '<', "$DBDIR/descriptions.txt" or die "couldn't open $DBDIR/descriptions.txt: $!";
 290     while (<DESC>) {
 291         $_ =~ $regex or next;
 292         print "DEBUG: Matched line $.<br>" if $debug > 2;
 293         push @lines, $.;
 294     }
 295     close DESC;
 296
 297     my $obj = tie my %packages, 'DB_File', "$DBDIR/packages_small.db", O_RDONLY, 0666, $DB_BTREE
 298         or die "couldn't tie DB $DBDIR/packages_small.db: $!";
 299     my $obj = tie my %did2pkg, 'DB_File', "$DBDIR/descriptions_packages.db", O_RDONLY, 0666, $DB_BTREE
 300         or die "couldn't tie DB $DBDIR/descriptions_packages.db: $!";
 301
 302     my %tmp_results;
 303     foreach my $l (@lines) {
 304         my $result = $did2pkg{$l};
 305         foreach (split /\000/o, $result) {
 306             my @data = split /\s/, $_, 3;
 307             next unless $archs{$data[2]};
 308             $tmp_results{$data[0]}++;
 309         }
 310     }
 311     foreach my $pkg (keys %tmp_results) {
 312         read_entry( \%packages, $pkg, \@results );
 313     }
 314 }
 315
 316 my $st1 = new Benchmark;
 317 my $std = timediff($st1, $st0);
 318 print "DEBUG: Search took ".timestr($std)."<br>" if $debug;
 319
 320 if ($format eq 'html') {
 321     my $suite_wording = $suites_enc eq "all" ? "all suites"
 322         : "suite(s) <em>$suites_enc</em>";
 323     my $section_wording = $sections_enc eq 'all' ? "all sections"
 324         : "section(s) <em>$sections_enc</em>";
 325     my $arch_wording = $archs_enc eq 'any' ? "all architectures"
 326         : "architecture(s) <em>$archs_enc</em>";
 327     if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 328         my $source_wording = $search_on_sources ? "source " : "";
 329         my $exact_wording = $exact ? "named" : "that names contain";
 330         print "<p>You have searched for ${source_wording}packages $exact_wording <em>$keyword_enc</em> in $suite_wording, $section_wording, and $arch_wording.</p>";
 331     } else {
 332         my $exact_wording = $exact ? "" : " (including subword matching)";
 333         print "<p>You have searched for <em>$keyword_enc</em> in packages names and descriptions in $suite_wording, $section_wording, and $arch_wording$exact_wording.</p>";
 334     }
 335 }
 336
 337 if ($too_much_hits) {
 338 print "<p><strong>Your search was too wide so we will only display exact matches. At least <em>$too_much_hits</em> results have been omitted and will not be displayed. Please consider using a longer keyword or more keywords.</strong></p>";
 339 }
 340
 341 if (!@results) {
 342     if ($format eq 'html') {
 343         my $keyword_esc = uri_escape( $keyword );
 344         my $printed = 0;
 345         if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 346             if (($suites_enc eq 'all')
 347                 && ($archs_enc eq 'any')
 348                 && ($sections_enc eq 'all')) {
 349                 print "<p><strong>Can't find that package.</strong></p>\n";
 350             } else {
 351                 print "<p><strong>Can't find that package, at least not in that suite ".
 352                     ( $search_on_sources ? "" : " and on that architecture" ).
 353                     ".</strong></p>\n";
 354             }
 355
 356             if ($exact) {
 357                 $printed = 1;
 358                 print "<p>You have searched only for exact matches of the package name. You can try to search for <a href=\"$thisscript?exact=0&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">package names that contain your search string</a>.</p>";
 359             }
 360         } else {
 361             if (($suites_enc eq 'all')
 362                 && ($archs_enc eq 'any')
 363                 && ($sections_enc eq 'all')) {
 364                 print "<p><strong>Can't find that string.</strong></p>\n";
 365             } else {
 366                 print "<p><strong>Can't find that string, at least not in that suite ($suites_enc, section $sections_enc) and on that architecture ($archs_enc).</strong></p>\n";
 367             }
 368
 369             unless ($subword) {
 370                 $printed = 1;
 371                 print "<p>You have searched only for words exactly matching your keywords. You can try to search <a href=\"$thisscript?subword=1&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">allowing subword matching</a>.</p>";
 372             }
 373         }
 374         print "<p>".( $printed ? "Or you" : "You" )." can try a different search on the <a href=\"$SEARCHPAGE#search_packages\">Packages search page</a>.</p>";
 375
 376         &printfooter;
 377     }
 378     exit;
 379 }
 380
 381 my (%pkgs, %sect, %part, %desc, %binaries);
 382
 383 unless ($search_on_sources) {
 384     foreach (@results) {
 385         my ($pkg_t, $suite, $arch, $section, $subsection,
 386             $priority, $version, $desc) = @$_;
 387
 388         my ($package) = $pkg_t =~ m/^(.+)/; # untaint
 389         $pkgs{$package}{$suite}{$version}{$arch} = 1;
 390         $sect{$package}{$suite}{$version} = $subsection;
 391         $part{$package}{$suite}{$version} = $section unless $section eq 'main';
 392
 393         $desc{$package}{$suite}{$version} = $desc;
 394
 395     }
 396
 397     if ($format eq 'html') {
 398         my ($start, $end) = multipageheader( scalar keys %pkgs );
 399         my $count = 0;
 400
 401         foreach my $pkg (sort keys %pkgs) {
 402             $count++;
 403             next if $count < $start or $count > $end;
 404             printf "<h3>Package %s</h3>\n", $pkg;
 405             print "<ul>\n";
 406             foreach my $ver (@SUITES) {
 407                 if (exists $pkgs{$pkg}{$ver}) {
 408                     my @versions = version_sort keys %{$pkgs{$pkg}{$ver}};
 409                     my $part_str = "";
 410                     if ($part{$pkg}{$ver}{$versions[0]}) {
 411                         $part_str = "[<span style=\"color:red\">$part{$pkg}{$ver}{$versions[0]}</span>]";
 412                     }
 413                     printf "<li><a href=\"$ROOT/%s/%s/%s\">%s</a> (%s): %s   %s\n",
 414                     $ver, $sect{$pkg}{$ver}{$versions[0]}, $pkg, $ver, $sect{$pkg}{$ver}{$versions[0]}, $desc{$pkg}{$ver}{$versions[0]}, $part_str;
 415
 416                     foreach my $v (@versions) {
 417                         printf "<br>%s: %s\n",
 418                         $v, join (" ", (sort keys %{$pkgs{$pkg}{$ver}{$v}}) );
 419                     }
 420                     print "</li>\n";
 421                 }
 422             }
 423             print "</ul>\n";
 424         }
 425     } elsif ($format eq 'xml') {
 426         require RDF::Simple::Serialiser;
 427         my $rdf = new RDF::Simple::Serialiser;
 428         $rdf->addns( debpkg => 'http://packages.debian.org/xml/01-debian-packages-rdf' );
 429         my @triples;
 430         foreach my $pkg (sort keys %pkgs) {
 431             foreach my $ver (@DISTS) {
 432                 if (exists $pkgs{$pkg}{$ver}) {
 433                     my @versions = version_sort keys %{$pkgs{$pkg}{$ver}};
 434                     foreach my $version (@versions) {
 435                         my $id = "$ROOT/$ver/$sect{$pkg}{$ver}{$version}/$pkg/$version";
 436                         push @triples, [ $id, 'debpkg:package', $pkg ];
 437                         push @triples, [ $id, 'debpkg:version', $version ];
 438                         push @triples, [ $id, 'debpkg:section', $sect{$pkg}{$ver}{$version}, ];
 439                         push @triples, [ $id, 'debpkg:suite', $ver ];
 440                         push @triples, [ $id, 'debpkg:shortdesc', $desc{$pkg}{$ver}{$version} ];
 441                         push @triples, [ $id, 'debpkg:part', $part{$pkg}{$ver}{$version} || 'main' ];
 442                         foreach my $arch (sort keys %{$pkgs{$pkg}{$ver}{$version}}) {
 443                             push @triples, [ $id, 'debpkg:architecture', $arch ];
 444                         }
 445                     }
 446                 }
 447             }
 448         }
 449
 450         print $rdf->serialise(@triples);
 451     }
 452 } else {
 453     foreach (@results) {
 454         my ($package, $suite, $section, $subsection, $priority,
 455             $version, $binaries) = @$_;
 456
 457         $pkgs{$package}{$suite} = $version;
 458         $sect{$package}{$suite}{source} = $subsection;
 459         $part{$package}{$suite}{source} = $section unless $section eq 'main';
 460
 461         $binaries{$package}{$suite} = [ sort split( /\s*,\s*/, $binaries ) ];
 462     }
 463
 464     if ($format eq 'html') {
 465         my ($start, $end) = multipageheader( scalar keys %pkgs );
 466         my $count = 0;
 467
 468         foreach my $pkg (sort keys %pkgs) {
 469             $count++;
 470             next if ($count < $start) or ($count > $end);
 471             printf "<h3>Source package %s</h3>\n", $pkg;
 472             print "<ul>\n";
 473             foreach my $ver (@SUITES) {
 474                 if (exists $pkgs{$pkg}{$ver}) {
 475                     my $part_str = "";
 476                     if ($part{$pkg}{$ver}{source}) {
 477                         $part_str = "[<span style=\"color:red\">$part{$pkg}{$ver}{source}</span>]";
 478                     }
 479                     printf "<li><a href=\"$ROOT/%s/source/%s\">%s</a> (%s): %s   %s", $ver, $pkg, $ver, $sect{$pkg}{$ver}{source}, $pkgs{$pkg}{$ver}, $part_str;
 480
 481                     print "<br>Binary packages: ";
 482                     my @bp_links;
 483                     foreach my $bp (@{$binaries{$pkg}{$ver}}) {
 484                         my $sect = 'section';
 485
 486                         my $bp_link;
 487                         if ($sect) {
 488                             $bp_link = sprintf( "<a href=\"$ROOT/%s/%s/%s\">%s</a>",
 489                                                 $ver, $sect, uri_escape( $bp ),  $bp );
 490                         } else {
 491                             $bp_link = $bp;
 492                         }
 493                         push @bp_links, $bp_link;
 494                     }
 495                     print join( ", ", @bp_links );
 496                     print "</li>\n";
 497                 }
 498             }
 499             print "</ul>\n";
 500         }
 501     } elsif ($format eq 'xml') {
 502         require RDF::Simple::Serialiser;
 503         my $rdf = new RDF::Simple::Serialiser;
 504         $rdf->addns( debpkg => 'http://packages.debian.org/xml/01-debian-packages-rdf' );
 505         my @triples;
 506         foreach my $pkg (sort keys %pkgs) {
 507             foreach my $ver (@SUITES) {
 508                 if (exists $pkgs{$pkg}{$ver}) {
 509                     my $id = "$ROOT/$ver/source/$pkg";
 510
 511                     push @triples, [ $id, 'debpkg:package', $pkg ];
 512                     push @triples, [ $id, 'debpkg:type', 'source' ];
 513                     push @triples, [ $id, 'debpkg:section', $sect{$pkg}{$ver}{source} ];
 514                     push @triples, [ $id, 'debpkg:version', $pkgs{$pkg}{$ver} ];
 515                     push @triples, [ $id, 'debpkg:part', $part{$pkg}{$ver}{source} || 'main' ];
 516
 517                     foreach my $bp (@{$binaries{$pkg}{$ver}}) {
 518                         push @triples, [ $id, 'debpkg:binary', $bp ];
 519                     }
 520                 }
 521             }
 522         }
 523         print $rdf->serialise(@triples);
 524     }
 525 }
 526
 527 if ($format eq 'html') {
 528     &printindexline( scalar keys %pkgs );
 529     &printfooter;
 530 }
 531
 532 exit;
 533
 534 sub printindexline {
 535     my $no_results = shift;
 536
 537     my $index_line;
 538     if ($no_results > $results_per_page) {
 539
 540         $index_line = prevlink($input,\%params)." | ".
 541             indexline( $input, \%params, $no_results)." | ".
 542             nextlink($input,\%params, $no_results);
 543
 544         print "<p style=\"text-align:center\">$index_line</p>";
 545     }
 546 }
 547
 548 sub multipageheader {
 549     my $no_results = shift;
 550
 551     my ($start, $end);
 552     if ($results_per_page =~ /^all$/i) {
 553         $start = 1;
 554         $end = $no_results;
 555         $results_per_page = $no_results;
 556     } else {
 557         $start = Packages::Search::start( \%params );
 558         $end = Packages::Search::end( \%params );
 559         if ($end > $no_results) { $end = $no_results; }
 560     }
 561
 562     print "<p>Found <em>$no_results</em> matching packages,";
 563     if ($end == $start) {
 564         print " displaying package $end.</p>";
 565     } else {
 566         print " displaying packages $start to $end.</p>";
 567     }
 568
 569     printindexline( $no_results );
 570
 571     if ($no_results > 100) {
 572         print "<p>Results per page: ";
 573         my @resperpagelinks;
 574         for (50, 100, 200) {
 575             if ($results_per_page == $_) {
 576                 push @resperpagelinks, $_;
 577             } else {
 578                 push @resperpagelinks, resperpagelink($input,\%params,$_);
 579             }
 580         }
 581         if ($params{values}{number}{final} =~ /^all$/i) {
 582             push @resperpagelinks, "all";
 583         } else {
 584             push @resperpagelinks, resperpagelink($input, \%params,"all");
 585         }
 586         print join( " | ", @resperpagelinks )."</p>";
 587     }
 588     return ( $start, $end );
 589 }
 590
 591 sub printfooter {
 592 print <<END;
 593 </div>
 594
 595 <hr class="hidecss">
 596 <p style="text-align:right;font-size:small;font-stlye:italic"><a href="$SEARCHPAGE">Packages search page</a></p>
 597
 598 </div>
 599 END
 600
 601 print $input->end_html;
 602 }
 603
 604 # vim: ts=8 sw=4