blosxom.cgi

   1 #!/usr/bin/perl
   2
   3 # Blosxom
   4 # Author: Rael Dornfest <rael@oreilly.com>
   5 # Version: 2.0.2
   6 # Home/Docs/Licensing: http://blosxom.sourceforge.net/
   7 # Development/Downloads: http://sourceforge.net/projects/blosxom
   8
   9 package blosxom;
  10
  11 # --- Configurable variables -----
  12
  13 # What's this blog's title?
  14 $blog_title = "My Weblog";
  15
  16 # What's this blog's description (for outgoing RSS feed)?
  17 $blog_description = "Yet another Blosxom weblog.";
  18
  19 # What's this blog's primary language (for outgoing RSS feed)?
  20 $blog_language = "en";
  21
  22 # What's this blog's text encoding ?
  23 $blog_encoding = "UTF-8";
  24
  25 # Where are this blog's entries kept?
  26 $datadir = "/Library/WebServer/Documents/blosxom";
  27
  28 # What's my preferred base URL for this blog (leave blank for automatic)?
  29 $url = "";
  30
  31 # Should I stick only to the datadir for items or travel down the
  32 # directory hierarchy looking for items?  If so, to what depth?
  33 # 0 = infinite depth (aka grab everything), 1 = datadir only, n = n levels down
  34 $depth = 0;
  35
  36 # How many entries should I show on the home page?
  37 $num_entries = 40;
  38
  39 # What file extension signifies a blosxom entry?
  40 $file_extension = "txt";
  41
  42 # What is the default flavour?
  43 $default_flavour = "html";
  44
  45 # Should I show entries from the future (i.e. dated after now)?
  46 $show_future_entries = 0;
  47
  48 # --- Plugins (Optional) -----
  49
  50 # File listing plugins blosxom should load
  51 # (if empty blosxom will load all plugins in $plugin_path directories)
  52 $plugin_list = "";
  53
  54 # Where are my plugins kept?
  55 # List of directories, separated by ';' on windows, ':' everywhere else
  56 $plugin_path = "";
  57
  58 # Where should my plugins keep their state information?
  59 $plugin_state_dir = "";
  60 #$plugin_state_dir = "/var/lib/blosxom/state";
  61
  62 # --- Static Rendering -----
  63
  64 # Where are this blog's static files to be created?
  65 $static_dir = "/Library/WebServer/Documents/blog";
  66
  67 # What's my administrative password (you must set this for static rendering)?
  68 $static_password = "";
  69
  70 # What flavours should I generate statically?
  71 @static_flavours = qw/html rss/;
  72
  73 # Should I statically generate individual entries?
  74 # 0 = no, 1 = yes
  75 $static_entries = 0;
  76
  77 # --------------------------------
  78
  79 use vars qw! $version $blog_title $blog_description $blog_language $blog_encoding $datadir $url %template $template $depth $num_entries $file_extension $default_flavour $static_or_dynamic $config_dir $plugin_list $plugin_path $plugin_dir $plugin_state_dir @plugins %plugins $static_dir $static_password @static_flavours $static_entries $path_info $path_info_yr $path_info_mo $path_info_da $path_info_mo_num $flavour $static_or_dynamic %month2num @num2month $interpolate $entries $output $header $show_future_entries %files %indexes %others !;
  80
  81 use strict;
  82 use FileHandle;
  83 use File::Find;
  84 use File::stat;
  85 use Time::localtime;
  86 use Time::Local;
  87 use CGI qw/:standard :netscape/;
  88
  89 $version = "2.0.2";
  90
  91 # Load configuration from $ENV{BLOSXOM_CONFIG_DIR}/blosxom.conf, if it exists
  92 my $blosxom_config;
  93 if ($ENV{BLOSXOM_CONFIG_FILE} && -r $ENV{BLOSXOM_CONFIG_FILE}) {
  94   $blosxom_config = $ENV{BLOSXOM_CONFIG_FILE};
  95   ($config_dir = $blosxom_config) =~ s! / [^/]* $ !!x;
  96 }
  97 else {
  98   for my $blosxom_config_dir ($ENV{BLOSXOM_CONFIG_DIR}, '/etc/blosxom', '/etc') {
  99     if (-r "$blosxom_config_dir/blosxom.conf") {
 100       $config_dir = $blosxom_config_dir;
 101       $blosxom_config = "$blosxom_config_dir/blosxom.conf";
 102       last;
 103     }
 104   }
 105 }
 106 # Load $blosxom_config
 107 if ($blosxom_config) {
 108   if (-r $blosxom_config) {
 109     eval { require $blosxom_config } or
 110       warn "Error reading blosxom config file '$blosxom_config'" . ($@ ? ": $@" : '');
 111   }
 112   else {
 113     warn "Cannot find or read blosxom config file '$blosxom_config'";
 114   }
 115 }
 116
 117 my $fh = new FileHandle;
 118
 119 %month2num = (nil=>'00', Jan=>'01', Feb=>'02', Mar=>'03', Apr=>'04', May=>'05', Jun=>'06', Jul=>'07', Aug=>'08', Sep=>'09', Oct=>'10', Nov=>'11', Dec=>'12');
 120 @num2month = sort { $month2num{$a} <=> $month2num{$b} } keys %month2num;
 121
 122 # Use the stated preferred URL or figure it out automatically
 123 $url ||= url(-path_info => 1);
 124 $url =~ s/^included:/http:/ if $ENV{SERVER_PROTOCOL} eq 'INCLUDED';
 125
 126 # NOTE: Since v3.12, it looks as if CGI.pm misbehaves for SSIs and
 127 # always appends path_info to the url. To fix this, we always
 128 # request an url with path_info, and always remove it from the end of the
 129 # string.
 130 my $pi_len = length $ENV{PATH_INFO};
 131 my $might_be_pi = substr($url, -$pi_len);
 132 substr($url, -length $ENV{PATH_INFO}) = '' if $might_be_pi eq $ENV{PATH_INFO};
 133
 134 $url =~ s!/$!!;
 135
 136 # Drop ending any / from dir settings
 137 $datadir =~ s!/$!!; $plugin_dir =~ s!/$!!; $static_dir =~ s!/$!!;
 138
 139 # Fix depth to take into account datadir's path
 140 $depth += ($datadir =~ tr[/][]) - 1 if $depth;
 141
 142 # Global variable to be used in head/foot.{flavour} templates
 143 $path_info = '';
 144
 145 if (    !$ENV{GATEWAY_INTERFACE}
 146     and param('-password')
 147     and $static_password
 148     and param('-password') eq $static_password )
 149 {
 150     $static_or_dynamic = 'static';
 151 }
 152 else {
 153     $static_or_dynamic = 'dynamic';
 154     param( -name => '-quiet', -value => 1 );
 155 }
 156
 157 # Path Info Magic
 158 # Take a gander at HTTP's PATH_INFO for optional blog name, archive yr/mo/day
 159 my @path_info = split m{/}, path_info() || param('path');
 160 shift @path_info;
 161
 162 while ($path_info[0] and $path_info[0] =~ /^[a-zA-Z].*$/ and $path_info[0] !~ /(.*)\.(.*)/) { $path_info .= '/' . shift @path_info; }
 163
 164 # Flavour specified by ?flav={flav} or index.{flav}
 165 $flavour = '';
 166
 167 if ( $path_info[$#path_info] =~ /(.+)\.(.+)$/ ) {
 168   $flavour = $2;
 169   $path_info .= "/$1.$2" if $1 ne 'index';
 170   pop @path_info;
 171 } else {
 172   $flavour = param('flav') || $default_flavour;
 173 }
 174
 175 # Strip spurious slashes
 176 $path_info =~ s!(^/*)|(/*$)!!g;
 177
 178 # Date fiddling
 179 ($path_info_yr,$path_info_mo,$path_info_da) = @path_info;
 180 $path_info_mo_num = $path_info_mo ? ( $path_info_mo =~ /\d{2}/ ? $path_info_mo : ($month2num{ucfirst(lc $path_info_mo)} || undef) ) : undef;
 181
 182 # Define standard template subroutine, plugin-overridable at Plugins: Template
 183 $template =
 184   sub {
 185     my ($path, $chunk, $flavour) = @_;
 186
 187     do {
 188       return join '', <$fh> if $fh->open("< $datadir/$path/$chunk.$flavour");
 189     } while ($path =~ s/(\/*[^\/]*)$// and $1);
 190
 191     # Check for definedness, since flavour can be the empty string
 192     if (defined $template{$flavour}{$chunk}) {
 193         return $template{$flavour}{$chunk};
 194     } elsif (defined $template{error}{$chunk}) {
 195         return $template{error}{$chunk}
 196     } else {
 197         return '';
 198     }
 199   };
 200 # Bring in the templates
 201 %template = ();
 202 while (<DATA>) {
 203   last if /^(__END__)$/;
 204   my($ct, $comp, $txt) = /^(\S+)\s(\S+)(?:\s(.*))?$/ or next;
 205   $txt =~ s/\\n/\n/mg;
 206   $template{$ct}{$comp} .= $txt . "\n";
 207 }
 208
 209 # Plugins: Start
 210 my $path_sep = $^O eq 'MSWin32' ? ';' : ':';
 211 my @plugin_dirs = split /$path_sep/, ($plugin_path || $plugin_dir);
 212 my @plugin_list = ();
 213 my %plugin_hash = ();
 214
 215 # If $plugin_list is set, read plugins to use from that file
 216 $plugin_list = "$config_dir/$plugin_list"
 217   if $plugin_list && $plugin_list !~ m!^\s*/!;
 218 if ( $plugin_list and -r $plugin_list and $fh->open("< $plugin_list") ) {
 219   @plugin_list = map { chomp $_; $_ } grep { /\S/ && ! /^#/ } <$fh>;
 220   $fh->close;
 221 }
 222 # Otherwise walk @plugin_dirs to get list of plugins to use
 223 elsif ( @plugin_dirs ) {
 224   for my $plugin_dir ( @plugin_dirs ) {
 225     next unless -d $plugin_dir;
 226     if ( opendir PLUGINS, $plugin_dir ) {
 227       for my $plugin ( grep { /^[\w:]+$/ && ! /~$/ && -f "$plugin_dir/$_" } readdir(PLUGINS) ) {
 228         # Ignore duplicates
 229         next if $plugin_hash{ $plugin };
 230         # Add to @plugin_list and %plugin_hash
 231         $plugin_hash{ $plugin } = "$plugin_dir/$plugin";
 232         push @plugin_list, $plugin;
 233       }
 234       closedir PLUGINS;
 235     }
 236   }
 237   @plugin_list = sort @plugin_list;
 238 }
 239
 240 # Load all plugins in @plugin_list
 241 unshift @INC, @plugin_dirs;
 242 foreach my $plugin ( @plugin_list ) {
 243   my($plugin_name, $off) = $plugin =~ /^\d*([\w:]+?)(_?)$/;
 244   my $on_off = $off eq '_' ? -1 : 1;
 245   # Allow perl module plugins
 246   if ($plugin =~ m/::/ && -z $plugin_hash{ $plugin }) {
 247     # For Blosxom::Plugin::Foo style plugins, we need to use a string require
 248     eval "require $plugin_name";
 249   }
 250   else {
 251     eval { require $plugin };
 252   }
 253   $@ and warn "$@ error finding or loading blosxom plugin $plugin_name - skipping\n" and next;
 254   $plugin_name->start() and ( $plugins{$plugin_name} = $on_off ) and push @plugins, $plugin_name;
 255 }
 256 shift @INC foreach @plugin_dirs;
 257
 258 # Plugins: Template
 259 # Allow for the first encountered plugin::template subroutine to override the
 260 # default built-in template subroutine
 261 my $tmp; foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('template') and defined($tmp = $plugin->template()) and $template = $tmp and last; }
 262
 263 # Provide backward compatibility for Blosxom < 2.0rc1 plug-ins
 264 sub load_template {
 265   return &$template(@_);
 266 }
 267
 268 # Define default entries subroutine
 269 $entries =
 270   sub {
 271     my(%files, %indexes, %others);
 272     find(
 273       sub {
 274         my $d;
 275         my $curr_depth = $File::Find::dir =~ tr[/][];
 276         return if $depth and $curr_depth > $depth;
 277
 278         if (
 279           # a match
 280           $File::Find::name =~ m!^$datadir/(?:(.*)/)?(.+)\.$file_extension$!
 281           # not an index, .file, and is readable
 282           and $2 ne 'index' and $2 !~ /^\./ and (-r $File::Find::name)
 283         ) {
 284
 285             # to show or not to show future entries
 286             (
 287               $show_future_entries
 288               or stat($File::Find::name)->mtime < time
 289             )
 290
 291               # add the file and its associated mtime to the list of files
 292               and $files{$File::Find::name} = stat($File::Find::name)->mtime
 293
 294                 # static rendering bits
 295                 and (
 296                   param('-all')
 297                   or !-f "$static_dir/$1/index." . $static_flavours[0]
 298                   or stat("$static_dir/$1/index." . $static_flavours[0])->mtime < stat($File::Find::name)->mtime
 299                 )
 300                   and $indexes{$1} = 1
 301                     and $d = join('/', (nice_date($files{$File::Find::name}))[5,2,3])
 302
 303                       and $indexes{$d} = $d
 304                         and $static_entries and $indexes{ ($1 ? "$1/" : '') . "$2.$file_extension" } = 1
 305
 306             }
 307             else {
 308               !-d $File::Find::name and -r $File::Find::name and $others{$File::Find::name} = stat($File::Find::name)->mtime
 309             }
 310       }, $datadir
 311     );
 312
 313     return (\%files, \%indexes, \%others);
 314   };
 315
 316 # Plugins: Entries
 317 # Allow for the first encountered plugin::entries subroutine to override the
 318 # default built-in entries subroutine
 319 my $tmp; foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('entries') and defined($tmp = $plugin->entries()) and $entries = $tmp and last; }
 320
 321 my ($files, $indexes, $others) = &$entries();
 322 %indexes = %$indexes;
 323
 324 # Static
 325 if (!$ENV{GATEWAY_INTERFACE} and param('-password') and $static_password and param('-password') eq $static_password) {
 326
 327   param('-quiet') or print "Blosxom is generating static index pages...\n";
 328
 329   # Home Page and Directory Indexes
 330   my %done;
 331   foreach my $path ( sort keys %indexes) {
 332     my $p = '';
 333     foreach ( ('', split /\//, $path) ) {
 334       $p .= "/$_";
 335       $p =~ s!^/!!;
 336       next if $done{$p}++;
 337       mkdir "$static_dir/$p", 0755 unless (-d "$static_dir/$p" or $p =~ /\.$file_extension$/);
 338       foreach $flavour ( @static_flavours ) {
 339         my $content_type = (&$template($p,'content_type',$flavour));
 340         $content_type =~ s!\n.*!!s;
 341         my $fn = $p =~ m!^(.+)\.$file_extension$! ? $1 : "$p/index";
 342         param('-quiet') or print "$fn.$flavour\n";
 343         my $fh_w = new FileHandle "> $static_dir/$fn.$flavour" or die "Couldn't open $static_dir/$p for writing: $!";
 344         $output = '';
 345         if ($indexes{$path} == 1) {
 346           # category
 347           $path_info = $p;
 348           # individual story
 349           $path_info =~ s!\.$file_extension$!\.$flavour!;
 350           print $fh_w &generate('static', $path_info, '', $flavour, $content_type);
 351         } else {
 352           # date
 353           local ($path_info_yr,$path_info_mo,$path_info_da, $path_info) =
 354               split /\//, $p, 4;
 355           unless (defined $path_info) {$path_info = ""};
 356           print $fh_w &generate('static', '', $p, $flavour, $content_type);
 357         }
 358         $fh_w->close;
 359       }
 360     }
 361   }
 362 }
 363
 364 # Dynamic
 365 else {
 366   my $content_type = (&$template($path_info,'content_type',$flavour));
 367   $content_type =~ s!\n.*!!s;
 368
 369   $content_type =~ s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
 370   $header = {-type=>$content_type};
 371
 372   print generate('dynamic', $path_info, "$path_info_yr/$path_info_mo_num/$path_info_da", $flavour, $content_type);
 373 }
 374
 375 # Plugins: End
 376 foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('end') and $entries = $plugin->end() }
 377
 378 # Generate
 379 sub generate {
 380   my($static_or_dynamic, $currentdir, $date, $flavour, $content_type) = @_;
 381
 382   %files = %$files; %others = ref $others ? %$others : ();
 383
 384   # Plugins: Filter
 385   foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('filter') and $entries = $plugin->filter(\%files, \%others) }
 386
 387   my %f = %files;
 388
 389   # Plugins: Skip
 390   # Allow plugins to decide if we can cut short story generation
 391   my $skip;
 392   foreach my $plugin (@plugins) {
 393       if ( $plugins{$plugin} > 0 and $plugin->can('skip') ) {
 394           if ( my $tmp = $plugin->skip() ) {
 395               $skip = $tmp;
 396               last;
 397           }
 398       }
 399   }
 400
 401
 402   # Define default interpolation subroutine
 403   $interpolate =
 404     sub {
 405       package blosxom;
 406       my $template = shift;
 407       $template =~
 408         s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
 409       return $template;
 410     };
 411
 412   unless (defined($skip) and $skip) {
 413
 414     # Plugins: Interpolate
 415     # Allow for the first encountered plugin::interpolate subroutine to
 416     # override the default built-in interpolate subroutine
 417     foreach my $plugin (@plugins) {
 418         if ( $plugins{$plugin} > 0 and $plugin->can('interpolate') ) {
 419             if ( my $tmp = $plugin->interpolate() ) {
 420                 $interpolate = $tmp;
 421                 last;
 422             }
 423         }
 424     }
 425
 426     # Head
 427     my $head = (&$template($currentdir,'head',$flavour));
 428
 429     # Plugins: Head
 430     foreach my $plugin (@plugins) {
 431         if ( $plugins{$plugin} > 0 and $plugin->can('head') ) {
 432             $entries = $plugin->head( $currentdir, \$head );
 433         }
 434     }
 435
 436     $head = &$interpolate($head);
 437
 438     $output .= $head;
 439
 440     # Stories
 441     my $curdate = '';
 442     my $ne = $num_entries;
 443
 444     if ( $currentdir =~ /(.*?)([^\/]+)\.(.+)$/ and $2 ne 'index' ) {
 445       $currentdir = "$1$2.$file_extension";
 446       $files{"$datadir/$1$2.$file_extension"} and %f = ( "$datadir/$1$2.$file_extension" => $files{"$datadir/$1$2.$file_extension"} );
 447     }
 448     else {
 449       $currentdir =~ s!/index\..+$!!;
 450     }
 451
 452     # Define a default sort subroutine
 453     my $sort = sub {
 454       my($files_ref) = @_;
 455       return sort { $files_ref->{$b} <=> $files_ref->{$a} } keys %$files_ref;
 456     };
 457
 458     # Plugins: Sort
 459     # Allow for the first encountered plugin::sort subroutine to override the
 460     # default built-in sort subroutine
 461     foreach my $plugin (@plugins) {
 462         if ( $plugins{$plugin} > 0 and $plugin->can('sort') ) {
 463             if ( my $tmp = $plugin->sort() ) {
 464                 $sort = $tmp;
 465                 last;
 466             }
 467         }
 468     }
 469
 470     foreach my $path_file ( &$sort(\%f, \%others) ) {
 471       last if $ne <= 0 && $date !~ /\d/;
 472       use vars qw/ $path $fn /;
 473       ($path,$fn) = $path_file =~ m!^$datadir/(?:(.*)/)?(.*)\.$file_extension!;
 474
 475       # Only stories in the right hierarchy
 476       $path =~ /^$currentdir/ or $path_file eq "$datadir/$currentdir" or next;
 477
 478       # Prepend a slash for use in templates only if a path exists
 479       $path &&= "/$path";
 480
 481       # Date fiddling for by-{year,month,day} archive views
 482       use vars qw/ $dw $mo $mo_num $da $ti $yr $hr $min $hr12 $ampm $utc_offset/;
 483       ($dw,$mo,$mo_num,$da,$ti,$yr,$utc_offset) = nice_date($files{"$path_file"});
 484       ($hr,$min) = split /:/, $ti;
 485       ($hr12, $ampm) = $hr >= 12 ? ($hr - 12,'pm') : ($hr, 'am');
 486       $hr12 =~ s/^0//; $hr12 == 0 and $hr12 = 12;
 487
 488       # Only stories from the right date
 489       my($path_info_yr,$path_info_mo_num, $path_info_da) = split /\//, $date;
 490       next if $path_info_yr && $yr != $path_info_yr; last if $path_info_yr && $yr < $path_info_yr;
 491       next if $path_info_mo_num && $mo ne $num2month[$path_info_mo_num];
 492       next if $path_info_da && $da != $path_info_da; last if $path_info_da && $da < $path_info_da;
 493
 494       # Date
 495       my $date = (&$template($path,'date',$flavour));
 496
 497       # Plugins: Date
 498       foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('date') and $entries = $plugin->date($currentdir, \$date, $files{$path_file}, $dw,$mo,$mo_num,$da,$ti,$yr) }
 499
 500       $date = &$interpolate($date);
 501
 502       $curdate ne $date and $curdate = $date and $output .= $date;
 503
 504       use vars qw/ $title $body $raw /;
 505       if (-f "$path_file" && $fh->open("< $path_file")) {
 506         chomp($title = <$fh>);
 507         chomp($body = join '', <$fh>);
 508         $fh->close;
 509         $raw = "$title\n$body";
 510       }
 511       my $story = (&$template($path,'story',$flavour));
 512
 513       # Plugins: Story
 514       foreach my $plugin (@plugins) {
 515           if ( $plugins{$plugin} > 0 and $plugin->can('story') ) {
 516               $entries = $plugin->story( $path, $fn, \$story, \$title, \$body );
 517           }
 518       }
 519
 520       if ($content_type =~ m{\bxml\b}) {
 521         # Escape <, >, and &, and to produce valid RSS
 522         my %escape = ('<'=>'&lt;', '>'=>'&gt;', '&'=>'&amp;', '"'=>'&quot;');
 523         my $escape_re  = join '|' => keys %escape;
 524         $title =~ s/($escape_re)/$escape{$1}/g;
 525         $body =~ s/($escape_re)/$escape{$1}/g;
 526       }
 527
 528       $story = &$interpolate($story);
 529
 530       $output .= $story;
 531       $fh->close;
 532
 533       $ne--;
 534     }
 535
 536     # Foot
 537     my $foot = (&$template($currentdir,'foot',$flavour));
 538
 539     # Plugins: Foot
 540     foreach my $plugin (@plugins) {
 541         if ( $plugins{$plugin} > 0 and $plugin->can('foot') ) {
 542             $entries = $plugin->foot( $currentdir, \$foot );
 543         }
 544     }
 545
 546     $foot = &$interpolate($foot);
 547     $output .= $foot;
 548
 549     # Plugins: Last
 550     foreach my $plugin (@plugins) {
 551         if ( $plugins{$plugin} > 0 and $plugin->can('last') ) {
 552             $entries = $plugin->last();
 553         }
 554     }
 555
 556   } # End skip
 557
 558   # Finally, add the header, if any and running dynamically
 559   $output = header($header) . $output if ($static_or_dynamic eq 'dynamic' and $header);
 560
 561   $output;
 562 }
 563
 564
 565 sub nice_date {
 566   my($unixtime) = @_;
 567
 568   my $c_time = ctime($unixtime);
 569   my($dw,$mo,$da,$hr,$min,$yr) = ( $c_time =~ /(\w{3}) +(\w{3}) +(\d{1,2}) +(\d{2}):(\d{2}):\d{2} +(\d{4})$/ );
 570   $ti="$hr:$min";
 571   $da = sprintf("%02d", $da);
 572   my $mo_num = $month2num{$mo};
 573
 574   my $offset = timegm(00, $min, $hr, $da, $mo_num-1, $yr-1900)-$unixtime;
 575   my $utc_offset = sprintf("%+03d", int($offset / 3600)).sprintf("%02d", ($offset % 3600)/60) ;
 576
 577   return ($dw,$mo,$mo_num,$da,$ti,$yr,$utc_offset);
 578 }
 579
 580
 581 # Default HTML and RSS template bits
 582 __DATA__
 583 html content_type text/html; charset=$blog_encoding
 584
 585 html head <html>
 586 html head     <head>
 587 html head         <meta http-equiv="content-type" content="text/html;charset=$blog_encoding" />
 588 html head         <link rel="alternate" type="type="application/rss+xml" title="RSS" href="$url/index.rss" />
 589 html head         <title>$blog_title $path_info_da $path_info_mo $path_info_yr
 590 html head         </title>
 591 html head     </head>
 592 html head     <body>
 593 html head         <center>
 594 html head             <font size="+3">$blog_title</font><br />
 595 html head             $path_info_da $path_info_mo $path_info_yr
 596 html head         </center>
 597 html head         <p />
 598
 599 html story        <p>
 600 html story            <a name="$fn"><b>$title</b></a><br />
 601 html story            $body<br />
 602 html story            <br />
 603 html story            posted at: $ti | path: <a href="$url$path">$path </a> | <a href="$url/$yr/$mo_num/$da#$fn">permanent link to this entry</a>
 604 html story        </p>
 605
 606 html date         <h3>$dw, $da $mo $yr</h3>
 607
 608 html foot
 609 html foot         <p />
 610 html foot         <center>
 611 html foot             <a href="http://blosxom.sourceforge.net/"><img src="http://blosxom.sourceforge.net/images/pb_blosxom.gif" border="0" /></a>
 612 html foot         </center>
 613 html foot     </body>
 614 html foot </html>
 615
 616 rss content_type text/xml; charset=$blog_encoding
 617
 618 rss head <?xml version="1.0" encoding="$blog_encoding"?>
 619 rss head <rss version="2.0">
 620 rss head   <channel>
 621 rss head     <title>$blog_title</title>
 622 rss head     <link>$url/$path_info</link>
 623 rss head     <description>$blog_description</description>
 624 rss head     <language>$blog_language</language>
 625 rss head     <docs>http://blogs.law.harvard.edu/tech/rss</docs>
 626 rss head     <generator>blosxom/$version</generator>
 627
 628 rss story   <item>
 629 rss story     <title>$title</title>
 630 rss story     <pubDate>$dw, $da $mo $yr $ti:00 $utc_offset</pubDate>
 631 rss story     <link>$url/$yr/$mo_num/$da#$fn</link>
 632 rss story     <category>$path</category>
 633 rss story     <guid isPermaLink="false">$path/$fn</guid>
 634 rss story     <description>$body</description>
 635 rss story   </item>
 636
 637 rss date
 638
 639 rss foot   </channel>
 640 rss foot </rss>
 641
 642 error content_type text/html
 643
 644 error head <html>
 645 error head <body>
 646 error head     <p><font color="red">Error: I'm afraid this is the first I've heard of a "$flavour" flavoured Blosxom.  Try dropping the "/+$flavour" bit from the end of the URL.</font></p>
 647
 648
 649 error story <p><b>$title</b><br />
 650 error story $body <a href="$url/$yr/$mo_num/$da#fn.$default_flavour">#</a></p>
 651
 652 error date <h3>$dw, $da $mo $yr</h3>
 653
 654 error foot     </body>
 655 error foot </html>
 656 __END__