lib/Packages/Template.pm

   1 package Packages::Template;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Template;
   7 use URI ();
   8 use HTML::Entities ();
   9 use URI::Escape ();
  10 use Benchmark ':hireswallclock';
  11
  12 use Packages::CGI;
  13 use Packages::Config qw( @LANGUAGES );
  14 use Packages::I18N::Locale;
  15 use Packages::I18N::Languages;
  16 use Packages::I18N::LanguageNames;
  17
  18 our @ISA = qw( Exporter );
  19 #our @EXPORT = qw( head );
  20
  21 use constant COMPILE => 1;
  22
  23 sub new {
  24     my ($classname, $include, $format, $vars, $options) = @_;
  25     $vars ||= {};
  26     $options ||= {};
  27
  28     my $self = {};
  29     bless( $self, $classname );
  30
  31     my @timestamp = gmtime;
  32     $vars->{timestamp} = {
  33         year => $timestamp[5]+1900,
  34         string => scalar gmtime() .' UTC',
  35     };
  36     $vars->{make_search_url} = sub { return &Packages::CGI::make_search_url(@_) };
  37     $vars->{make_url} = sub { return &Packages::CGI::make_url(@_) };
  38     if ($vars->{cat}) {
  39         $vars->{g} = sub { return Packages::I18N::Locale::g($vars->{cat}, @_) };
  40     }
  41     $vars->{extract_host} = sub { my $uri = URI->new($_[0]);
  42                                   my $host = $uri->host;
  43                                   $host .= ':'.$uri->port if $uri->port != $uri->default_port;
  44                                   return $host;
  45                               };
  46     # needed to work around the limitations of the the FILTER syntax
  47     $vars->{html_encode} = sub { return HTML::Entities::encode_entities(@_,'<>&"') };
  48     $vars->{uri_escape} = sub { return URI::Escape::uri_escape(@_) };
  49     $vars->{quotemeta} = sub { return quotemeta($_[0]) };
  50     $vars->{string2id} = sub { return &Packages::CGI::string2id(@_) };
  51
  52     $self->{template} = Template->new( {
  53         PRE_PROCESS => [ 'config.tmpl' ],
  54         INCLUDE_PATH => $include,
  55         VARIABLES => $vars,
  56         COMPILE_EXT => '.ttc',
  57         %$options,
  58     } ) or die sprintf( "Initialization of Template Engine failed: %s", $Template::ERROR );
  59     $self->{format} = $format;
  60     $self->{vars} = $vars;
  61
  62     return $self;
  63 }
  64
  65 sub process {
  66     my $self = shift;
  67     return $self->{template}->process(@_);
  68 }
  69 sub error {
  70     my $self = shift;
  71     return $self->{template}->error(@_);
  72 }
  73
  74 sub page {
  75     my ($self, $action, $page_content, $target) = @_;
  76
  77     #use Data::Dumper;
  78     #die Dumper($self, $action, $page_content);
  79     if ($page_content->{cat}) {
  80         $page_content->{g} =
  81             sub { return Packages::I18N::Locale::g($page_content->{cat}, @_) };
  82     }
  83     $page_content->{used_langs} ||= \@LANGUAGES;
  84     $page_content->{langs} = languages( $page_content->{lang}
  85                                         || $self->{vars}{lang} || 'en',
  86                                         @{$page_content->{used_langs}} );
  87
  88     my $txt;
  89     if ($target) {
  90         $self->process("$self->{format}/$action.tmpl", $page_content, $target)
  91             or die sprintf( "template error: %s", $self->error ); # too late for reporting on-line
  92     } else {
  93         $self->process("$self->{format}/$action.tmpl", $page_content, \$txt)
  94             or die sprintf( "template error: %s", $self->error );
  95     }
  96     return $txt;
  97 }
  98
  99 sub error_page {
 100     my ($self, $page_content) = @_;
 101
 102 #    use Data::Dumper;
 103 #    warn Dumper($page_content);
 104
 105     my $txt;
 106     $self->process("html/error.tmpl", $page_content, \$txt)
 107         or die sprintf( "template error: %s", $self->error ); # too late for reporting on-line
 108
 109     return $txt;
 110 }
 111
 112 sub languages {
 113     my ( $lang, @used_langs ) = @_;
 114     my $cat = Packages::I18N::Locale->get_handle($lang)
 115         || Packages::I18N::Locale->get_handle('en');
 116
 117     my @langs;
 118
 119     if (@used_langs) {
 120
 121         my @printed_langs = ();
 122         foreach (@used_langs) {
 123             next if $_ eq $lang; # Never print the current language
 124             unless (get_selfname($_)) { warn "missing language $_"; next } #DEBUG
 125             push @printed_langs, $_;
 126         }
 127         return [] unless scalar @printed_langs;
 128         # Sort on uppercase to work with languages which use lowercase initial
 129         # letters.
 130         foreach my $cur_lang (sort langcmp @printed_langs) {
 131             my %lang;
 132             $lang{lang} = $cur_lang;
 133             $lang{tooltip} = $cat->g(get_language_name($cur_lang));
 134             $lang{selfname} = get_selfname($cur_lang);
 135             $lang{transliteration} = get_transliteration($cur_lang)
 136                 if defined get_transliteration($cur_lang);
 137             push @langs, \%lang;
 138         }
 139     }
 140
 141     return \@langs;
 142 }
 143
 144 1;