cgi-bin/search_packages.pl

   1 #!/usr/bin/perl -wT
   2 # $Id$
   3 # search_packages.pl -- CGI interface to the Packages files on packages.debian.org
   4 #
   5 # Copyright (C) 1998 James Treacy
   6 # Copyright (C) 2000, 2001 Josip Rodin
   7 # Copyright (C) 2001 Adam Heath
   8 # Copyright (C) 2004 Martin Schulze
   9 # Copyright (C) 2004-2006 Frank Lichtenheld
  10 #
  11 # use is allowed under the terms of the GNU Public License (GPL)
  12 # see http://www.fsf.org/copyleft/gpl.html for a copy of the license
  13
  14 use strict;
  15 use lib '../lib';
  16 use CGI qw( -oldstyle_urls );
  17 use CGI::Carp qw( fatalsToBrowser );
  18 use POSIX;
  19 use URI::Escape;
  20 use HTML::Entities;
  21 use DB_File;
  22 use Benchmark;
  23
  24 use Deb::Versions;
  25 use Packages::Config qw( $DBDIR $ROOT $SEARCH_CGI $SEARCH_PAGE
  26                          @SUITES @SECTIONS @ARCHIVES @ARCHITECTURES );
  27 use Packages::CGI;
  28 use Packages::DB;
  29 use Packages::Search qw( :all );
  30 use Packages::HTML ();
  31
  32 &Packages::CGI::reset;
  33
  34 $ENV{PATH} = "/bin:/usr/bin";
  35
  36 # Read in all the variables set by the form
  37 my $input;
  38 if ($ARGV[0] && ($ARGV[0] eq 'php')) {
  39         $input = new CGI(\*STDIN);
  40 } else {
  41         $input = new CGI;
  42 }
  43
  44 my $pet0 = new Benchmark;
  45 my $tet0 = new Benchmark;
  46 # use this to disable debugging in production mode completly
  47 my $debug_allowed = 1;
  48 my $debug = $debug_allowed && $input->param("debug");
  49 $debug = 0 if !defined($debug) || $debug !~ /^\d+$/o;
  50 $Packages::CGI::debug = $debug;
  51
  52 &Packages::Config::init( '../' );
  53 &Packages::DB::init();
  54
  55 if (my $path = $input->param('path')) {
  56     my @components = map { lc $_ } split /\//, $path;
  57
  58     my %SUITES = map { $_ => 1 } @SUITES;
  59     my %SECTIONS = map { $_ => 1 } @SECTIONS;
  60     my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
  61     my %ARCHITECTURES = map { $_ => 1 } @ARCHITECTURES;
  62
  63     foreach (@components) {
  64         if ($SUITES{$_}) {
  65             $input->param('suite', $_);
  66         } elsif ($SECTIONS{$_}) {
  67             $input->param('section', $_);
  68         } elsif ($ARCHIVES{$_}) {
  69             $input->param('archive', $_);
  70         } elsif ($ARCHITECTURES{$_}) {
  71             $input->param('arch', $_);
  72         } elsif ($_ eq 'source') {
  73             $input->param('searchon','sourcenames');
  74         }
  75     }
  76 }
  77
  78 my ( $format, $keyword, $case, $subword, $exact, $searchon,
  79      @suites, @sections, @archives, @archs );
  80
  81 my %params_def = ( keywords => { default => undef,
  82                                  match => '^\s*([-+\@\w\/.:]+)\s*$',
  83                                  var => \$keyword },
  84                    suite => { default => 'stable', match => '^([\w-]+)$',
  85                               alias => 'version', array => ',',
  86                               var => \@suites,
  87                               replace => { all => \@SUITES } },
  88                    archive => { default => 'all', match => '^([\w-]+)$',
  89                                 array => ',', var => \@archives,
  90                                 replace => { all => \@ARCHIVES } },
  91                    case => { default => 'insensitive', match => '^(\w+)$',
  92                              var => \$case },
  93                    official => { default => 0, match => '^(\w+)$' },
  94                    subword => { default => 0, match => '^(\w+)$',
  95                                 var => \$subword },
  96                    exact => { default => undef, match => '^(\w+)$',
  97                               var => \$exact },
  98                    searchon => { default => 'all', match => '^(\w+)$',
  99                                  var => \$searchon },
 100                    section => { default => 'all', match => '^([\w-]+)$',
 101                                 alias => 'release', array => ',',
 102                                 var => \@sections,
 103                                 replace => { all => \@SECTIONS } },
 104                    arch => { default => 'any', match => '^(\w+)$',
 105                              array => ',', var => \@archs, replace =>
 106                              { any => \@ARCHITECTURES } },
 107                    format => { default => 'html', match => '^(\w+)$',
 108                                var => \$format },
 109                    );
 110 my %opts;
 111 my %params = Packages::Search::parse_params( $input, \%params_def, \%opts );
 112
 113 #XXX: Don't use alternative output formats yet
 114 $format = 'html';
 115 if ($format eq 'html') {
 116     print $input->header( -charset => 'utf-8' );
 117 }
 118
 119 if ($params{errors}{keywords}) {
 120     fatal_error( "keyword not valid or missing" );
 121 } elsif (length($keyword) < 2) {
 122     fatal_error( "keyword too short (keywords need to have at least two characters)" );
 123 }
 124
 125 my $case_bool = ( $case !~ /insensitive/ );
 126 $exact = !$subword unless defined $exact;
 127 $opts{h_suites} = { map { $_ => 1 } @suites };
 128 $opts{h_sections} = { map { $_ => 1 } @sections };
 129 $opts{h_archives} = { map { $_ => 1 } @archives };
 130 $opts{h_archs} = { map { $_ => 1 } @archs };
 131
 132 # for URL construction
 133 my $suites_param = join ',', @{$params{values}{suite}{no_replace}};
 134 my $sections_param = join ',', @{$params{values}{section}{no_replace}};
 135 my $archs_param = join ',', @{$params{values}{arch}{no_replace}};
 136
 137 # for output
 138 my $keyword_enc = encode_entities $keyword || '';
 139 my $searchon_enc = encode_entities $searchon;
 140 my $suites_enc = encode_entities join ', ', @{$params{values}{suite}{no_replace}};
 141 my $sections_enc = encode_entities join ', ', @{$params{values}{section}{no_replace}};
 142 my $archs_enc = encode_entities join ', ',  @{$params{values}{arch}{no_replace}};
 143 my $pet1 = new Benchmark;
 144 my $petd = timediff($pet1, $pet0);
 145 debug( "Parameter evaluation took ".timestr($petd) );
 146
 147 my $st0 = new Benchmark;
 148 my @results;
 149
 150 unless (@Packages::CGI::fatal_errors) {
 151
 152     if ($searchon eq 'names') {
 153         push @results, @{ do_names_search( $keyword, \%packages,
 154                                            $p_obj,
 155                                            \&read_entry, \%opts ) };
 156     } elsif ($searchon eq 'sourcenames') {
 157         push @results, @{ do_names_search( $keyword, \%sources,
 158                                            $sp_obj,
 159                                            \&read_src_entry, \%opts ) };
 160     } elsif ($searchon eq 'contents') {
 161         require "./search_contents.pl";
 162         &contents(\$input);
 163         exit;
 164     } else {
 165         push @results, @{ do_names_search( $keyword, \%packages,
 166                                            $p_obj,
 167                                            \&read_entry, \%opts ) };
 168         push @results, @{ do_fulltext_search( $keyword, "$DBDIR/descriptions.txt",
 169                                               \%did2pkg,
 170                                               \%packages,
 171                                               \&read_entry, \%opts ) };
 172     }
 173 }
 174
 175 my $st1 = new Benchmark;
 176 my $std = timediff($st1, $st0);
 177 debug( "Search took ".timestr($std) );
 178
 179 if ($format eq 'html') {
 180     my $suite_wording = $suites_enc eq "all" ? "all suites"
 181         : "suite(s) <em>$suites_enc</em>";
 182     my $section_wording = $sections_enc eq 'all' ? "all sections"
 183         : "section(s) <em>$sections_enc</em>";
 184     my $arch_wording = $archs_enc eq 'any' ? "all architectures"
 185         : "architecture(s) <em>$archs_enc</em>";
 186     if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 187         my $source_wording = ( $searchon eq 'sourcenames' ) ? "source " : "";
 188         my $exact_wording = $exact ? "named" : "that names contain";
 189         msg( "You have searched for ${source_wording}packages $exact_wording <em>$keyword_enc</em> in $suite_wording, $section_wording, and $arch_wording." );
 190     } else {
 191         my $exact_wording = $exact ? "" : " (including subword matching)";
 192         msg( "You have searched for <em>$keyword_enc</em> in packages names and descriptions in $suite_wording, $section_wording, and $arch_wording$exact_wording." );
 193     }
 194 }
 195
 196 if ($Packages::Search::too_many_hits) {
 197     error( "Your search was too wide so we will only display exact matches. At least <em>$Packages::Search::too_many_hits</em> results have been omitted and will not be displayed. Please consider using a longer keyword or more keywords." );
 198 }
 199
 200 if (!@Packages::CGI::fatal_errors && !@results) {
 201     if ($format eq 'html') {
 202         my $keyword_esc = uri_escape( $keyword );
 203         my $printed = 0;
 204         if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 205             if (($suites_enc eq 'all')
 206                 && ($archs_enc eq 'any')
 207                 && ($sections_enc eq 'all')) {
 208                 error( "Can't find that package." );
 209             } else {
 210                 error( "Can't find that package, at least not in that suite ".
 211                     ( ( $searchon eq 'sourcenames' ) ? "" : " and on that architecture" ) )
 212             }
 213
 214             if ($exact) {
 215                 $printed++;
 216                 hint( "You have searched only for exact matches of the package name. You can try to search for <a href=\"$SEARCH_CGI?exact=0&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">package names that contain your search string</a>." );
 217             }
 218         } else {
 219             if (($suites_enc eq 'all')
 220                 && ($archs_enc eq 'any')
 221                 && ($sections_enc eq 'all')) {
 222                 error( "Can't find that string." );
 223             } else {
 224                 error( "Can't find that string, at least not in that suite ($suites_enc, section $sections_enc) and on that architecture ($archs_enc)." );
 225             }
 226
 227             unless ($subword) {
 228                 $printed++;
 229                 hint( "You have searched only for words exactly matching your keywords. You can try to search <a href=\"$SEARCH_CGI?subword=1&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">allowing subword matching</a>." );
 230             }
 231         }
 232         hint( ( $printed ? "Or you" : "You" )." can try a different search on the <a href=\"$SEARCH_PAGE#search_packages\">Packages search page</a>." );
 233
 234     }
 235 }
 236
 237 print Packages::HTML::header( title => 'Package Search Results' ,
 238                               lang => 'en',
 239                               title_tag => 'Debian Package Search Results',
 240                               print_title_above => 1,
 241                               print_search_field => 'packages',
 242                               search_field_values => {
 243                                   keywords => $keyword_enc,
 244                                   searchon => $searchon,
 245                                   arch => $archs_enc,
 246                                   suite => $suites_enc,
 247                                   section => $sections_enc,
 248                                   subword => $subword,
 249                                   exact => $exact,
 250                                   case => $case,
 251                                   debug => $debug,
 252                               },
 253                               );
 254 print_msgs();
 255 print_errors();
 256 print_hints();
 257 print_debug();
 258 if (@results) {
 259     my (%pkgs, %subsect, %sect, %desc, %binaries, %provided_by);
 260
 261     unless ($opts{searchon} eq 'sourcenames') {
 262         foreach (@results) {
 263             my ($pkg_t, $archive, $suite, $arch, $section, $subsection,
 264                 $priority, $version, $desc) = @$_;
 265
 266             my ($pkg) = $pkg_t =~ m/^(.+)/; # untaint
 267             if ($arch ne 'virtual') {
 268                 $pkgs{$pkg}{$suite}{$archive}{$version}{$arch} = 1;
 269                 $subsect{$pkg}{$suite}{$archive}{$version} = $subsection;
 270                 $sect{$pkg}{$suite}{$archive}{$version} = $section
 271                     unless $section eq 'main';
 272
 273                 $desc{$pkg}{$suite}{$archive}{$version} = $desc;
 274             } else {
 275                 $provided_by{$pkg}{$suite}{$archive} = [ split /\s+/, $desc ];
 276             }
 277         }
 278
 279 my @pkgs = sort(keys %pkgs, keys %provided_by);
 280         if ($opts{format} eq 'html') {
 281             my ($start, $end) = multipageheader( $input, scalar @pkgs, \%opts );
 282             my $count = 0;
 283
 284             foreach my $pkg (@pkgs) {
 285                 $count++;
 286                 next if $count < $start or $count > $end;
 287                 printf "<h3>Package %s</h3>\n", $pkg;
 288                 print "<ul>\n";
 289                 foreach my $suite (@SUITES) {
 290                     foreach my $archive (@ARCHIVES) {
 291                         my $path = $suite.(($archive ne 'us')?"/$archive":'');
 292                         if (exists $pkgs{$pkg}{$suite}{$archive}) {
 293                             my @versions = version_sort keys %{$pkgs{$pkg}{$suite}{$archive}};
 294                             my $origin_str = "";
 295                             if ($sect{$pkg}{$suite}{$archive}{$versions[0]}) {
 296                                 $origin_str .= " [<span style=\"color:red\">$sect{$pkg}{$suite}{$archive}{$versions[0]}</span>]";
 297                             }
 298                             printf "<li><a href=\"$ROOT/%s/%s\">%s</a> (%s): %s   %s\n",
 299                             $path, $pkg, $path, $subsect{$pkg}{$suite}{$archive}{$versions[0]},
 300                             $desc{$pkg}{$suite}{$archive}{$versions[0]}, $origin_str;
 301
 302                             foreach my $v (@versions) {
 303                                 printf "<br>%s: %s\n",
 304                                 $v, join (" ", (sort keys %{$pkgs{$pkg}{$suite}{$archive}{$v}}) );
 305                             }
 306                             if (my $provided_by =  $provided_by{$pkg}{$suite}{$archive}) {
 307                                 print '<br>also provided by: ',
 308                                 join( ', ', map { "<a href=\"$ROOT/$path/$_\">$_</a>"  } @$provided_by);
 309                             }
 310                             print "</li>\n";
 311                         } elsif (my $provided_by =  $provided_by{$pkg}{$suite}{$archive}) {
 312                             printf "<li><a href=\"$ROOT/%s/%s\">%s</a>: Virtual package<br>",
 313                             $path, $pkg, $path;
 314                             print 'provided by: ',
 315                             join( ', ', map { "<a href=\"$ROOT/$path/$_\">$_</a>"  } @$provided_by);
 316                         }
 317                     }
 318                 }
 319                 print "</ul>\n";
 320             }
 321         }
 322     } else {
 323         foreach (@results) {
 324             my ($pkg, $archive, $suite, $section, $subsection, $priority,
 325                 $version) = @$_;
 326
 327             $pkgs{$pkg}{$suite}{$archive} = $version;
 328             $subsect{$pkg}{$suite}{$archive}{source} = $subsection;
 329             $sect{$pkg}{$suite}{$archive}{source} = $section
 330                 unless $section eq 'main';
 331
 332             $binaries{$pkg}{$suite}{$archive} = find_binaries( $pkg, $archive, $suite, \%src2bin );
 333         }
 334
 335         if ($opts{format} eq 'html') {
 336             my ($start, $end) = multipageheader( $input, scalar keys %pkgs, \%opts );
 337             my $count = 0;
 338
 339             foreach my $pkg (sort keys %pkgs) {
 340                 $count++;
 341                 next if ($count < $start) or ($count > $end);
 342                 printf "<h3>Source package %s</h3>\n", $pkg;
 343                 print "<ul>\n";
 344                 foreach my $suite (@SUITES) {
 345                     foreach my $archive (@ARCHIVES) {
 346                         if (exists $pkgs{$pkg}{$suite}{$archive}) {
 347                             my $origin_str = "";
 348                             if ($sect{$pkg}{$suite}{$archive}{source}) {
 349                                 $origin_str .= " [<span style=\"color:red\">$sect{$pkg}{$suite}{$archive}{source}</span>]";
 350                             }
 351                             printf( "<li><a href=\"$ROOT/%s/source/%s\">%s</a> (%s): %s   %s",
 352                                     $suite.(($archive ne 'us')?"/$archive":''), $pkg, $suite.(($archive ne 'us')?"/$archive":''), $subsect{$pkg}{$suite}{$archive}{source},
 353                                     $pkgs{$pkg}{$suite}{$archive}, $origin_str );
 354
 355                             print "<br>Binary packages: ";
 356                             my @bp_links;
 357                             foreach my $bp (@{$binaries{$pkg}{$suite}{$archive}}) {
 358                                 my $bp_link = sprintf( "<a href=\"$ROOT/%s/%s\">%s</a>",
 359                                                        $suite.(($archive ne 'us')?"/$archive":''), uri_escape( $bp ),  $bp );
 360                                 push @bp_links, $bp_link;
 361                             }
 362                             print join( ", ", @bp_links );
 363                             print "</li>\n";
 364                         }
 365                     }
 366                 }
 367                 print "</ul>\n";
 368             }
 369         }
 370     }
 371     printindexline( $input, scalar keys %pkgs, \%opts );
 372 }
 373 #print_results(\@results, \%opts) if @results;;
 374 my $tet1 = new Benchmark;
 375 my $tetd = timediff($tet1, $tet0);
 376 print "Total page evaluation took ".timestr($tetd)."<br>"
 377     if $debug_allowed;
 378
 379 my $trailer = Packages::HTML::trailer( $ROOT );
 380 $trailer =~ s/LAST_MODIFIED_DATE/gmtime()/e; #FIXME
 381 print $trailer;
 382
 383 # vim: ts=8 sw=4