m4/po.m4

   1 # po.m4 serial 7 (gettext-0.14.3)
   2 dnl Copyright (C) 1995-2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6 dnl
   7 dnl This file can can be used in projects which are not available under
   8 dnl the GNU General Public License or the GNU Library General Public
   9 dnl License but which still want to provide support for the GNU gettext
  10 dnl functionality.
  11 dnl Please note that the actual code of the GNU gettext library is covered
  12 dnl by the GNU Library General Public License, and the rest of the GNU
  13 dnl gettext package package is covered by the GNU General Public License.
  14 dnl They are *not* in the public domain.
  15
  16 dnl Authors:
  17 dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
  18 dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2003.
  19
  20 AC_PREREQ(2.50)
  21
  22 dnl Checks for all prerequisites of the po subdirectory.
  23 AC_DEFUN([AM_PO_SUBDIRS],
  24 [
  25   AC_REQUIRE([AC_PROG_MAKE_SET])dnl
  26   AC_REQUIRE([AC_PROG_INSTALL])dnl
  27   AC_REQUIRE([AM_MKINSTALLDIRS])dnl
  28   AC_REQUIRE([AM_NLS])dnl
  29
  30   dnl Perform the following tests also if --disable-nls has been given,
  31   dnl because they are needed for "make dist" to work.
  32
  33   dnl Search for GNU msgfmt in the PATH.
  34   dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions.
  35   dnl The second test excludes FreeBSD msgfmt.
  36   AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
  37     [$ac_dir/$ac_word --statistics /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
  38      (if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
  39     :)
  40   AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
  41
  42   dnl Search for GNU xgettext 0.12 or newer in the PATH.
  43   dnl The first test excludes Solaris xgettext and early GNU xgettext versions.
  44   dnl The second test excludes FreeBSD xgettext.
  45   AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
  46     [$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
  47      (if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
  48     :)
  49   dnl Remove leftover from FreeBSD xgettext call.
  50   rm -f messages.po
  51
  52   dnl Search for GNU msgmerge 0.11 or newer in the PATH.
  53   AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge,
  54     [$ac_dir/$ac_word --update -q /dev/null /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1], :)
  55
  56   dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
  57   dnl Test whether we really found GNU msgfmt.
  58   if test "$GMSGFMT" != ":"; then
  59     dnl If it is no GNU msgfmt we define it as : so that the
  60     dnl Makefiles still can work.
  61     if $GMSGFMT --statistics /dev/null >/dev/null 2>&1 &&
  62        (if $GMSGFMT --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi); then
  63       : ;
  64     else
  65       GMSGFMT=`echo "$GMSGFMT" | sed -e 's,^.*/,,'`
  66       AC_MSG_RESULT(
  67         [found $GMSGFMT program is not GNU msgfmt; ignore it])
  68       GMSGFMT=":"
  69     fi
  70   fi
  71
  72   dnl This could go away some day; the PATH_PROG_WITH_TEST already does it.
  73   dnl Test whether we really found GNU xgettext.
  74   if test "$XGETTEXT" != ":"; then
  75     dnl If it is no GNU xgettext we define it as : so that the
  76     dnl Makefiles still can work.
  77     if $XGETTEXT --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >/dev/null 2>&1 &&
  78        (if $XGETTEXT --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi); then
  79       : ;
  80     else
  81       AC_MSG_RESULT(
  82         [found xgettext program is not GNU xgettext; ignore it])
  83       XGETTEXT=":"
  84     fi
  85     dnl Remove leftover from FreeBSD xgettext call.
  86     rm -f messages.po
  87   fi
  88
  89   AC_OUTPUT_COMMANDS([
  90     for ac_file in $CONFIG_FILES; do
  91       # Support "outfile[:infile[:infile...]]"
  92       case "$ac_file" in
  93         *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
  94       esac
  95       # PO directories have a Makefile.in generated from Makefile.in.in.
  96       case "$ac_file" in */Makefile.in)
  97         # Adjust a relative srcdir.
  98         ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
  99         ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
 100         ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
 101         # In autoconf-2.13 it is called $ac_given_srcdir.
 102         # In autoconf-2.50 it is called $srcdir.
 103         test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
 104         case "$ac_given_srcdir" in
 105           .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
 106           /*) top_srcdir="$ac_given_srcdir" ;;
 107           *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
 108         esac
 109         # Treat a directory as a PO directory if and only if it has a
 110         # POTFILES.in file. This allows packages to have multiple PO
 111         # directories under different names or in different locations.
 112         if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
 113           rm -f "$ac_dir/POTFILES"
 114           test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
 115           cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[   ]*\$/d" -e "s,.*,     $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES"
 116           POMAKEFILEDEPS="POTFILES.in"
 117           # ALL_LINGUAS, POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES depend
 118           # on $ac_dir but don't depend on user-specified configuration
 119           # parameters.
 120           if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
 121             # The LINGUAS file contains the set of available languages.
 122             if test -n "$OBSOLETE_ALL_LINGUAS"; then
 123               test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
 124             fi
 125             ALL_LINGUAS_=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
 126             # Hide the ALL_LINGUAS assigment from automake.
 127             eval 'ALL_LINGUAS''=$ALL_LINGUAS_'
 128             POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
 129           else
 130             # The set of available languages was given in configure.in.
 131             eval 'ALL_LINGUAS''=$OBSOLETE_ALL_LINGUAS'
 132           fi
 133           # Compute POFILES
 134           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
 135           # Compute UPDATEPOFILES
 136           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
 137           # Compute DUMMYPOFILES
 138           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
 139           # Compute GMOFILES
 140           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
 141           case "$ac_given_srcdir" in
 142             .) srcdirpre= ;;
 143             *) srcdirpre='$(srcdir)/' ;;
 144           esac
 145           POFILES=
 146           UPDATEPOFILES=
 147           DUMMYPOFILES=
 148           GMOFILES=
 149           for lang in $ALL_LINGUAS; do
 150             POFILES="$POFILES $srcdirpre$lang.po"
 151             UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
 152             DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
 153             GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 154           done
 155           # CATALOGS depends on both $ac_dir and the user's LINGUAS
 156           # environment variable.
 157           INST_LINGUAS=
 158           if test -n "$ALL_LINGUAS"; then
 159             for presentlang in $ALL_LINGUAS; do
 160               useit=no
 161               if test "%UNSET%" != "$LINGUAS"; then
 162                 desiredlanguages="$LINGUAS"
 163               else
 164                 desiredlanguages="$ALL_LINGUAS"
 165               fi
 166               for desiredlang in $desiredlanguages; do
 167                 # Use the presentlang catalog if desiredlang is
 168                 #   a. equal to presentlang, or
 169                 #   b. a variant of presentlang (because in this case,
 170                 #      presentlang can be used as a fallback for messages
 171                 #      which are not translated in the desiredlang catalog).
 172                 case "$desiredlang" in
 173                   "$presentlang"*) useit=yes;;
 174                 esac
 175               done
 176               if test $useit = yes; then
 177                 INST_LINGUAS="$INST_LINGUAS $presentlang"
 178               fi
 179             done
 180           fi
 181           CATALOGS=
 182           if test -n "$INST_LINGUAS"; then
 183             for lang in $INST_LINGUAS; do
 184               CATALOGS="$CATALOGS $lang.gmo"
 185             done
 186           fi
 187           test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
 188           sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
 189         fi
 190         ;;
 191       esac
 192     done],
 193    [# Capture the value of obsolete ALL_LINGUAS because we need it to compute
 194     # POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES, CATALOGS. But hide it
 195     # from automake.
 196     eval 'OBSOLETE_ALL_LINGUAS''="$ALL_LINGUAS"'
 197     # Capture the value of LINGUAS because we need it to compute CATALOGS.
 198     LINGUAS="${LINGUAS-%UNSET%}"
 199    ])
 200 ])
 201
 202 dnl Postprocesses a Makefile in a directory containing PO files.
 203 AC_DEFUN([AM_POSTPROCESS_PO_MAKEFILE],
 204 [
 205   # When this code is run, in config.status, two variables have already been
 206   # set:
 207   # - OBSOLETE_ALL_LINGUAS is the value of LINGUAS set in configure.in,
 208   # - LINGUAS is the value of the environment variable LINGUAS at configure
 209   #   time.
 210
 211 changequote(,)dnl
 212   # Adjust a relative srcdir.
 213   ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
 214   ac_dir_suffix="/`echo "$ac_dir"|sed 's%^\./%%'`"
 215   ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
 216   # In autoconf-2.13 it is called $ac_given_srcdir.
 217   # In autoconf-2.50 it is called $srcdir.
 218   test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
 219   case "$ac_given_srcdir" in
 220     .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
 221     /*) top_srcdir="$ac_given_srcdir" ;;
 222     *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
 223   esac
 224
 225   # Find a way to echo strings without interpreting backslash.
 226   if test "X`(echo '\t') 2>/dev/null`" = 'X\t'; then
 227     gt_echo='echo'
 228   else
 229     if test "X`(printf '%s\n' '\t') 2>/dev/null`" = 'X\t'; then
 230       gt_echo='printf %s\n'
 231     else
 232       echo_func () {
 233         cat <<EOT
 234 $*
 235 EOT
 236       }
 237       gt_echo='echo_func'
 238     fi
 239   fi
 240
 241   # A sed script that extracts the value of VARIABLE from a Makefile.
 242   sed_x_variable='
 243 # Test if the hold space is empty.
 244 x
 245 s/P/P/
 246 x
 247 ta
 248 # Yes it was empty. Look if we have the expected variable definition.
 249 /^[      ]*VARIABLE[     ]*=/{
 250   # Seen the first line of the variable definition.
 251   s/^[   ]*VARIABLE[     ]*=//
 252   ba
 253 }
 254 bd
 255 :a
 256 # Here we are processing a line from the variable definition.
 257 # Remove comment, more precisely replace it with a space.
 258 s/#.*$/ /
 259 # See if the line ends in a backslash.
 260 tb
 261 :b
 262 s/\\$//
 263 # Print the line, without the trailing backslash.
 264 p
 265 tc
 266 # There was no trailing backslash. The end of the variable definition is
 267 # reached. Clear the hold space.
 268 s/^.*$//
 269 x
 270 bd
 271 :c
 272 # A trailing backslash means that the variable definition continues in the
 273 # next line. Put a nonempty string into the hold space to indicate this.
 274 s/^.*$/P/
 275 x
 276 :d
 277 '
 278 changequote([,])dnl
 279
 280   # Set POTFILES to the value of the Makefile variable POTFILES.
 281   sed_x_POTFILES="`$gt_echo \"$sed_x_variable\" | sed -e '/^ *#/d' -e 's/VARIABLE/POTFILES/g'`"
 282   POTFILES=`sed -n -e "$sed_x_POTFILES" < "$ac_file"`
 283   # Compute POTFILES_DEPS as
 284   #   $(foreach file, $(POTFILES), $(top_srcdir)/$(file))
 285   POTFILES_DEPS=
 286   for file in $POTFILES; do
 287     POTFILES_DEPS="$POTFILES_DEPS "'$(top_srcdir)/'"$file"
 288   done
 289   POMAKEFILEDEPS=""
 290
 291   if test -n "$OBSOLETE_ALL_LINGUAS"; then
 292     test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
 293   fi
 294   if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
 295     # The LINGUAS file contains the set of available languages.
 296     ALL_LINGUAS_=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
 297     POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
 298   else
 299     # Set ALL_LINGUAS to the value of the Makefile variable LINGUAS.
 300     sed_x_LINGUAS="`$gt_echo \"$sed_x_variable\" | sed -e '/^ *#/d' -e 's/VARIABLE/LINGUAS/g'`"
 301     ALL_LINGUAS_=`sed -n -e "$sed_x_LINGUAS" < "$ac_file"`
 302   fi
 303   # Hide the ALL_LINGUAS assigment from automake.
 304   eval 'ALL_LINGUAS''=$ALL_LINGUAS_'
 305   # Compute POFILES
 306   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
 307   # Compute UPDATEPOFILES
 308   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
 309   # Compute DUMMYPOFILES
 310   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
 311   # Compute GMOFILES
 312   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
 313   # Compute PROPERTIESFILES
 314   # as      $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).properties)
 315   # Compute CLASSFILES
 316   # as      $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).class)
 317   # Compute QMFILES
 318   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).qm)
 319   # Compute MSGFILES
 320   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang)).msg)
 321   # Compute RESOURCESDLLFILES
 322   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang))/$(DOMAIN).resources.dll)
 323   case "$ac_given_srcdir" in
 324     .) srcdirpre= ;;
 325     *) srcdirpre='$(srcdir)/' ;;
 326   esac
 327   POFILES=
 328   UPDATEPOFILES=
 329   DUMMYPOFILES=
 330   GMOFILES=
 331   PROPERTIESFILES=
 332   CLASSFILES=
 333   QMFILES=
 334   MSGFILES=
 335   RESOURCESDLLFILES=
 336   for lang in $ALL_LINGUAS; do
 337     POFILES="$POFILES $srcdirpre$lang.po"
 338     UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
 339     DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
 340     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 341     PROPERTIESFILES="$PROPERTIESFILES \$(top_srcdir)/\$(DOMAIN)_$lang.properties"
 342     CLASSFILES="$CLASSFILES \$(top_srcdir)/\$(DOMAIN)_$lang.class"
 343     QMFILES="$QMFILES $srcdirpre$lang.qm"
 344     frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 345     MSGFILES="$MSGFILES $srcdirpre$frobbedlang.msg"
 346     frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 347     RESOURCESDLLFILES="$RESOURCESDLLFILES $srcdirpre$frobbedlang/\$(DOMAIN).resources.dll"
 348   done
 349   # CATALOGS depends on both $ac_dir and the user's LINGUAS
 350   # environment variable.
 351   INST_LINGUAS=
 352   if test -n "$ALL_LINGUAS"; then
 353     for presentlang in $ALL_LINGUAS; do
 354       useit=no
 355       if test "%UNSET%" != "$LINGUAS"; then
 356         desiredlanguages="$LINGUAS"
 357       else
 358         desiredlanguages="$ALL_LINGUAS"
 359       fi
 360       for desiredlang in $desiredlanguages; do
 361         # Use the presentlang catalog if desiredlang is
 362         #   a. equal to presentlang, or
 363         #   b. a variant of presentlang (because in this case,
 364         #      presentlang can be used as a fallback for messages
 365         #      which are not translated in the desiredlang catalog).
 366         case "$desiredlang" in
 367           "$presentlang"*) useit=yes;;
 368         esac
 369       done
 370       if test $useit = yes; then
 371         INST_LINGUAS="$INST_LINGUAS $presentlang"
 372       fi
 373     done
 374   fi
 375   CATALOGS=
 376   JAVACATALOGS=
 377   QTCATALOGS=
 378   TCLCATALOGS=
 379   CSHARPCATALOGS=
 380   if test -n "$INST_LINGUAS"; then
 381     for lang in $INST_LINGUAS; do
 382       CATALOGS="$CATALOGS $lang.gmo"
 383       JAVACATALOGS="$JAVACATALOGS \$(DOMAIN)_$lang.properties"
 384       QTCATALOGS="$QTCATALOGS $lang.qm"
 385       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 386       TCLCATALOGS="$TCLCATALOGS $frobbedlang.msg"
 387       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 388       CSHARPCATALOGS="$CSHARPCATALOGS $frobbedlang/\$(DOMAIN).resources.dll"
 389     done
 390   fi
 391
 392   sed -e "s|@POTFILES_DEPS@|$POTFILES_DEPS|g" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@PROPERTIESFILES@|$PROPERTIESFILES|g" -e "s|@CLASSFILES@|$CLASSFILES|g" -e "s|@QMFILES@|$QMFILES|g" -e "s|@MSGFILES@|$MSGFILES|g" -e "s|@RESOURCESDLLFILES@|$RESOURCESDLLFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@JAVACATALOGS@|$JAVACATALOGS|g" -e "s|@QTCATALOGS@|$QTCATALOGS|g" -e "s|@TCLCATALOGS@|$TCLCATALOGS|g" -e "s|@CSHARPCATALOGS@|$CSHARPCATALOGS|g" -e 's,^#distdir:,distdir:,' < "$ac_file" > "$ac_file.tmp"
 393   if grep -l '@TCLCATALOGS@' "$ac_file" > /dev/null; then
 394     # Add dependencies that cannot be formulated as a simple suffix rule.
 395     for lang in $ALL_LINGUAS; do
 396       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 397       cat >> "$ac_file.tmp" <<EOF
 398 $frobbedlang.msg: $lang.po
 399         @echo "\$(MSGFMT) -c --tcl -d \$(srcdir) -l $lang $srcdirpre$lang.po"; \
 400         \$(MSGFMT) -c --tcl -d "\$(srcdir)" -l $lang $srcdirpre$lang.po || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
 401 EOF
 402     done
 403   fi
 404   if grep -l '@CSHARPCATALOGS@' "$ac_file" > /dev/null; then
 405     # Add dependencies that cannot be formulated as a simple suffix rule.
 406     for lang in $ALL_LINGUAS; do
 407       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 408       cat >> "$ac_file.tmp" <<EOF
 409 $frobbedlang/\$(DOMAIN).resources.dll: $lang.po
 410         @echo "\$(MSGFMT) -c --csharp -d \$(srcdir) -l $lang $srcdirpre$lang.po -r \$(DOMAIN)"; \
 411         \$(MSGFMT) -c --csharp -d "\$(srcdir)" -l $lang $srcdirpre$lang.po -r "\$(DOMAIN)" || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
 412 EOF
 413     done
 414   fi
 415   if test -n "$POMAKEFILEDEPS"; then
 416     cat >> "$ac_file.tmp" <<EOF
 417 Makefile: $POMAKEFILEDEPS
 418 EOF
 419   fi
 420   mv "$ac_file.tmp" "$ac_file"
 421 ])