bin/parse-packages

   1 #!/usr/bin/perl -w
   2 # Convert Packages.gz files into Sleepycat db files for efficient usage of
   3 # data
   4 #
   5 # Copyright (C) 2006  Jeroen van Wolffelaar <jeroen@wolffelaar.nl>
   6 # Copyright (C) 2006-2007 Frank Lichtenheld <frank@lichtenheld.de>
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  21
  22 use strict;
  23 use warnings;
  24 use lib './lib';
  25
  26 $| = 1;
  27
  28 my $what = $ARGV[0] ? "non-free" : "*";
  29 # max. distinct results for a given package postfix
  30 my $MAX_PACKAGE_POSTFIXES = 100;
  31
  32 use DB_File;
  33 use Storable;
  34 use File::Path;
  35 use Digest::MD5;
  36 use Deb::Versions;
  37 use Lingua::Stem v0.82;
  38 use Search::Xapian;
  39 use Packages::Config qw( $TOPDIR $DBDIR @ARCHIVES @SUITES );
  40 &Packages::Config::init( './' );
  41 my %packages_small = ();
  42 my %virtual_packages = ();
  43 my %package_names = ();
  44 my %package_postfixes = ();
  45 my %sources_packages = ();
  46 my %descriptions = ();
  47 my @descriptions = ("we count lines one-based\000");
  48 my %packages_descriptions = ();
  49 my %descriptions_packages = ();
  50
  51 my %sections = ();
  52 my %subsections = ();
  53 my %priorities = ();
  54
  55 $/ = "";
  56
  57 -d $DBDIR || mkpath( $DBDIR );
  58 -d "$DBDIR/xapian.new" && rmtree("$DBDIR/xapian.new");
  59 -d "$DBDIR/xapian.old" && rmtree("$DBDIR/xapian.old");
  60 mkpath( "$DBDIR/xapian.new" );
  61
  62 for my $suite (@SUITES) {
  63     my %package_names_suite = ();
  64     my %packages_all_db;
  65     tie %packages_all_db, "DB_File", "$DBDIR/packages_all_$suite.db.new",
  66             O_RDWR|O_CREAT, 0666, $DB_BTREE
  67             or die "Error creating DB: $!";
  68
  69     for my $archive (@ARCHIVES) {
  70         print "Reading $archive/$suite...\n";
  71         if (!-d "$TOPDIR/archive/$archive/$suite/") {
  72                 print "\tseems not to exist, skipping...\n";
  73                 next;
  74         }
  75         open PKG, "zcat $TOPDIR/archive/$archive/$suite/$what/{,debian-installer/}binary-*/Packages.gz|";
  76         while (<PKG>) {
  77                 next if /^\s*$/;
  78                 my $data = "";
  79                 my %data = ();
  80                 chomp;
  81                 s/\n /\377/g;
  82                 while (/^(\S+):\s*(.*)\s*$/mg) {
  83                         my ($key, $value) = ($1, $2);
  84                         $value =~ s/\377/\n /g;
  85                         $key =~ tr [A-Z] [a-z];
  86                         $data{$key} = $value;
  87                 }
  88                 # Skip broken debs
  89                 next unless $data{architecture};
  90                 # Skip double package
  91                 next if exists($packages_all_db{"$data{'package'} $data{'architecture'} $data{'version'}"});
  92                 # Skip arch:all for amd64 & debports, any non-redundancy is
  93                 # usually a bug anyway
  94                 next if ($archive eq 'amd64' or $archive eq 'debports')
  95                     and $data{architecture} eq 'all';
  96
  97                 if ($data{'provides'}) {
  98                     foreach (split /\s*,\s*/, $data{'provides'}) {
  99                         $virtual_packages{$_}{$suite}{$data{'package'}}++;
 100                         $packages_small{$_} ||= {};
 101                     }
 102                 }
 103                 $package_names{$data{'package'}} = 1;
 104                 $package_names_suite{$data{'package'}} = 1;
 105                 my $src = $data{'package'};
 106                 my $src_version = '';
 107                 if ($data{'source'}) {
 108                         $src = $data{'source'};
 109                         $src =~ s/\s+.*//o; # strip version info
 110                 }
 111                 $data{'source'} = $src;
 112
 113                 # expand tags like devel::{lang:c,lang:c++}
 114                 if ($data{'tag'} && $data{'tag'} =~ /\{/) {
 115                     my @complete_tags = split(/, /, $data{'tag'});
 116                     my @tags;
 117                     foreach (@complete_tags) {
 118                         my ($facet, $tag) = split( /::/, $_, 2);
 119                         if ($tag =~ s/^\{(.+)\}$/$1/) {
 120                             warn "pkg=$data{package} tags=$data{tag}\n" unless $facet && $tag;
 121                             foreach (split( /,/, $tag )) {
 122                                 push @tags, "${facet}::$_";
 123                             }
 124                         } else {
 125                             warn "pkg=$data{package} tags=$data{tag}\n" unless $facet && $tag;
 126                             push @tags, "${facet}::$tag";
 127                         }
 128                     }
 129                     my $old = $data{tag};
 130                     $data{'tag'} = join ", ", @tags;
 131                 }
 132
 133                 # we add some additional data here
 134                 my $descr = "$data{'description'}\000$data{'package'}\000"
 135                     .($data{'tag'}||'');
 136                 my $sdescr = $data{'description'};
 137                 $sdescr =~ s/\n.*//os;
 138                 my $did = undef;
 139                 if (exists($descriptions{$descr})) {
 140                         $did  = $descriptions{$descr};
 141                 } else {
 142                         $did = 1 + $#descriptions;
 143                         $descriptions[$did] = $descr;
 144                         $descriptions{$descr} = $did;
 145                 }
 146                 $data{'description-md5'} = Digest::MD5::md5_hex($data{'description'}, "\n");
 147                 $data{'description'} = $did;
 148                 $packages_descriptions{"$data{'package'} $data{'version'} $data{'architecture'}"} = $did;
 149                 $descriptions_packages{$did} .=
 150                         "$data{'package'} $data{'version'} $data{'architecture'}\000";
 151
 152                 my $section = 'main';
 153                 my $subsection = $data{section} || '-';
 154                 if ($data{section} && ($data{section} =~ m=/=o)) {
 155                     ($section, $subsection) = split m=/=o, $data{section}, 2;
 156                 }
 157                 $data{'section'} = $section;
 158                 $data{'subsection'} = $subsection;
 159                 $data{'priority'} ||= '-';
 160                 $sections{$suite}{$section}++;
 161                 $subsections{$suite}{$subsection}++;
 162                 $priorities{$suite}{$data{priority}}++;
 163                 my $pkgitem = "$archive $suite $data{'architecture'} ".
 164                         "$section $subsection $data{'priority'} $data{'version'} $data{'description-md5'} $sdescr\0";
 165                 my $previtem = ($packages_small{$data{'package'}}{$suite}{$data{'architecture'}}
 166                     ||= $pkgitem);
 167                 $packages_small{$data{'package'}}{$suite}{$data{'architecture'}} = $pkgitem
 168                     if version_cmp($data{'version'}, (split /\s/o, $previtem)[6]) > 0;
 169                 $previtem = ($packages_small{$data{'package'}}{$suite}{'any'}
 170                     ||= $pkgitem);
 171                 $packages_small{$data{'package'}}{$suite}{'any'} = $pkgitem
 172                     if version_cmp($data{'version'}, (split /\s/o, $previtem)[6]) > 0;
 173                 $sources_packages{$src} .=
 174                         "$archive $suite $data{'package'} $data{'version'} $data{'architecture'}\000";
 175                 $data{archive} = $archive;
 176                 while (my ($key, $value) = each (%data)) {
 177                         next if $key eq 'package' or $key eq 'version' or $key eq 'architecture'
 178                                 or $key eq 'maintainer';
 179                         print STDERR "WARN: $key ($suite/$archive/$data{package}/$data{architecture}\n" unless defined $value;
 180                         $data .= "$key\00$value\00";
 181                 }
 182                 $data =~ s/.$//s;
 183                 $packages_all_db{"$data{'package'} $data{'architecture'} $data{'version'}"}
 184                         = $data;
 185         }
 186     }
 187
 188     open NAMES, '>', "$DBDIR/package_names_$suite.txt.new"
 189         or die "Error creating package names list: $!";
 190     foreach (sort keys %package_names_suite) {
 191         print NAMES "$_\n";
 192     }
 193     close NAMES;
 194
 195     untie %packages_all_db;
 196 }
 197
 198 print "Writing databases...\n";
 199 my %packages_small_db;
 200 tie %packages_small_db, "DB_File", "$DBDIR/packages_small.db.new",
 201         O_RDWR|O_CREAT, 0666, $DB_BTREE
 202         or die "Error creating DB: $!";
 203 while (my ($pkg, $v) = each(%packages_small)) {
 204         my ($res1, $res2, $res3) = ("", "", "");
 205         while (my ($suite, $v2) = each %$v) {
 206             $res2 .= $v2->{'any'};
 207             while (my ($arch, $v3) = each %$v2) {
 208                 next if $arch eq 'any' or $v3 eq $v2->{'any'};
 209                 $res3 .= $v3;
 210             }
 211         }
 212
 213         if (exists $virtual_packages{$pkg}) {
 214                 while (my ($suite, $v2) = each %{$virtual_packages{$pkg}}) {
 215                         $res1 .= "$suite\01".(join ' ', keys %$v2)."\01";
 216                 }
 217         } else {
 218                 $res1 .= "-\01-\01";
 219         }
 220         $res1 =~ s/.$/\0/s;
 221
 222         my $res = "$res1$res2$res3";
 223         $res =~ s/.$//s;
 224         $packages_small_db{$pkg} = $res;
 225 }
 226 untie %packages_small_db;
 227
 228 my %sources_packages_db;
 229 tie %sources_packages_db, "DB_File", "$DBDIR/sources_packages.db.new",
 230         O_RDWR|O_CREAT, 0666, $DB_BTREE
 231         or die "Error creating DB: $!";
 232 while (my ($k, $v) = each(%sources_packages)) {
 233         $v =~ s/.$//s;
 234         $sources_packages_db{$k} = $v;
 235 }
 236 untie %sources_packages_db;
 237
 238 my %packages_descriptions_db;
 239 tie %packages_descriptions_db, "DB_File", "$DBDIR/packages_descriptions.db.new",
 240         O_RDWR|O_CREAT, 0666, $DB_BTREE
 241         or die "Error creating DB: $!";
 242 while (my ($k, $v) = each(%packages_descriptions)) {
 243         $packages_descriptions_db{$k} = $v;
 244 }
 245 untie %packages_descriptions_db;
 246
 247 my %descriptions_packages_db;
 248 tie %descriptions_packages_db, "DB_File", "$DBDIR/descriptions_packages.db.new",
 249         O_RDWR|O_CREAT, 0666, $DB_BTREE
 250         or die "Error creating DB: $!";
 251 while (my ($k, $v) = each(%descriptions_packages)) {
 252         $v =~ s/.$//s;
 253         $descriptions_packages_db{$k} = $v;
 254 }
 255 untie %descriptions_packages_db;
 256
 257 my $stemmer = Lingua::Stem->new();
 258 $stemmer->stem_caching({ -level => 2 });
 259 my $xapian_db;
 260 eval {
 261     $xapian_db = Search::Xapian::WritableDatabase->new("$DBDIR/xapian.new",
 262                                                        Search::Xapian::DB_CREATE_OR_OPEN)
 263         or die "can't create write-able db object: $!\n";
 264 };
 265 die $@ if $@;
 266 my %descriptions_db;
 267 tie %descriptions_db, "DB_File", "$DBDIR/descriptions.db.new",
 268         O_RDWR|O_CREAT, 0666, $DB_BTREE
 269         or die "Error creating DB: $!";
 270 print "Index $#descriptions descriptions\n";
 271 for (my $i=1; $i<= $#descriptions; $i++) {
 272         # strip away additional data
 273         my ($only_desc, $pkg, $tags) = split /\000/o, $descriptions[$i], 3;
 274         my $orig_desc = $only_desc;
 275 # WARNING: This needs to correspond with what happens in
 276 # Packages/Search.pm:do_xapian_search
 277         $only_desc =~ s#[^\w/+]+# #og;
 278
 279         #XAPIAN
 280         eval {
 281             my @words = split /\s+/, $only_desc;
 282             unshift @words, $pkg;
 283
 284             my $doc = Search::Xapian::Document->new()
 285                 or die "can't create doc object for $i: $!\n";
 286             if ($doc->set_data($i)){
 287                 warn "can't set_data in doc object for $i: $!\n";
 288             }
 289
 290             # package with prefix
 291             if ($doc->add_term("P$pkg")) {
 292                 warn "can't add term P$pkg: $!\n";
 293             }
 294             # description, unstemmed with positional info
 295             for my $j (0 .. (@words-1)) {
 296                 next if $words[$j] =~ /^\s*$/o;
 297                 if ($doc->add_posting($words[$j], $j)) {
 298                     warn "can't add posting $words[$j] at $j: $!\n";
 299                 }
 300             }
 301             # description, stemmed
 302             my $stem_words = $stemmer->stem( \@words );
 303             foreach my $w (@$stem_words) {
 304                 next if $w =~ /^\s*$/o;
 305                 if ($doc->add_term($w)) {
 306                     warn "can't add term $w: $!\n";
 307                 }
 308             }
 309             if ($tags) {
 310                 foreach my $t (split m/, /, $tags) {
 311                     if ($doc->add_term($t)) {
 312                         warn "can't add term $t: $!\n";
 313                     }
 314                 }
 315             }
 316
 317             $xapian_db->add_document($doc)
 318                 or warn "failed to add document: $i\n";
 319         };
 320         die $@ if $@;
 321
 322         $descriptions_db{$i} = $orig_desc;
 323 }
 324 untie %descriptions_db;
 325 $xapian_db->flush;
 326 undef $xapian_db;
 327
 328 # package names stuff:
 329 for my $pkg (keys %package_names) {
 330         for (my $i=0;$i<length($pkg)-1;$i++) {
 331                 my $before = substr($pkg, 0, $i);
 332                 my $after = substr($pkg, $i);
 333                 $before = "^" if $before eq ""; # otherwise split doesn't work properly
 334                 $package_postfixes{$after} .= "$before\0";
 335         }
 336 }
 337 my %package_postfixes_db;
 338 tie %package_postfixes_db, "DB_File", "$DBDIR/package_postfixes.db.new",
 339         O_RDWR|O_CREAT, 0666, $DB_BTREE
 340         or die "Error creating DB: $!";
 341 while (my ($k, $v) = each(%package_postfixes)) {
 342         $v =~ s/.$//s;
 343         my $nr = ($v =~ tr/\000/\000/) + 1;
 344         if ($nr > $MAX_PACKAGE_POSTFIXES) {
 345             $v = ($v =~ /\^/) ? "^\001" . $nr
 346                 : "\001" . $nr;
 347         }
 348         $package_postfixes_db{$k} = $v;
 349 }
 350 untie %package_postfixes_db;
 351
 352 store \%sections, "$DBDIR/sections.info";
 353 store \%subsections, "$DBDIR/subsections.info";
 354 store \%priorities, "$DBDIR/priorities.info";
 355
 356 rename("$DBDIR/packages_small.db.new", "$DBDIR/packages_small.db");
 357 rename("$DBDIR/sources_packages.db.new", "$DBDIR/sources_packages.db");
 358 for my $suite (@SUITES) {
 359         rename("$DBDIR/packages_all_$suite.db.new",
 360                "$DBDIR/packages_all_$suite.db");
 361         rename("$DBDIR/package_names_$suite.txt.new",
 362                "$DBDIR/package_names_$suite.txt");
 363 }
 364 rename("$DBDIR/xapian", "$DBDIR/xapian.old");
 365 rename("$DBDIR/xapian.new","$DBDIR/xapian");
 366 rmtree("$DBDIR/xapian.old");
 367 rename("$DBDIR/packages_descriptions.db.new",
 368        "$DBDIR/packages_descriptions.db");
 369 rename("$DBDIR/descriptions_packages.db.new",
 370        "$DBDIR/descriptions_packages.db");
 371 rename("$DBDIR/descriptions.db.new", "$DBDIR/descriptions.db");
 372 rename("$DBDIR/package_postfixes.db.new", "$DBDIR/package_postfixes.db");