Fix typo in default html head rss line, and adjust tests.
[pkg/blosxom.git] / blosxom.cgi
1 #!/usr/bin/perl
2
3 # Blosxom
4 # Author: Rael Dornfest <rael@oreilly.com>
5 # Version: 2.0.2
6 # Home/Docs/Licensing: http://blosxom.sourceforge.net/
7 # Development/Downloads: http://sourceforge.net/projects/blosxom
8
9 package blosxom;
10
11 # --- Configurable variables -----
12
13 # What's this blog's title?
14 $blog_title = "My Weblog";
15
16 # What's this blog's description (for outgoing RSS feed)?
17 $blog_description = "Yet another Blosxom weblog.";
18
19 # What's this blog's primary language (for outgoing RSS feed)?
20 $blog_language = "en";
21
22 # What's this blog's text encoding ?
23 $blog_encoding = "UTF-8";
24
25 # Where are this blog's entries kept?
26 $datadir = "/Library/WebServer/Documents/blosxom";
27
28 # What's my preferred base URL for this blog (leave blank for automatic)?
29 $url = "";
30
31 # Should I stick only to the datadir for items or travel down the
32 # directory hierarchy looking for items?  If so, to what depth?
33 # 0 = infinite depth (aka grab everything), 1 = datadir only, n = n levels down
34 $depth = 0;
35
36 # How many entries should I show on the home page?
37 $num_entries = 40;
38
39 # What file extension signifies a blosxom entry?
40 $file_extension = "txt";
41
42 # What is the default flavour?
43 $default_flavour = "html";
44
45 # Should I show entries from the future (i.e. dated after now)?
46 $show_future_entries = 0;
47
48 # --- Plugins (Optional) -----
49
50 # File listing plugins blosxom should load
51 # (if empty blosxom will load all plugins in $plugin_dir and $plugin_path directories)
52 $plugin_list = "";
53
54 # Where are my plugins kept?
55 $plugin_dir = "";
56
57 # Where should my plugins keep their state information?
58 $plugin_state_dir = "$plugin_dir/state";
59
60 # Additional plugins location
61 # List of directories, separated by ';' on windows, ':' everywhere else
62 $plugin_path = "";
63
64 # --- Static Rendering -----
65
66 # Where are this blog's static files to be created?
67 $static_dir = "/Library/WebServer/Documents/blog";
68
69 # What's my administrative password (you must set this for static rendering)?
70 $static_password = "";
71
72 # What flavours should I generate statically?
73 @static_flavours = qw/html rss/;
74
75 # Should I statically generate individual entries?
76 # 0 = no, 1 = yes
77 $static_entries = 0;
78
79 # --------------------------------
80
81 use vars
82     qw! $version $blog_title $blog_description $blog_language $blog_encoding $datadir $url %template $template $depth $num_entries $file_extension $default_flavour $static_or_dynamic $config_dir $plugin_list $plugin_path $plugin_dir $plugin_state_dir @plugins %plugins $static_dir $static_password @static_flavours $static_entries $path_info $path_info_yr $path_info_mo $path_info_da $path_info_mo_num $flavour $static_or_dynamic %month2num @num2month $interpolate $entries $output $header $show_future_entries %files %indexes %others !;
83
84 use strict;
85 use FileHandle;
86 use File::Find;
87 use File::stat;
88 use Time::Local;
89 use CGI qw/:standard :netscape/;
90
91 $version = "2.0.2";
92
93 # Load configuration from $ENV{BLOSXOM_CONFIG_DIR}/blosxom.conf, if it exists
94 my $blosxom_config;
95 if ( $ENV{BLOSXOM_CONFIG_FILE} && -r $ENV{BLOSXOM_CONFIG_FILE} ) {
96     $blosxom_config = $ENV{BLOSXOM_CONFIG_FILE};
97     ( $config_dir = $blosxom_config ) =~ s! / [^/]* $ !!x;
98 }
99 else {
100     for my $blosxom_config_dir ( $ENV{BLOSXOM_CONFIG_DIR}, '/etc/blosxom',
101         '/etc' )
102     {
103         if ( -r "$blosxom_config_dir/blosxom.conf" ) {
104             $config_dir     = $blosxom_config_dir;
105             $blosxom_config = "$blosxom_config_dir/blosxom.conf";
106             last;
107         }
108     }
109 }
110
111 # Load $blosxom_config
112 if ($blosxom_config) {
113     if ( -r $blosxom_config ) {
114         eval { require $blosxom_config }
115             or warn "Error reading blosxom config file '$blosxom_config'"
116             . ( $@ ? ": $@" : '' );
117     }
118     else {
119         warn "Cannot find or read blosxom config file '$blosxom_config'";
120     }
121 }
122
123 my $fh = new FileHandle;
124
125 %month2num = (
126     nil => '00',
127     Jan => '01',
128     Feb => '02',
129     Mar => '03',
130     Apr => '04',
131     May => '05',
132     Jun => '06',
133     Jul => '07',
134     Aug => '08',
135     Sep => '09',
136     Oct => '10',
137     Nov => '11',
138     Dec => '12'
139 );
140 @num2month = sort { $month2num{$a} <=> $month2num{$b} } keys %month2num;
141
142 # Use the stated preferred URL or figure it out automatically
143 $url ||= url( -path_info => 1 );
144 $url =~ s/^included:/http:/ if $ENV{SERVER_PROTOCOL} eq 'INCLUDED';
145
146 # NOTE: Since v3.12, it looks as if CGI.pm misbehaves for SSIs and
147 # always appends path_info to the url. To fix this, we always
148 # request an url with path_info, and always remove it from the end of the
149 # string.
150 my $pi_len = length $ENV{PATH_INFO};
151 my $might_be_pi = substr( $url, -$pi_len );
152 substr( $url, -length $ENV{PATH_INFO} ) = ''
153     if $might_be_pi eq $ENV{PATH_INFO};
154
155 $url =~ s!/$!!;
156
157 # Drop ending any / from dir settings
158 $datadir    =~ s!/$!!;
159 $plugin_dir =~ s!/$!!;
160 $static_dir =~ s!/$!!;
161
162 # Fix depth to take into account datadir's path
163 $depth += ( $datadir =~ tr[/][] ) - 1 if $depth;
164
165 # Global variable to be used in head/foot.{flavour} templates
166 $path_info = '';
167
168 if (    !$ENV{GATEWAY_INTERFACE}
169     and param('-password')
170     and $static_password
171     and param('-password') eq $static_password )
172 {
173     $static_or_dynamic = 'static';
174 }
175 else {
176     $static_or_dynamic = 'dynamic';
177     param( -name => '-quiet', -value => 1 );
178 }
179
180 # Path Info Magic
181 # Take a gander at HTTP's PATH_INFO for optional blog name, archive yr/mo/day
182 my @path_info = split m{/}, path_info() || param('path');
183 shift @path_info;
184
185 while ( $path_info[0]
186     and $path_info[0] =~ /^[a-zA-Z].*$/
187     and $path_info[0] !~ /(.*)\.(.*)/ )
188 {
189     $path_info .= '/' . shift @path_info;
190 }
191
192 # Flavour specified by ?flav={flav} or index.{flav}
193 $flavour = '';
194
195 if ( $path_info[$#path_info] =~ /(.+)\.(.+)$/ ) {
196     $flavour = $2;
197     $path_info .= "/$1.$2" if $1 ne 'index';
198     pop @path_info;
199 }
200 else {
201     $flavour = param('flav') || $default_flavour;
202 }
203
204 # Strip spurious slashes
205 $path_info =~ s!(^/*)|(/*$)!!g;
206
207 # Date fiddling
208 ( $path_info_yr, $path_info_mo, $path_info_da ) = @path_info;
209 $path_info_mo_num
210     = $path_info_mo
211     ? ( $path_info_mo =~ /\d{2}/
212     ? $path_info_mo
213     : ( $month2num{ ucfirst( lc $path_info_mo ) } || undef ) )
214     : undef;
215
216 # Define standard template subroutine, plugin-overridable at Plugins: Template
217 $template = sub {
218     my ( $path, $chunk, $flavour ) = @_;
219
220     do {
221         return join '', <$fh>
222             if $fh->open("< $datadir/$path/$chunk.$flavour");
223     } while ( $path =~ s/(\/*[^\/]*)$// and $1 );
224
225     # Check for definedness, since flavour can be the empty string
226     if ( defined $template{$flavour}{$chunk} ) {
227         return $template{$flavour}{$chunk};
228     }
229     elsif ( defined $template{error}{$chunk} ) {
230         return $template{error}{$chunk};
231     }
232     else {
233         return '';
234     }
235 };
236
237 # Bring in the templates
238 %template = ();
239 while (<DATA>) {
240     last if /^(__END__)$/;
241     my ( $ct, $comp, $txt ) = /^(\S+)\s(\S+)(?:\s(.*))?$/ or next;
242     $txt =~ s/\\n/\n/mg;
243     $template{$ct}{$comp} .= $txt . "\n";
244 }
245
246 # Plugins: Start
247 my $path_sep = $^O eq 'MSWin32' ? ';' : ':';
248 my @plugin_dirs = split /$path_sep/, $plugin_path;
249 unshift @plugin_dirs, $plugin_dir;
250 my @plugin_list = ();
251 my %plugin_hash = ();
252
253 # If $plugin_list is set, read plugins to use from that file
254 if ( $plugin_list ) {
255     if ( -r $plugin_list and $fh->open("< $plugin_list") ) {
256         @plugin_list = map { chomp $_; $_ } grep { /\S/ && !/^#/ } <$fh>;
257         $fh->close;
258     }
259     else {
260         warn "unable to read or open plugin_list '$plugin_list': $!";
261         $plugin_list = '';
262     }
263 }
264
265 # Otherwise walk @plugin_dirs to get list of plugins to use
266 if ( ! @plugin_list && @plugin_dirs ) {
267     for my $plugin_dir (@plugin_dirs) {
268         next unless -d $plugin_dir;
269         if ( opendir PLUGINS, $plugin_dir ) {
270             for my $plugin (
271                 grep { /^[\w:]+$/ && !/~$/ && -f "$plugin_dir/$_" }
272                 readdir(PLUGINS) )
273             {
274
275                 # Ignore duplicates
276                 next if $plugin_hash{$plugin};
277
278                 # Add to @plugin_list and %plugin_hash
279                 $plugin_hash{$plugin} = "$plugin_dir/$plugin";
280                 push @plugin_list, $plugin;
281             }
282             closedir PLUGINS;
283         }
284     }
285     @plugin_list = sort @plugin_list;
286 }
287
288 # Load all plugins in @plugin_list
289 unshift @INC, @plugin_dirs;
290 foreach my $plugin (@plugin_list) {
291     my ( $plugin_name, $off ) = $plugin =~ /^\d*([\w:]+?)(_?)$/;
292     my $plugin_file = $plugin_list ? $plugin_name : $plugin;
293     my $on_off = $off eq '_' ? -1 : 1;
294
295     # Allow perl module plugins
296     # The -z test is a hack to allow a zero-length placeholder file in a 
297     #   $plugin_path directory to indicate an @INC module should be loaded
298     if ( $plugin =~ m/::/ && ( $plugin_list || -z $plugin_hash{$plugin} ) ) {
299
300      # For Blosxom::Plugin::Foo style plugins, we need to use a string require
301         eval "require $plugin_file";
302     }
303     else
304     { # we try first to load from $plugin_dir before attempting from $plugin_path
305         eval        { require "$plugin_dir/$plugin_file" }
306             or eval { require $plugin_file };
307     }
308
309     if ($@) {
310         warn "error finding or loading blosxom plugin '$plugin_name': $@";
311         next;
312     }
313     if ( $plugin_name->start() and ( $plugins{$plugin_name} = $on_off ) ) {
314         push @plugins, $plugin_name;
315     }
316
317 }
318 shift @INC foreach @plugin_dirs;
319
320 # Plugins: Template
321 # Allow for the first encountered plugin::template subroutine to override the
322 # default built-in template subroutine
323 foreach my $plugin (@plugins) {
324     if ( $plugins{$plugin} > 0 and $plugin->can('template') ) {
325         if ( my $tmp = $plugin->template() ) {
326             $template = $tmp;
327             last;
328         }
329     }
330 }
331
332 # Provide backward compatibility for Blosxom < 2.0rc1 plug-ins
333 sub load_template {
334     return &$template(@_);
335 }
336
337 # Define default entries subroutine
338 $entries = sub {
339     my ( %files, %indexes, %others );
340     find(
341         sub {
342             my $d;
343             my $curr_depth = $File::Find::dir =~ tr[/][];
344             return if $depth and $curr_depth > $depth;
345
346             if (
347
348                 # a match
349                 $File::Find::name
350                 =~ m!^$datadir/(?:(.*)/)?(.+)\.$file_extension$!
351
352                 # not an index, .file, and is readable
353                 and $2 ne 'index' and $2 !~ /^\./ and ( -r $File::Find::name )
354                 )
355             {
356
357                 # read modification time
358                 my $mtime = stat($File::Find::name)->mtime or return;
359
360                 # to show or not to show future entries
361                 return unless ( $show_future_entries or $mtime < time );
362
363                 # add the file and its associated mtime to the list of files
364                 $files{$File::Find::name} = $mtime;
365
366                 # static rendering bits
367                 my $static_file
368                     = "$static_dir/$1/index." . $static_flavours[0];
369                 if (   param('-all')
370                     or !-f $static_file
371                     or stat($static_file)->mtime < $mtime )
372                 {
373                     $indexes{$1} = 1;
374                     $d = join( '/', ( nice_date($mtime) )[ 5, 2, 3 ] );
375                     $indexes{$d} = $d;
376                     $indexes{ ( $1 ? "$1/" : '' ) . "$2.$file_extension" } = 1
377                         if $static_entries;
378                 }
379             }
380
381             # not an entries match
382             elsif ( !-d $File::Find::name and -r $File::Find::name ) {
383                 $others{$File::Find::name} = stat($File::Find::name)->mtime;
384             }
385         },
386         $datadir
387     );
388
389     return ( \%files, \%indexes, \%others );
390 };
391
392 # Plugins: Entries
393 # Allow for the first encountered plugin::entries subroutine to override the
394 # default built-in entries subroutine
395 foreach my $plugin (@plugins) {
396     if ( $plugins{$plugin} > 0 and $plugin->can('entries') ) {
397         if ( my $tmp = $plugin->entries() ) {
398             $entries = $tmp;
399             last;
400         }
401     }
402 }
403
404 my ( $files, $indexes, $others ) = &$entries();
405 %indexes = %$indexes;
406
407 # Static
408 if (    !$ENV{GATEWAY_INTERFACE}
409     and param('-password')
410     and $static_password
411     and param('-password') eq $static_password )
412 {
413
414     param('-quiet') or print "Blosxom is generating static index pages...\n";
415
416     # Home Page and Directory Indexes
417     my %done;
418     foreach my $path ( sort keys %indexes ) {
419         my $p = '';
420         foreach ( ( '', split /\//, $path ) ) {
421             $p .= "/$_";
422             $p =~ s!^/!!;
423             next if $done{$p}++;
424             mkdir "$static_dir/$p", 0755
425                 unless ( -d "$static_dir/$p" or $p =~ /\.$file_extension$/ );
426             foreach $flavour (@static_flavours) {
427                 my $content_type
428                     = ( &$template( $p, 'content_type', $flavour ) );
429                 $content_type =~ s!\n.*!!s;
430                 my $fn = $p =~ m!^(.+)\.$file_extension$! ? $1 : "$p/index";
431                 param('-quiet') or print "$fn.$flavour\n";
432                 my $fh_w = new FileHandle "> $static_dir/$fn.$flavour"
433                     or die "Couldn't open $static_dir/$p for writing: $!";
434                 $output = '';
435                 if ( $indexes{$path} == 1 ) {
436
437                     # category
438                     $path_info = $p;
439
440                     # individual story
441                     $path_info =~ s!\.$file_extension$!\.$flavour!;
442                     print $fh_w &generate( 'static', $path_info, '', $flavour,
443                         $content_type );
444                 }
445                 else {
446
447                     # date
448                     local (
449                         $path_info_yr, $path_info_mo,
450                         $path_info_da, $path_info
451                     ) = split /\//, $p, 4;
452                     unless ( defined $path_info ) { $path_info = "" }
453                     print $fh_w &generate( 'static', '', $p, $flavour,
454                         $content_type );
455                 }
456                 $fh_w->close;
457             }
458         }
459     }
460 }
461
462 # Dynamic
463 else {
464     my $content_type = ( &$template( $path_info, 'content_type', $flavour ) );
465     $content_type =~ s!\n.*!!s;
466
467     $content_type =~ s/(\$\w+(?:::\w+)*)/"defined $1 ? $1 : ''"/gee;
468     $header = { -type => $content_type };
469
470     print generate( 'dynamic', $path_info,
471         "$path_info_yr/$path_info_mo_num/$path_info_da",
472         $flavour, $content_type );
473 }
474
475 # Plugins: End
476 foreach my $plugin (@plugins) {
477     if ( $plugins{$plugin} > 0 and $plugin->can('end') ) {
478         $entries = $plugin->end();
479     }
480 }
481
482 # Generate
483 sub generate {
484     my ( $static_or_dynamic, $currentdir, $date, $flavour, $content_type )
485         = @_;
486
487     %files = %$files;
488     %others = ref $others ? %$others : ();
489
490     # Plugins: Filter
491     foreach my $plugin (@plugins) {
492         if ( $plugins{$plugin} > 0 and $plugin->can('filter') ) {
493             $entries = $plugin->filter( \%files, \%others );
494         }
495     }
496
497     my %f = %files;
498
499     # Plugins: Skip
500     # Allow plugins to decide if we can cut short story generation
501     my $skip;
502     foreach my $plugin (@plugins) {
503         if ( $plugins{$plugin} > 0 and $plugin->can('skip') ) {
504             if ( my $tmp = $plugin->skip() ) {
505                 $skip = $tmp;
506                 last;
507             }
508         }
509     }
510
511     # Define default interpolation subroutine
512     $interpolate = sub {
513
514         package blosxom;
515         my $template = shift;
516         $template =~ s/(\$\w+(?:::\w+)*)/"defined $1 ? $1 : ''"/gee;
517         return $template;
518     };
519
520     unless ( defined($skip) and $skip ) {
521
522         # Plugins: Interpolate
523         # Allow for the first encountered plugin::interpolate subroutine to
524         # override the default built-in interpolate subroutine
525         foreach my $plugin (@plugins) {
526             if ( $plugins{$plugin} > 0 and $plugin->can('interpolate') ) {
527                 if ( my $tmp = $plugin->interpolate() ) {
528                     $interpolate = $tmp;
529                     last;
530                 }
531             }
532         }
533
534         # Head
535         my $head = ( &$template( $currentdir, 'head', $flavour ) );
536
537         # Plugins: Head
538         foreach my $plugin (@plugins) {
539             if ( $plugins{$plugin} > 0 and $plugin->can('head') ) {
540                 $entries = $plugin->head( $currentdir, \$head );
541             }
542         }
543
544         $head = &$interpolate($head);
545
546         $output .= $head;
547
548         # Stories
549         my $curdate = '';
550         my $ne      = $num_entries;
551
552         if ( $currentdir =~ /(.*?)([^\/]+)\.(.+)$/ and $2 ne 'index' ) {
553             $currentdir = "$1$2.$file_extension";
554             %f = ( "$datadir/$currentdir" => $files{"$datadir/$currentdir"} )
555                 if $files{"$datadir/$currentdir"};
556         }
557         else {
558             $currentdir =~ s!/index\..+$!!;
559         }
560
561         # Define a default sort subroutine
562         my $sort = sub {
563             my ($files_ref) = @_;
564             return
565                 sort { $files_ref->{$b} <=> $files_ref->{$a} }
566                 keys %$files_ref;
567         };
568
569      # Plugins: Sort
570      # Allow for the first encountered plugin::sort subroutine to override the
571      # default built-in sort subroutine
572         foreach my $plugin (@plugins) {
573             if ( $plugins{$plugin} > 0 and $plugin->can('sort') ) {
574                 if ( my $tmp = $plugin->sort() ) {
575                     $sort = $tmp;
576                     last;
577                 }
578             }
579         }
580
581         foreach my $path_file ( &$sort( \%f, \%others ) ) {
582             last if $ne <= 0 && $date !~ /\d/;
583             use vars qw/ $path $fn /;
584             ( $path, $fn )
585                 = $path_file =~ m!^$datadir/(?:(.*)/)?(.*)\.$file_extension!;
586
587             # Only stories in the right hierarchy
588             $path =~ /^$currentdir/
589                 or $path_file eq "$datadir/$currentdir"
590                 or next;
591
592             # Prepend a slash for use in templates only if a path exists
593             $path &&= "/$path";
594
595             # Date fiddling for by-{year,month,day} archive views
596             use vars
597                 qw/ $dw $mo $mo_num $da $ti $yr $hr $min $hr12 $ampm $utc_offset/;
598             ( $dw, $mo, $mo_num, $da, $ti, $yr, $utc_offset )
599                 = nice_date( $files{"$path_file"} );
600             ( $hr, $min ) = split /:/, $ti;
601             ( $hr12, $ampm ) = $hr >= 12 ? ( $hr - 12, 'pm' ) : ( $hr, 'am' );
602             $hr12 =~ s/^0//;
603             if ( $hr12 == 0 ) { $hr12 = 12 }
604
605             # Only stories from the right date
606             my ( $path_info_yr, $path_info_mo_num, $path_info_da )
607                 = split /\//, $date;
608             next if $path_info_yr     && $yr != $path_info_yr;
609             last if $path_info_yr     && $yr < $path_info_yr;
610             next if $path_info_mo_num && $mo ne $num2month[$path_info_mo_num];
611             next if $path_info_da     && $da != $path_info_da;
612             last if $path_info_da     && $da < $path_info_da;
613
614             # Date
615             my $date = ( &$template( $path, 'date', $flavour ) );
616
617             # Plugins: Date
618             foreach my $plugin (@plugins) {
619                 if ( $plugins{$plugin} > 0 and $plugin->can('date') ) {
620                     $entries
621                         = $plugin->date( $currentdir, \$date,
622                         $files{$path_file}, $dw, $mo, $mo_num, $da, $ti,
623                         $yr );
624                 }
625             }
626
627             $date = &$interpolate($date);
628
629             if ( $date && $curdate ne $date ) {
630                 $curdate = $date;
631                 $output .= $date;
632             }
633
634             use vars qw/ $title $body $raw /;
635             if ( -f "$path_file" && $fh->open("< $path_file") ) {
636                 chomp( $title = <$fh> );
637                 chomp( $body = join '', <$fh> );
638                 $fh->close;
639                 $raw = "$title\n$body";
640             }
641             my $story = ( &$template( $path, 'story', $flavour ) );
642
643             # Plugins: Story
644             foreach my $plugin (@plugins) {
645                 if ( $plugins{$plugin} > 0 and $plugin->can('story') ) {
646                     $entries = $plugin->story( $path, $fn, \$story, \$title,
647                         \$body );
648                 }
649             }
650
651             if ( $content_type =~ m{\bxml\b} ) {
652
653                 # Escape <, >, and &, and to produce valid RSS
654                 my %escape = (
655                     '<' => '&lt;',
656                     '>' => '&gt;',
657                     '&' => '&amp;',
658                     '"' => '&quot;'
659                 );
660                 my $escape_re = join '|' => keys %escape;
661                 $title =~ s/($escape_re)/$escape{$1}/g;
662                 $body  =~ s/($escape_re)/$escape{$1}/g;
663             }
664
665             $story = &$interpolate($story);
666
667             $output .= $story;
668             $fh->close;
669
670             $ne--;
671         }
672
673         # Foot
674         my $foot = ( &$template( $currentdir, 'foot', $flavour ) );
675
676         # Plugins: Foot
677         foreach my $plugin (@plugins) {
678             if ( $plugins{$plugin} > 0 and $plugin->can('foot') ) {
679                 $entries = $plugin->foot( $currentdir, \$foot );
680             }
681         }
682
683         $foot = &$interpolate($foot);
684         $output .= $foot;
685
686         # Plugins: Last
687         foreach my $plugin (@plugins) {
688             if ( $plugins{$plugin} > 0 and $plugin->can('last') ) {
689                 $entries = $plugin->last();
690             }
691         }
692
693     }    # End skip
694
695     # Finally, add the header, if any and running dynamically
696     $output = header($header) . $output
697         if ( $static_or_dynamic eq 'dynamic' and $header );
698
699     $output;
700 }
701
702 sub nice_date {
703     my ($unixtime) = @_;
704
705     my $c_time = CORE::localtime($unixtime);
706     my ( $dw, $mo, $da, $hr, $min, $sec, $yr )
707         = ( $c_time
708             =~ /(\w{3}) +(\w{3}) +(\d{1,2}) +(\d{2}):(\d{2}):(\d{2}) +(\d{4})$/
709         );
710     $ti = "$hr:$min";
711     $da = sprintf( "%02d", $da );
712     my $mo_num = $month2num{$mo};
713
714     my $offset
715         = timegm( $sec, $min, $hr, $da, $mo_num - 1, $yr - 1900 ) - $unixtime;
716     my $utc_offset = sprintf( "%+03d", int( $offset / 3600 ) )
717         . sprintf( "%02d", ( $offset % 3600 ) / 60 );
718
719     return ( $dw, $mo, $mo_num, $da, $ti, $yr, $utc_offset );
720 }
721
722 # Default HTML and RSS template bits
723 __DATA__
724 html content_type text/html; charset=$blog_encoding
725
726 html head <html>
727 html head     <head>
728 html head         <meta http-equiv="content-type" content="text/html;charset=$blog_encoding" />
729 html head         <link rel="alternate" type="application/rss+xml" title="RSS" href="$url/index.rss" />
730 html head         <title>$blog_title $path_info_da $path_info_mo $path_info_yr
731 html head         </title>
732 html head     </head>
733 html head     <body>
734 html head         <center>
735 html head             <font size="+3">$blog_title</font><br />
736 html head             $path_info_da $path_info_mo $path_info_yr
737 html head         </center>
738 html head         <p />
739
740 html story        <p>
741 html story            <a name="$fn"><b>$title</b></a><br />
742 html story            $body<br />
743 html story            <br />
744 html story            posted at: $ti | path: <a href="$url$path">$path </a> | <a href="$url/$yr/$mo_num/$da#$fn">permanent link to this entry</a>
745 html story        </p>
746
747 html date         <h3>$dw, $da $mo $yr</h3>
748
749 html foot
750 html foot         <p />
751 html foot         <center>
752 html foot             <a href="http://blosxom.sourceforge.net/"><img src="http://blosxom.sourceforge.net/images/pb_blosxom.gif" border="0" /></a>
753 html foot         </center>
754 html foot     </body>
755 html foot </html>
756
757 rss content_type text/xml; charset=$blog_encoding
758
759 rss head <?xml version="1.0" encoding="$blog_encoding"?>
760 rss head <rss version="2.0">
761 rss head   <channel>
762 rss head     <title>$blog_title</title>
763 rss head     <link>$url/$path_info</link>
764 rss head     <description>$blog_description</description>
765 rss head     <language>$blog_language</language>
766 rss head     <docs>http://blogs.law.harvard.edu/tech/rss</docs>
767 rss head     <generator>blosxom/$version</generator>
768
769 rss story   <item>
770 rss story     <title>$title</title>
771 rss story     <pubDate>$dw, $da $mo $yr $ti:00 $utc_offset</pubDate>
772 rss story     <link>$url/$yr/$mo_num/$da#$fn</link>
773 rss story     <category>$path</category>
774 rss story     <guid isPermaLink="false">$path/$fn</guid>
775 rss story     <description>$body</description>
776 rss story   </item>
777
778 rss date 
779
780 rss foot   </channel>
781 rss foot </rss>
782
783 error content_type text/html
784
785 error head <html>
786 error head <body>
787 error head     <p><font color="red">Error: I'm afraid this is the first I've heard of a "$flavour" flavoured Blosxom.  Try dropping the "/+$flavour" bit from the end of the URL.</font></p>
788
789
790 error story <p><b>$title</b><br />
791 error story $body <a href="$url/$yr/$mo_num/$da#fn.$default_flavour">#</a></p>
792
793 error date <h3>$dw, $da $mo $yr</h3>
794
795 error foot     </body>
796 error foot </html>
797 __END__
798