2c6b6ee17d1e7e5692668cba4f5be2d3297ff4dd
[pkg/blosxom.git] / blosxom.cgi
1 #!/usr/bin/perl
2
3 # Blosxom
4 # Author: Rael Dornfest <rael@oreilly.com>
5 # Version: 2.0.2
6 # Home/Docs/Licensing: http://blosxom.sourceforge.net/
7 # Development/Downloads: http://sourceforge.net/projects/blosxom
8
9 package blosxom;
10
11 # --- Configurable variables -----
12
13 # What's this blog's title?
14 $blog_title = "My Weblog";
15
16 # What's this blog's description (for outgoing RSS feed)?
17 $blog_description = "Yet another Blosxom weblog.";
18
19 # What's this blog's primary language (for outgoing RSS feed)?
20 $blog_language = "en";
21
22 # What's this blog's text encoding ?
23 $blog_encoding = "UTF-8";
24
25 # Where are this blog's entries kept?
26 $datadir = "/Library/WebServer/Documents/blosxom";
27
28 # What's my preferred base URL for this blog (leave blank for automatic)?
29 $url = "";
30
31 # Should I stick only to the datadir for items or travel down the
32 # directory hierarchy looking for items?  If so, to what depth?
33 # 0 = infinite depth (aka grab everything), 1 = datadir only, n = n levels down
34 $depth = 0;
35
36 # How many entries should I show on the home page?
37 $num_entries = 40;
38
39 # What file extension signifies a blosxom entry?
40 $file_extension = "txt";
41
42 # What is the default flavour?
43 $default_flavour = "html";
44
45 # Should I show entries from the future (i.e. dated after now)?
46 $show_future_entries = 0;
47
48 # --- Plugins (Optional) -----
49
50 # File listing plugins blosxom should load 
51 # (if empty blosxom will load all plugins in $plugin_path directories)
52 $plugin_list = "";
53
54 # Where are my plugins kept? 
55 # List of directories, separated by ';' on windows, ':' everywhere else
56 $plugin_path = "";
57
58 # Where should my plugins keep their state information?
59 $plugin_state_dir = "";
60 #$plugin_state_dir = "/var/lib/blosxom/state";
61
62 # --- Static Rendering -----
63
64 # Where are this blog's static files to be created?
65 $static_dir = "/Library/WebServer/Documents/blog";
66
67 # What's my administrative password (you must set this for static rendering)?
68 $static_password = "";
69
70 # What flavours should I generate statically?
71 @static_flavours = qw/html rss/;
72
73 # Should I statically generate individual entries?
74 # 0 = no, 1 = yes
75 $static_entries = 0;
76
77 # --------------------------------
78
79 use vars qw! $version $blog_title $blog_description $blog_language $blog_encoding $datadir $url %template $template $depth $num_entries $file_extension $default_flavour $static_or_dynamic $config_dir $plugin_list $plugin_path $plugin_dir $plugin_state_dir @plugins %plugins $static_dir $static_password @static_flavours $static_entries $path_info $path_info_yr $path_info_mo $path_info_da $path_info_mo_num $flavour $static_or_dynamic %month2num @num2month $interpolate $entries $output $header $show_future_entries %files %indexes %others !;
80
81 use strict;
82 use FileHandle;
83 use File::Find;
84 use File::stat;
85 use Time::localtime;
86 use Time::Local;
87 use CGI qw/:standard :netscape/;
88
89 $version = "2.0.2";
90
91 # Load configuration from $ENV{BLOSXOM_CONFIG_DIR}/blosxom.conf, if it exists
92 my $blosxom_config;
93 if ($ENV{BLOSXOM_CONFIG_FILE} && -r $ENV{BLOSXOM_CONFIG_FILE}) {
94   $blosxom_config = $ENV{BLOSXOM_CONFIG_FILE};
95   ($config_dir = $blosxom_config) =~ s! / [^/]* $ !!x;                          
96 }
97 else {
98   for my $blosxom_config_dir ($ENV{BLOSXOM_CONFIG_DIR}, '/etc/blosxom', '/etc') {
99     if (-r "$blosxom_config_dir/blosxom.conf") {
100       $config_dir = $blosxom_config_dir;
101       $blosxom_config = "$blosxom_config_dir/blosxom.conf";
102       last;
103     }
104   }
105 }
106 # Load $blosxom_config
107 if ($blosxom_config) { 
108   if (-r $blosxom_config) {
109     eval { require $blosxom_config } or
110       warn "Error reading blosxom config file '$blosxom_config'" . ($@ ? ": $@" : '');
111   }
112   else {
113     warn "Cannot find or read blosxom config file '$blosxom_config'";
114   }
115 }
116
117 my $fh = new FileHandle;
118
119 %month2num = (nil=>'00', Jan=>'01', Feb=>'02', Mar=>'03', Apr=>'04', May=>'05', Jun=>'06', Jul=>'07', Aug=>'08', Sep=>'09', Oct=>'10', Nov=>'11', Dec=>'12');
120 @num2month = sort { $month2num{$a} <=> $month2num{$b} } keys %month2num;
121
122 # Use the stated preferred URL or figure it out automatically
123 $url ||= url(-path_info => 1);
124 $url =~ s/^included:/http:/ if $ENV{SERVER_PROTOCOL} eq 'INCLUDED';
125
126 # NOTE: Since v3.12, it looks as if CGI.pm misbehaves for SSIs and
127 # always appends path_info to the url. To fix this, we always
128 # request an url with path_info, and always remove it from the end of the
129 # string.
130 my $pi_len = length $ENV{PATH_INFO};
131 my $might_be_pi = substr($url, -$pi_len);
132 substr($url, -length $ENV{PATH_INFO}) = '' if $might_be_pi eq $ENV{PATH_INFO};
133
134 $url =~ s!/$!!;
135
136 # Drop ending any / from dir settings
137 $datadir =~ s!/$!!; $plugin_dir =~ s!/$!!; $static_dir =~ s!/$!!;
138   
139 # Fix depth to take into account datadir's path
140 $depth += ($datadir =~ tr[/][]) - 1 if $depth;
141
142 # Global variable to be used in head/foot.{flavour} templates
143 $path_info = '';
144
145 if (    !$ENV{GATEWAY_INTERFACE}
146     and param('-password')
147     and $static_password
148     and param('-password') eq $static_password )
149 {
150     $static_or_dynamic = 'static';
151 }
152 else {
153     $static_or_dynamic = 'dynamic';
154     param( -name => '-quiet', -value => 1 );
155 }
156
157 # Path Info Magic
158 # Take a gander at HTTP's PATH_INFO for optional blog name, archive yr/mo/day
159 my @path_info = split m{/}, path_info() || param('path'); 
160 shift @path_info;
161
162 while ($path_info[0] and $path_info[0] =~ /^[a-zA-Z].*$/ and $path_info[0] !~ /(.*)\.(.*)/) { $path_info .= '/' . shift @path_info; }
163
164 # Flavour specified by ?flav={flav} or index.{flav}
165 $flavour = '';
166
167 if ( $path_info[$#path_info] =~ /(.+)\.(.+)$/ ) {
168   $flavour = $2;
169   $path_info .= "/$1.$2" if $1 ne 'index';
170   pop @path_info;
171 } else {
172   $flavour = param('flav') || $default_flavour;
173 }
174
175 # Strip spurious slashes
176 $path_info =~ s!(^/*)|(/*$)!!g;
177
178 # Date fiddling
179 ($path_info_yr,$path_info_mo,$path_info_da) = @path_info;
180 $path_info_mo_num = $path_info_mo ? ( $path_info_mo =~ /\d{2}/ ? $path_info_mo : ($month2num{ucfirst(lc $path_info_mo)} || undef) ) : undef;
181
182 # Define standard template subroutine, plugin-overridable at Plugins: Template
183 $template = 
184   sub {
185     my ($path, $chunk, $flavour) = @_;
186
187     do {
188       return join '', <$fh> if $fh->open("< $datadir/$path/$chunk.$flavour");
189     } while ($path =~ s/(\/*[^\/]*)$// and $1);
190
191     # Check for definedness, since flavour can be the empty string
192     if (defined $template{$flavour}{$chunk}) {
193         return $template{$flavour}{$chunk};
194     } elsif (defined $template{error}{$chunk}) {
195         return $template{error}{$chunk} 
196     } else {
197         return '';
198     }
199   };
200 # Bring in the templates
201 %template = ();
202 while (<DATA>) {
203   last if /^(__END__)$/;
204   my($ct, $comp, $txt) = /^(\S+)\s(\S+)(?:\s(.*))?$/ or next;
205   $txt =~ s/\\n/\n/mg;
206   $template{$ct}{$comp} .= $txt . "\n";
207 }
208
209 # Plugins: Start
210 my $path_sep = $^O eq 'MSWin32' ? ';' : ':';
211 my @plugin_dirs = split /$path_sep/, ($plugin_path || $plugin_dir);
212 my @plugin_list = ();
213 my %plugin_hash = ();
214
215 # If $plugin_list is set, read plugins to use from that file
216 $plugin_list = "$config_dir/$plugin_list"
217   if $plugin_list && $plugin_list !~ m!^\s*/!;
218 if ( $plugin_list and -r $plugin_list and $fh->open("< $plugin_list") ) {
219   @plugin_list = map { chomp $_; $_ } grep { /\S/ && ! /^#/ } <$fh>; 
220   $fh->close;
221 }
222 # Otherwise walk @plugin_dirs to get list of plugins to use
223 elsif ( @plugin_dirs ) {
224   for my $plugin_dir ( @plugin_dirs ) {
225     next unless -d $plugin_dir;
226     if ( opendir PLUGINS, $plugin_dir ) {
227       for my $plugin ( grep { /^[\w:]+$/ && ! /~$/ && -f "$plugin_dir/$_" } readdir(PLUGINS) ) {
228         # Ignore duplicates
229         next if $plugin_hash{ $plugin };
230         # Add to @plugin_list and %plugin_hash
231         $plugin_hash{ $plugin } = "$plugin_dir/$plugin";
232         push @plugin_list, $plugin;
233       }
234       closedir PLUGINS;
235     }
236   }
237   @plugin_list = sort @plugin_list;
238 }
239
240 # Load all plugins in @plugin_list
241 unshift @INC, @plugin_dirs;
242 foreach my $plugin ( @plugin_list ) {
243   my($plugin_name, $off) = $plugin =~ /^\d*([\w:]+?)(_?)$/;
244   my $on_off = $off eq '_' ? -1 : 1;
245   # Allow perl module plugins
246   if ($plugin =~ m/::/ && -z $plugin_hash{ $plugin }) {
247     # For Blosxom::Plugin::Foo style plugins, we need to use a string require
248     eval "require $plugin_name";
249   }
250   else {
251     eval { require $plugin };
252   }
253   $@ and warn "$@ error finding or loading blosxom plugin $plugin_name - skipping\n" and next;
254   $plugin_name->start() and ( $plugins{$plugin_name} = $on_off ) and push @plugins, $plugin_name;
255 }
256 shift @INC foreach @plugin_dirs;
257
258 # Plugins: Template
259 # Allow for the first encountered plugin::template subroutine to override the
260 # default built-in template subroutine
261 my $tmp; foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('template') and defined($tmp = $plugin->template()) and $template = $tmp and last; }
262
263 # Provide backward compatibility for Blosxom < 2.0rc1 plug-ins
264 sub load_template {
265   return &$template(@_);
266 }
267
268 # Define default entries subroutine
269 $entries =
270   sub {
271     my(%files, %indexes, %others);
272     find(
273       sub {
274         my $d; 
275         my $curr_depth = $File::Find::dir =~ tr[/][]; 
276         return if $depth and $curr_depth > $depth; 
277      
278         if ( 
279           # a match
280           $File::Find::name =~ m!^$datadir/(?:(.*)/)?(.+)\.$file_extension$!
281           # not an index, .file, and is readable
282           and $2 ne 'index' and $2 !~ /^\./ and (-r $File::Find::name)
283         ) {
284             # read modification time
285             my $mtime = stat($File::Find::name)->mtime or return;
286
287
288             # to show or not to show future entries
289             return unless ($show_future_entries or $mtime < time);
290
291               # add the file and its associated mtime to the list of files
292             $files{$File::Find::name} = $mtime;
293
294                 # static rendering bits
295             my $static_file = "$static_dir/$1/index." . $static_flavours[0];
296             if (param('-all')
297                 or !-f $static_file
298                 or stat($static_file)->mtime < $mtime)
299              {
300               $indexes{$1} = 1;
301               $d = join('/', (nice_date($mtime))[5,2,3]);
302               $indexes{$d} = $d;
303               $indexes{ ($1 ? "$1/" : '') . "$2.$file_extension" } = 1 if $static_entries;
304               }
305           }
306           # not an entries match
307           elsif (!-d $File::Find::name and -r $File::Find::name)
308           {
309             $others{$File::Find::name} = stat($File::Find::name)->mtime;
310           }
311       }, $datadir
312     );
313
314     return (\%files, \%indexes, \%others);
315   };
316
317 # Plugins: Entries
318 # Allow for the first encountered plugin::entries subroutine to override the
319 # default built-in entries subroutine
320 my $tmp; foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('entries') and defined($tmp = $plugin->entries()) and $entries = $tmp and last; }
321
322 my ($files, $indexes, $others) = &$entries();
323 %indexes = %$indexes;
324
325 # Static
326 if (!$ENV{GATEWAY_INTERFACE} and param('-password') and $static_password and param('-password') eq $static_password) {
327
328   param('-quiet') or print "Blosxom is generating static index pages...\n";
329
330   # Home Page and Directory Indexes
331   my %done;
332   foreach my $path ( sort keys %indexes) {
333     my $p = '';
334     foreach ( ('', split /\//, $path) ) {
335       $p .= "/$_";
336       $p =~ s!^/!!;
337       next if $done{$p}++;
338       mkdir "$static_dir/$p", 0755 unless (-d "$static_dir/$p" or $p =~ /\.$file_extension$/);
339       foreach $flavour ( @static_flavours ) {
340         my $content_type = (&$template($p,'content_type',$flavour));
341         $content_type =~ s!\n.*!!s;
342         my $fn = $p =~ m!^(.+)\.$file_extension$! ? $1 : "$p/index";
343         param('-quiet') or print "$fn.$flavour\n";
344         my $fh_w = new FileHandle "> $static_dir/$fn.$flavour" or die "Couldn't open $static_dir/$p for writing: $!";  
345         $output = '';
346         if ($indexes{$path} == 1) {
347           # category
348           $path_info = $p;
349           # individual story
350           $path_info =~ s!\.$file_extension$!\.$flavour!;
351           print $fh_w &generate('static', $path_info, '', $flavour, $content_type);
352         } else {
353           # date
354           local ($path_info_yr,$path_info_mo,$path_info_da, $path_info) = 
355               split /\//, $p, 4;
356           unless (defined $path_info) {$path_info = ""};
357           print $fh_w &generate('static', '', $p, $flavour, $content_type);
358         }
359         $fh_w->close;
360       }
361     }
362   }
363 }
364
365 # Dynamic
366 else {
367   my $content_type = (&$template($path_info,'content_type',$flavour));
368   $content_type =~ s!\n.*!!s;
369
370   $content_type =~ s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
371   $header = {-type=>$content_type};
372
373   print generate('dynamic', $path_info, "$path_info_yr/$path_info_mo_num/$path_info_da", $flavour, $content_type);
374 }
375
376 # Plugins: End
377 foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('end') and $entries = $plugin->end() }
378
379 # Generate 
380 sub generate {
381   my($static_or_dynamic, $currentdir, $date, $flavour, $content_type) = @_;
382
383   %files = %$files; %others = ref $others ? %$others : ();
384
385   # Plugins: Filter
386   foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('filter') and $entries = $plugin->filter(\%files, \%others) }
387
388   my %f = %files;
389
390   # Plugins: Skip
391   # Allow plugins to decide if we can cut short story generation
392   my $skip;
393   foreach my $plugin (@plugins) {
394       if ( $plugins{$plugin} > 0 and $plugin->can('skip') ) {
395           if ( my $tmp = $plugin->skip() ) {
396               $skip = $tmp;
397               last;
398           }
399       }
400   }
401
402   
403   # Define default interpolation subroutine
404   $interpolate = 
405     sub {
406       package blosxom;
407       my $template = shift;
408       $template =~ 
409         s/(\$\w+(?:::)?\w*)/"defined $1 ? $1 : ''"/gee;
410       return $template;
411     };  
412
413   unless (defined($skip) and $skip) {
414
415     # Plugins: Interpolate
416     # Allow for the first encountered plugin::interpolate subroutine to 
417     # override the default built-in interpolate subroutine
418     foreach my $plugin (@plugins) {
419         if ( $plugins{$plugin} > 0 and $plugin->can('interpolate') ) {
420             if ( my $tmp = $plugin->interpolate() ) {
421                 $interpolate = $tmp;
422                 last;
423             }
424         }
425     }
426         
427     # Head
428     my $head = (&$template($currentdir,'head',$flavour));
429   
430     # Plugins: Head
431     foreach my $plugin (@plugins) {
432         if ( $plugins{$plugin} > 0 and $plugin->can('head') ) {
433             $entries = $plugin->head( $currentdir, \$head );
434         }
435     }
436   
437     $head = &$interpolate($head);
438   
439     $output .= $head;
440     
441     # Stories
442     my $curdate = '';
443     my $ne = $num_entries;
444
445     if ( $currentdir =~ /(.*?)([^\/]+)\.(.+)$/ and $2 ne 'index' ) {
446       $currentdir = "$1$2.$file_extension";
447       $files{"$datadir/$1$2.$file_extension"} and %f = ( "$datadir/$1$2.$file_extension" => $files{"$datadir/$1$2.$file_extension"} );
448     } 
449     else { 
450       $currentdir =~ s!/index\..+$!!;
451     }
452
453     # Define a default sort subroutine
454     my $sort = sub {
455       my($files_ref) = @_;
456       return sort { $files_ref->{$b} <=> $files_ref->{$a} } keys %$files_ref;
457     };
458   
459     # Plugins: Sort
460     # Allow for the first encountered plugin::sort subroutine to override the
461     # default built-in sort subroutine
462     foreach my $plugin (@plugins) {
463         if ( $plugins{$plugin} > 0 and $plugin->can('sort') ) {
464             if ( my $tmp = $plugin->sort() ) {
465                 $sort = $tmp;
466                 last;
467             }
468         }
469     }
470   
471     foreach my $path_file ( &$sort(\%f, \%others) ) {
472       last if $ne <= 0 && $date !~ /\d/;
473       use vars qw/ $path $fn /;
474       ($path,$fn) = $path_file =~ m!^$datadir/(?:(.*)/)?(.*)\.$file_extension!;
475   
476       # Only stories in the right hierarchy
477       $path =~ /^$currentdir/ or $path_file eq "$datadir/$currentdir" or next;
478   
479       # Prepend a slash for use in templates only if a path exists
480       $path &&= "/$path";
481
482       # Date fiddling for by-{year,month,day} archive views
483       use vars qw/ $dw $mo $mo_num $da $ti $yr $hr $min $hr12 $ampm $utc_offset/;
484       ($dw,$mo,$mo_num,$da,$ti,$yr,$utc_offset) = nice_date($files{"$path_file"});
485       ($hr,$min) = split /:/, $ti;
486       ($hr12, $ampm) = $hr >= 12 ? ($hr - 12,'pm') : ($hr, 'am'); 
487       $hr12 =~ s/^0//; $hr12 == 0 and $hr12 = 12;
488   
489       # Only stories from the right date
490       my($path_info_yr,$path_info_mo_num, $path_info_da) = split /\//, $date;
491       next if $path_info_yr && $yr != $path_info_yr; last if $path_info_yr && $yr < $path_info_yr; 
492       next if $path_info_mo_num && $mo ne $num2month[$path_info_mo_num];
493       next if $path_info_da && $da != $path_info_da; last if $path_info_da && $da < $path_info_da; 
494   
495       # Date 
496       my $date = (&$template($path,'date',$flavour));
497       
498       # Plugins: Date
499       foreach my $plugin ( @plugins ) { $plugins{$plugin} > 0 and $plugin->can('date') and $entries = $plugin->date($currentdir, \$date, $files{$path_file}, $dw,$mo,$mo_num,$da,$ti,$yr) }
500   
501       $date = &$interpolate($date);
502   
503       $curdate ne $date and $curdate = $date and $output .= $date;
504       
505       use vars qw/ $title $body $raw /;
506       if (-f "$path_file" && $fh->open("< $path_file")) {
507         chomp($title = <$fh>);
508         chomp($body = join '', <$fh>);
509         $fh->close;
510         $raw = "$title\n$body";
511       }
512       my $story = (&$template($path,'story',$flavour));
513   
514       # Plugins: Story
515       foreach my $plugin (@plugins) {
516           if ( $plugins{$plugin} > 0 and $plugin->can('story') ) {
517               $entries = $plugin->story( $path, $fn, \$story, \$title, \$body );
518           }
519       }
520       
521       if ($content_type =~ m{\bxml\b}) {
522         # Escape <, >, and &, and to produce valid RSS
523         my %escape = ('<'=>'&lt;', '>'=>'&gt;', '&'=>'&amp;', '"'=>'&quot;');  
524         my $escape_re  = join '|' => keys %escape;
525         $title =~ s/($escape_re)/$escape{$1}/g;
526         $body =~ s/($escape_re)/$escape{$1}/g;
527       }
528   
529       $story = &$interpolate($story);
530     
531       $output .= $story;
532       $fh->close;
533   
534       $ne--;
535     }
536   
537     # Foot
538     my $foot = (&$template($currentdir,'foot',$flavour));
539   
540     # Plugins: Foot
541     foreach my $plugin (@plugins) {
542         if ( $plugins{$plugin} > 0 and $plugin->can('foot') ) {
543             $entries = $plugin->foot( $currentdir, \$foot );
544         }
545     }
546   
547     $foot = &$interpolate($foot);
548     $output .= $foot;
549
550     # Plugins: Last
551     foreach my $plugin (@plugins) {
552         if ( $plugins{$plugin} > 0 and $plugin->can('last') ) {
553             $entries = $plugin->last();
554         }
555     }
556
557   } # End skip
558
559   # Finally, add the header, if any and running dynamically
560   $output = header($header) . $output if ($static_or_dynamic eq 'dynamic' and $header);
561   
562   $output;
563 }
564
565
566 sub nice_date {
567   my($unixtime) = @_;
568   
569   my $c_time = ctime($unixtime);
570   my($dw,$mo,$da,$hr,$min,$yr) = ( $c_time =~ /(\w{3}) +(\w{3}) +(\d{1,2}) +(\d{2}):(\d{2}):\d{2} +(\d{4})$/ );
571   $ti="$hr:$min";
572   $da = sprintf("%02d", $da);
573   my $mo_num = $month2num{$mo};
574
575   my $offset = timegm(00, $min, $hr, $da, $mo_num-1, $yr-1900)-$unixtime;  
576   my $utc_offset = sprintf("%+03d", int($offset / 3600)).sprintf("%02d", ($offset % 3600)/60) ;
577
578   return ($dw,$mo,$mo_num,$da,$ti,$yr,$utc_offset);
579 }
580
581
582 # Default HTML and RSS template bits
583 __DATA__
584 html content_type text/html; charset=$blog_encoding
585
586 html head <html>
587 html head     <head>
588 html head         <meta http-equiv="content-type" content="text/html;charset=$blog_encoding" />
589 html head         <link rel="alternate" type="type="application/rss+xml" title="RSS" href="$url/index.rss" />
590 html head         <title>$blog_title $path_info_da $path_info_mo $path_info_yr
591 html head         </title>
592 html head     </head>
593 html head     <body>
594 html head         <center>
595 html head             <font size="+3">$blog_title</font><br />
596 html head             $path_info_da $path_info_mo $path_info_yr
597 html head         </center>
598 html head         <p />
599
600 html story        <p>
601 html story            <a name="$fn"><b>$title</b></a><br />
602 html story            $body<br />
603 html story            <br />
604 html story            posted at: $ti | path: <a href="$url$path">$path </a> | <a href="$url/$yr/$mo_num/$da#$fn">permanent link to this entry</a>
605 html story        </p>
606
607 html date         <h3>$dw, $da $mo $yr</h3>
608
609 html foot
610 html foot         <p />
611 html foot         <center>
612 html foot             <a href="http://blosxom.sourceforge.net/"><img src="http://blosxom.sourceforge.net/images/pb_blosxom.gif" border="0" /></a>
613 html foot         </center>
614 html foot     </body>
615 html foot </html>
616
617 rss content_type text/xml; charset=$blog_encoding
618
619 rss head <?xml version="1.0" encoding="$blog_encoding"?>
620 rss head <rss version="2.0">
621 rss head   <channel>
622 rss head     <title>$blog_title</title>
623 rss head     <link>$url/$path_info</link>
624 rss head     <description>$blog_description</description>
625 rss head     <language>$blog_language</language>
626 rss head     <docs>http://blogs.law.harvard.edu/tech/rss</docs>
627 rss head     <generator>blosxom/$version</generator>
628
629 rss story   <item>
630 rss story     <title>$title</title>
631 rss story     <pubDate>$dw, $da $mo $yr $ti:00 $utc_offset</pubDate>
632 rss story     <link>$url/$yr/$mo_num/$da#$fn</link>
633 rss story     <category>$path</category>
634 rss story     <guid isPermaLink="false">$path/$fn</guid>
635 rss story     <description>$body</description>
636 rss story   </item>
637
638 rss date 
639
640 rss foot   </channel>
641 rss foot </rss>
642
643 error content_type text/html
644
645 error head <html>
646 error head <body>
647 error head     <p><font color="red">Error: I'm afraid this is the first I've heard of a "$flavour" flavoured Blosxom.  Try dropping the "/+$flavour" bit from the end of the URL.</font></p>
648
649
650 error story <p><b>$title</b><br />
651 error story $body <a href="$url/$yr/$mo_num/$da#fn.$default_flavour">#</a></p>
652
653 error date <h3>$dw, $da $mo $yr</h3>
654
655 error foot     </body>
656 error foot </html>
657 __END__