cgi-bin/search_packages.pl

   1 #!/usr/bin/perl -wT
   2 # $Id$
   3 # search_packages.pl -- CGI interface to the Packages files on packages.debian.org
   4 #
   5 # Copyright (C) 1998 James Treacy
   6 # Copyright (C) 2000, 2001 Josip Rodin
   7 # Copyright (C) 2001 Adam Heath
   8 # Copyright (C) 2004 Martin Schulze
   9 # Copyright (C) 2004-2006 Frank Lichtenheld
  10 #
  11 # use is allowed under the terms of the GNU Public License (GPL)
  12 # see http://www.fsf.org/copyleft/gpl.html for a copy of the license
  13
  14 use strict;
  15 use lib '../lib';
  16 use CGI qw( -oldstyle_urls );
  17 use CGI::Carp qw( fatalsToBrowser );
  18 use POSIX;
  19 use URI::Escape;
  20 use HTML::Entities;
  21 use DB_File;
  22 use Benchmark;
  23
  24 use Deb::Versions;
  25 use Packages::Config qw( $DBDIR $ROOT $SEARCH_CGI $SEARCH_PAGE
  26                          @SUITES @SECTIONS @ARCHIVES @ARCHITECTURES );
  27 use Packages::CGI;
  28 use Packages::DB;
  29 use Packages::Search qw( :all );
  30 use Packages::HTML ();
  31
  32 &Packages::CGI::reset;
  33
  34 $ENV{PATH} = "/bin:/usr/bin";
  35
  36 # Read in all the variables set by the form
  37 my $input;
  38 if ($ARGV[0] && ($ARGV[0] eq 'php')) {
  39         $input = new CGI(\*STDIN);
  40 } else {
  41         $input = new CGI;
  42 }
  43
  44 my $pet0 = new Benchmark;
  45 my $tet0 = new Benchmark;
  46 # use this to disable debugging in production mode completly
  47 my $debug_allowed = 1;
  48 my $debug = $debug_allowed && $input->param("debug");
  49 $debug = 0 if !defined($debug) || $debug !~ /^\d+$/o;
  50 $Packages::CGI::debug = $debug;
  51
  52 &Packages::Config::init( '../' );
  53 &Packages::DB::init();
  54
  55 if (my $path = $input->param('path')) {
  56     my @components = map { lc $_ } split /\//, $path;
  57
  58     my %SUITES = map { $_ => 1 } @SUITES;
  59     my %SECTIONS = map { $_ => 1 } @SECTIONS;
  60     my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
  61     my %ARCHITECTURES = map { $_ => 1 } @ARCHITECTURES;
  62
  63     foreach (@components) {
  64         if ($SUITES{$_}) {
  65             $input->param('suite', $_);
  66         } elsif ($SECTIONS{$_}) {
  67             $input->param('section', $_);
  68         } elsif ($ARCHIVES{$_}) {
  69             $input->param('archive', $_);
  70         } elsif ($ARCHITECTURES{$_}) {
  71             $input->param('arch', $_);
  72         } elsif ($_ eq 'source') {
  73             $input->param('searchon','sourcenames');
  74         }
  75     }
  76 }
  77
  78 my ( $format, $keyword, $case, $subword, $exact, $searchon,
  79      @suites, @sections, @archives, @archs );
  80
  81 my %params_def = ( keywords => { default => undef,
  82                                  match => '^\s*([-+\@\w\/.:]+)\s*$',
  83                                  var => \$keyword },
  84                    suite => { default => 'stable', match => '^([\w-]+)$',
  85                               alias => 'version', array => ',',
  86                               var => \@suites,
  87                               replace => { all => \@SUITES } },
  88                    archive => { default => 'all', match => '^([\w-]+)$',
  89                                 array => ',', var => \@archives,
  90                                 replace => { all => \@ARCHIVES } },
  91                    case => { default => 'insensitive', match => '^(\w+)$',
  92                              var => \$case },
  93                    official => { default => 0, match => '^(\w+)$' },
  94                    subword => { default => 0, match => '^(\w+)$',
  95                                 var => \$subword },
  96                    exact => { default => undef, match => '^(\w+)$',
  97                               var => \$exact },
  98                    searchon => { default => 'all', match => '^(\w+)$',
  99                                  var => \$searchon },
 100                    section => { default => 'all', match => '^([\w-]+)$',
 101                                 alias => 'release', array => ',',
 102                                 var => \@sections,
 103                                 replace => { all => \@SECTIONS } },
 104                    arch => { default => 'any', match => '^(\w+)$',
 105                              array => ',', var => \@archs, replace =>
 106                              { any => \@ARCHITECTURES } },
 107                    format => { default => 'html', match => '^(\w+)$',
 108                                var => \$format },
 109                    );
 110 my %opts;
 111 my %params = Packages::Search::parse_params( $input, \%params_def, \%opts );
 112
 113 #XXX: Don't use alternative output formats yet
 114 $format = 'html';
 115 if ($format eq 'html') {
 116     print $input->header;
 117 }
 118
 119 if ($params{errors}{keywords}) {
 120     fatal_error( "keyword not valid or missing" );
 121 } elsif (length($keyword) < 2) {
 122     fatal_error( "keyword too short (keywords need to have at least two characters)" );
 123 }
 124
 125 my $case_bool = ( $case !~ /insensitive/ );
 126 $exact = !$subword unless defined $exact;
 127 $opts{h_suites} = { map { $_ => 1 } @suites };
 128 $opts{h_sections} = { map { $_ => 1 } @sections };
 129 $opts{h_archives} = { map { $_ => 1 } @archives };
 130 $opts{h_archs} = { map { $_ => 1 } @archs };
 131
 132 # for URL construction
 133 my $suites_param = join ',', @{$params{values}{suite}{no_replace}};
 134 my $sections_param = join ',', @{$params{values}{section}{no_replace}};
 135 my $archs_param = join ',', @{$params{values}{arch}{no_replace}};
 136
 137 # for output
 138 my $keyword_enc = encode_entities $keyword || '';
 139 my $searchon_enc = encode_entities $searchon;
 140 my $suites_enc = encode_entities join ', ', @{$params{values}{suite}{no_replace}};
 141 my $sections_enc = encode_entities join ', ', @{$params{values}{section}{no_replace}};
 142 my $archs_enc = encode_entities join ', ',  @{$params{values}{arch}{no_replace}};
 143 my $pet1 = new Benchmark;
 144 my $petd = timediff($pet1, $pet0);
 145 debug( "Parameter evaluation took ".timestr($petd) );
 146
 147 my $st0 = new Benchmark;
 148 my @results;
 149
 150 unless (@Packages::CGI::fatal_errors) {
 151
 152     if ($searchon eq 'names') {
 153         push @results, @{ do_names_search( $keyword, \%packages,
 154                                            $p_obj,
 155                                            \&read_entry, \%opts ) };
 156     } elsif ($searchon eq 'sourcenames') {
 157         push @results, @{ do_names_search( $keyword, \%sources,
 158                                            $sp_obj,
 159                                            \&read_src_entry, \%opts ) };
 160     } else {
 161         push @results, @{ do_names_search( $keyword, \%packages,
 162                                            $p_obj,
 163                                            \&read_entry, \%opts ) };
 164         push @results, @{ do_fulltext_search( $keyword, "$DBDIR/descriptions.txt",
 165                                               \%did2pkg,
 166                                               \%packages,
 167                                               \&read_entry, \%opts ) };
 168     }
 169 }
 170
 171 my $st1 = new Benchmark;
 172 my $std = timediff($st1, $st0);
 173 debug( "Search took ".timestr($std) );
 174
 175 if ($format eq 'html') {
 176     my $suite_wording = $suites_enc eq "all" ? "all suites"
 177         : "suite(s) <em>$suites_enc</em>";
 178     my $section_wording = $sections_enc eq 'all' ? "all sections"
 179         : "section(s) <em>$sections_enc</em>";
 180     my $arch_wording = $archs_enc eq 'any' ? "all architectures"
 181         : "architecture(s) <em>$archs_enc</em>";
 182     if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 183         my $source_wording = ( $searchon eq 'sourcenames' ) ? "source " : "";
 184         my $exact_wording = $exact ? "named" : "that names contain";
 185         msg( "You have searched for ${source_wording}packages $exact_wording <em>$keyword_enc</em> in $suite_wording, $section_wording, and $arch_wording." );
 186     } else {
 187         my $exact_wording = $exact ? "" : " (including subword matching)";
 188         msg( "You have searched for <em>$keyword_enc</em> in packages names and descriptions in $suite_wording, $section_wording, and $arch_wording$exact_wording." );
 189     }
 190 }
 191
 192 if ($Packages::Search::too_many_hits) {
 193     error( "Your search was too wide so we will only display exact matches. At least <em>$Packages::Search::too_many_hits</em> results have been omitted and will not be displayed. Please consider using a longer keyword or more keywords." );
 194 }
 195
 196 if (!@Packages::CGI::fatal_errors && !@results) {
 197     if ($format eq 'html') {
 198         my $keyword_esc = uri_escape( $keyword );
 199         my $printed = 0;
 200         if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 201             if (($suites_enc eq 'all')
 202                 && ($archs_enc eq 'any')
 203                 && ($sections_enc eq 'all')) {
 204                 error( "Can't find that package." );
 205             } else {
 206                 error( "Can't find that package, at least not in that suite ".
 207                     ( ( $searchon eq 'sourcenames' ) ? "" : " and on that architecture" ) )
 208             }
 209
 210             if ($exact) {
 211                 $printed++;
 212                 hint( "You have searched only for exact matches of the package name. You can try to search for <a href=\"$SEARCH_CGI?exact=0&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">package names that contain your search string</a>." );
 213             }
 214         } else {
 215             if (($suites_enc eq 'all')
 216                 && ($archs_enc eq 'any')
 217                 && ($sections_enc eq 'all')) {
 218                 error( "Can't find that string." );
 219             } else {
 220                 error( "Can't find that string, at least not in that suite ($suites_enc, section $sections_enc) and on that architecture ($archs_enc)." );
 221             }
 222
 223             unless ($subword) {
 224                 $printed++;
 225                 hint( "You have searched only for words exactly matching your keywords. You can try to search <a href=\"$SEARCH_CGI?subword=1&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">allowing subword matching</a>." );
 226             }
 227         }
 228         hint( ( $printed ? "Or you" : "You" )." can try a different search on the <a href=\"$SEARCH_PAGE#search_packages\">Packages search page</a>." );
 229
 230     }
 231 }
 232
 233 print Packages::HTML::header( title => 'Package Search Results' ,
 234                               lang => 'en',
 235                               title_tag => 'Debian Package Search Results',
 236                               print_title_above => 1,
 237                               print_search_field => 'packages',
 238                               search_field_values => {
 239                                   keywords => $keyword_enc,
 240                                   searchon => $searchon,
 241                                   arch => $archs_enc,
 242                                   suite => $suites_enc,
 243                                   section => $sections_enc,
 244                                   subword => $subword,
 245                                   exact => $exact,
 246                                   case => $case,
 247                                   debug => $debug,
 248                               },
 249                               );
 250 print_msgs();
 251 print_errors();
 252 print_hints();
 253 print_debug();
 254 if (@results) {
 255     my (%pkgs, %subsect, %sect, %desc, %binaries);
 256
 257     unless ($opts{searchon} eq 'sourcenames') {
 258         foreach (@results) {
 259             my ($pkg_t, $archive, $suite, $arch, $section, $subsection,
 260                 $priority, $version, $desc) = @$_;
 261
 262             my ($pkg) = $pkg_t =~ m/^(.+)/; # untaint
 263             $pkgs{$pkg}{$suite}{$archive}{$version}{$arch} = 1;
 264             $subsect{$pkg}{$suite}{$archive}{$version} = $subsection;
 265             $sect{$pkg}{$suite}{$archive}{$version} = $section
 266                 unless $section eq 'main';
 267
 268             $desc{$pkg}{$suite}{$archive}{$version} = $desc;
 269         }
 270
 271         if ($opts{format} eq 'html') {
 272             my ($start, $end) = multipageheader( $input, scalar keys %pkgs, \%opts );
 273             my $count = 0;
 274
 275             foreach my $pkg (sort keys %pkgs) {
 276                 $count++;
 277                 next if $count < $start or $count > $end;
 278                 printf "<h3>Package %s</h3>\n", $pkg;
 279                 print "<ul>\n";
 280                 foreach my $suite (@SUITES) {
 281                     foreach my $archive (@ARCHIVES) {
 282                         if (exists $pkgs{$pkg}{$suite}{$archive}) {
 283                             my @versions = version_sort keys %{$pkgs{$pkg}{$suite}{$archive}};
 284                             my $origin_str = "";
 285                             if ($sect{$pkg}{$suite}{$archive}{$versions[0]}) {
 286                                 $origin_str .= " [<span style=\"color:red\">$sect{$pkg}{$suite}{$versions[0]}</span>]";
 287                             }
 288                             printf "<li><a href=\"$ROOT/%s/%s\">%s</a> (%s): %s   %s\n",
 289                             $suite.(($archive ne 'us')?"/$archive":''), $pkg, $suite.(($archive ne 'us')?"/$archive":''), $subsect{$pkg}{$suite}{$archive}{$versions[0]},
 290                             $desc{$pkg}{$suite}{$archive}{$versions[0]}, $origin_str;
 291
 292                             foreach my $v (@versions) {
 293                                 printf "<br>%s: %s\n",
 294                                 $v, join (" ", (sort keys %{$pkgs{$pkg}{$suite}{$archive}{$v}}) );
 295                             }
 296                             print "</li>\n";
 297                         }
 298                     }
 299                 }
 300                 print "</ul>\n";
 301             }
 302         }
 303     } else {
 304         foreach (@results) {
 305             my ($pkg, $archive, $suite, $section, $subsection, $priority,
 306                 $version) = @$_;
 307
 308             $pkgs{$pkg}{$suite}{$archive} = $version;
 309             $subsect{$pkg}{$suite}{$archive}{source} = $subsection;
 310             $sect{$pkg}{$suite}{$archive}{source} = $section
 311                 unless $section eq 'main';
 312
 313             $binaries{$pkg}{$suite}{$archive} = find_binaries( $pkg, $archive, $suite, \%src2bin );
 314         }
 315
 316         if ($opts{format} eq 'html') {
 317             my ($start, $end) = multipageheader( $input, scalar keys %pkgs, \%opts );
 318             my $count = 0;
 319
 320             foreach my $pkg (sort keys %pkgs) {
 321                 $count++;
 322                 next if ($count < $start) or ($count > $end);
 323                 printf "<h3>Source package %s</h3>\n", $pkg;
 324                 print "<ul>\n";
 325                 foreach my $suite (@SUITES) {
 326                     foreach my $archive (@ARCHIVES) {
 327                         if (exists $pkgs{$pkg}{$suite}{$archive}) {
 328                             my $origin_str = "";
 329                             if ($sect{$pkg}{$suite}{$archive}{source}) {
 330                                 $origin_str .= " [<span style=\"color:red\">$sect{$pkg}{$suite}{$archive}{source}</span>]";
 331                             }
 332                             printf( "<li><a href=\"$ROOT/%s/source/%s\">%s</a> (%s): %s   %s",
 333                                     $suite.(($archive ne 'us')?"/$archive":''), $pkg, $suite.(($archive ne 'us')?"/$archive":''), $subsect{$pkg}{$suite}{$archive}{source},
 334                                     $pkgs{$pkg}{$suite}{$archive}, $origin_str );
 335
 336                             print "<br>Binary packages: ";
 337                             my @bp_links;
 338                             foreach my $bp (@{$binaries{$pkg}{$suite}{$archive}}) {
 339                                 my $bp_link = sprintf( "<a href=\"$ROOT/%s/%s\">%s</a>",
 340                                                        $suite.(($archive ne 'us')?"/$archive":''), uri_escape( $bp ),  $bp );
 341                                 push @bp_links, $bp_link;
 342                             }
 343                             print join( ", ", @bp_links );
 344                             print "</li>\n";
 345                         }
 346                     }
 347                 }
 348                 print "</ul>\n";
 349             }
 350         }
 351     }
 352     printindexline( $input, scalar keys %pkgs, \%opts );
 353 }
 354 #print_results(\@results, \%opts) if @results;;
 355 my $tet1 = new Benchmark;
 356 my $tetd = timediff($tet1, $tet0);
 357 print "Total page evaluation took ".timestr($tetd)."<br>"
 358     if $debug_allowed;
 359
 360 my $trailer = Packages::HTML::trailer( $ROOT );
 361 $trailer =~ s/LAST_MODIFIED_DATE/gmtime()/e; #FIXME
 362 print $trailer;
 363
 364 # vim: ts=8 sw=4