lib/Packages/Search.pm

   1 #
   2 # Packages::Search
   3 #
   4 # Copyright (C) 2004-2006 Frank Lichtenheld <frank@lichtenheld.de>
   5 #
   6 # The code is based on the old search_packages.pl script that
   7 # was:
   8 #
   9 # Copyright (C) 1998 James Treacy
  10 # Copyright (C) 2000, 2001 Josip Rodin
  11 # Copyright (C) 2001 Adam Heath
  12 # Copyright (C) 2004 Martin Schulze
  13 #
  14 #    This program is free software; you can redistribute it and/or modify
  15 #    it under the terms of the GNU General Public License as published by
  16 #    the Free Software Foundation; either version 1 of the License, or
  17 #    (at your option) any later version.
  18 #
  19 #    This program is distributed in the hope that it will be useful,
  20 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 #    GNU General Public License for more details.
  23 #
  24 #    You should have received a copy of the GNU General Public License
  25 #    along with this program; if not, write to the Free Software
  26 #    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  27 #
  28
  29 =head1 NAME
  30
  31 Packages::Search -
  32
  33 =head1 SYNOPSIS
  34
  35 =head1 DESCRIPTION
  36
  37 =over 4
  38
  39 =cut
  40
  41 package Packages::Search;
  42
  43 use strict;
  44 use warnings;
  45
  46 use POSIX;
  47 use HTML::Entities;
  48 use DB_File;
  49 use Lingua::Stem v0.82;
  50 use Search::Xapian qw(:ops);
  51
  52 use Deb::Versions;
  53 use Packages::CGI;
  54 use Exporter;
  55
  56 our @ISA = qw( Exporter );
  57
  58 our @EXPORT_OK = qw( read_entry read_entry_all read_entry_simple
  59                      read_src_entry read_src_entry_all find_binaries
  60                      do_names_search do_fulltext_search do_xapian_search
  61                      find_similar
  62                      );
  63 our %EXPORT_TAGS = ( all => [ @EXPORT_OK ] );
  64
  65 our $VERSION = 0.01;
  66
  67 our $too_many_hits = 0;
  68
  69 sub read_entry_all {
  70     my ($hash, $key, $results, $non_results, $opts) = @_;
  71     my ($virt, $result) = split /\000/o, $hash->{$key} || "-\01-", 2;
  72
  73     my %virt = split /\01/o, $virt;
  74     while (my ($suite, $provides) = each %virt) {
  75         next if $suite eq '-';
  76         if ($opts->{h_suites}{$suite}) {
  77             push @$results, [ $key, "-", $suite, 'virtual', 'v', 'v', 'v', 'v',
  78                               $provides];
  79         } else {
  80             push @$non_results, [ $key, "-", $suite, 'virtual', 'v', 'v', 'v', 'v',
  81                                   $provides];
  82         }
  83     }
  84
  85     foreach (split /\000/o, $result) {
  86         my @data = split ( /\s/o, $_, 8 );
  87         debug( "Considering entry ".join( ':', @data), 2) if DEBUG;
  88         if ($opts->{h_suites}{$data[1]}
  89             && ($opts->{h_archs}{$data[2]} || $data[2] eq 'all')
  90             && $opts->{h_sections}{$data[3]}) {
  91             debug( "Using entry ".join( ':', @data), 2) if DEBUG;
  92             push @$results, [ $key, @data ];
  93         } else {
  94             push @$non_results, [ $key, @data ];
  95         }
  96     }
  97 }
  98 sub read_entry {
  99     my ($hash, $key, $results, $opts) = @_;
 100     my @non_results;
 101     read_entry_all( $hash, $key, $results, \@non_results, $opts );
 102 }
 103
 104 #FIXME: make configurable
 105 my %fallback_suites = (
 106                        'oldstable-backports' => 'oldstable',
 107                        'oldstable-volatile' => 'oldstable',
 108                        'stable-backports' => 'stable',
 109                        'stable-volatile' => 'stable',
 110                        experimental => 'unstable' );
 111
 112 sub read_entry_simple {
 113     my ($hash, $key, $archives, $suite) = @_;
 114     # FIXME: drop $archives
 115
 116     my ($virt, $result) = split /\000/o, $hash->{$key} || "-\01-\0", 2;
 117     my %virt = split /\01/o, $virt;
 118     debug( "read_entry_simple: key=$key, archives=".
 119            join(" ",(keys %$archives)).", suite=$suite", 1) if DEBUG;
 120     debug( "read_entry_simple: virt=".join(" ",(%virt)), 2) if DEBUG;
 121     # FIXME: not all of the 2^4=16 combinations of empty(results),
 122     # empty(virt{suite}), empty(fb_result), empty(virt{fb_suite}) are dealt
 123     # with correctly, but it's adequate enough for now
 124     return [ $virt{$suite} ] unless defined $result;
 125     foreach (split /\000/o, $result) {
 126         my @data = split ( /\s/o, $_, 8 );
 127         debug( "use entry: @data", 2 ) if DEBUG && $data[1] eq $suite;
 128         return [ $virt{$suite}, @data ] if $data[1] eq $suite;
 129     }
 130     if (my $fb_suite = $fallback_suites{$suite}) {
 131         my $fb_result = read_entry_simple( $hash, $key, $archives, $fb_suite );
 132         my $fb_virt = shift(@$fb_result);
 133         $virt{$suite} .= $virt{$suite} ? " $fb_virt" : $fb_virt if $fb_virt;
 134         return [ $virt{$suite}, @$fb_result ] if @$fb_result;
 135     }
 136     return [ $virt{$suite} ];
 137 }
 138
 139 sub read_src_entry_all {
 140     my ($hash, $key, $results, $non_results, $opts) = @_;
 141     my $result = $hash->{$key} || '';
 142     debug( "read_src_entry_all: key=$key", 1) if DEBUG;
 143     foreach (split /\000/o, $result) {
 144         my @data = split ( /\s/o, $_, 6 );
 145         debug( "Considering entry ".join( ':', @data), 2) if DEBUG;
 146         if ($opts->{h_archives}{$data[0]}
 147             && $opts->{h_suites}{$data[1]}
 148             && $opts->{h_sections}{$data[2]}) {
 149             debug( "Using entry ".join( ':', @data), 2) if DEBUG;
 150             push @$results, [ $key, @data ];
 151         } else {
 152             push @$non_results, [ $key, @data ];
 153         }
 154     }
 155 }
 156 sub read_src_entry {
 157     my ($hash, $key, $results, $opts) = @_;
 158     my @non_results;
 159     read_src_entry_all( $hash, $key, $results, \@non_results, $opts );
 160 }
 161 sub do_names_search {
 162     my ($keywords, $packages, $postfixes, $read_entry, $opts,
 163         $results, $non_results) = @_;
 164
 165     my $first_keyword = lc shift @$keywords;
 166     @$keywords = map { lc $_ } @$keywords;
 167
 168     my ($key, $prefixes) = ($first_keyword, '');
 169     my %pkgs;
 170     $postfixes->seq( $key, $prefixes, R_CURSOR );
 171     while (index($key, $first_keyword) >= 0) {
 172         if ($prefixes =~ /^\001(\d+)/o) {
 173             debug( "$key has too many hits", 2 ) if DEBUG;
 174             $too_many_hits += $1;
 175         } else {
 176           PREFIX:
 177             foreach (split /\000/o, $prefixes) {
 178                 $_ = '' if $_ eq '^';
 179                 my $word = "$_$key";
 180                 foreach my $k (@$keywords) {
 181                     next PREFIX unless $word =~ /\Q$k\E/;
 182                 }
 183                 debug( "add word $word", 2) if DEBUG;
 184                 $pkgs{$word}++;
 185             }
 186         }
 187         last if $postfixes->seq( $key, $prefixes, R_NEXT ) != 0;
 188         last if $too_many_hits or keys %pkgs >= 100;
 189     }
 190
 191     my $no_results = keys %pkgs;
 192     if ($too_many_hits || ($no_results >= 100)) {
 193         $too_many_hits += $no_results;
 194         %pkgs = ( $first_keyword => 1 ) unless @$keywords;
 195     }
 196     foreach my $pkg (sort keys %pkgs) {
 197         &$read_entry( $packages, $pkg, $results, $non_results, $opts );
 198     }
 199 }
 200
 201 sub do_xapian_search {
 202     my ($keywords, $db, $did2pkg, $packages, $read_entry, $opts,
 203         $results, $non_results) = @_;
 204
 205 # NOTE: this needs to correspond with parse-packages!
 206     my @tmp;
 207     foreach my $keyword (@$keywords) {
 208         $keyword =~ s;[^\w/+]+; ;og;
 209         push @tmp, $keyword;
 210     }
 211     my $stemmer = Lingua::Stem->new();
 212     my $stemmed_keywords = $stemmer->stem( @tmp );
 213
 214     my $db = Search::Xapian::Database->new( $db );
 215     my $enq = $db->enquire( OP_OR, @$keywords, @$stemmed_keywords );
 216     debug( "Xapian Query was: ".$enq->get_query()->get_description(), 1) if DEBUG;
 217     my @matches = $enq->matches(0, 999);
 218
 219     my (@order, %tmp_results);
 220     foreach my $match ( @matches ) {
 221         my $id = $match->get_docid();
 222         my $result = $did2pkg->{$id};
 223
 224         foreach (split /\000/o, $result) {
 225             my @data = split /\s/, $_, 3;
 226             debug ("Considering $data[0], arch = $data[2], relevance=".$match->get_percent(), 3) if DEBUG;
 227 #           next unless $data[2] eq 'all' || $opts->{h_archs}{$data[2]};
 228 #           debug ("Ok", 3) if DEBUG;
 229             unless ($tmp_results{$data[0]}++) {
 230                 push @order, $data[0];
 231             }
 232         }
 233         last if @order > 100;
 234     }
 235     undef $db;
 236     $too_many_hits++ if @order > 100;
 237
 238     debug ("ORDER: @order", 2) if DEBUG;
 239     foreach my $pkg (@order) {
 240         &$read_entry( $packages, $pkg, $results, $non_results, $opts );
 241     }
 242 }
 243
 244 sub find_similar {
 245     my ($pkg, $db, $did2pkg) = @_;
 246
 247     my $db = Search::Xapian::Database->new( $db );
 248     my $enq = $db->enquire( "P$pkg" );
 249     debug( "Xapian Query was: ".$enq->get_query()->get_description(), 1) if DEBUG;
 250     my $first_match = ($enq->matches(0,1))[0]->get_document();
 251
 252     my @terms;
 253     my $term_it = $first_match->termlist_begin();
 254     my $term_end = $first_match->termlist_end();
 255
 256     for ($term_it; $term_it ne $term_end; $term_it++) {
 257         debug( "TERM: ".$term_it->get_termname(), 3);
 258         push @terms, $term_it->get_termname();
 259     }
 260
 261     my $rel_enq = $db->enquire( OP_OR, @terms );
 262     debug( "Xapian Query was: ".$rel_enq->get_query()->get_description(), 1) if DEBUG;
 263     my @rel_pkg = $rel_enq->matches(2,20);
 264
 265     use Data::Dumper;
 266     debug(Dumper(\@rel_pkg),1);
 267
 268     my (@order, %tmp_results);
 269     foreach my $match ( @rel_pkg ) {
 270         my $id = $match->get_docid();
 271         my $result = $did2pkg->{$id};
 272
 273         foreach (split /\000/o, $result) {
 274             my @data = split /\s/, $_, 3;
 275             debug ("Considering $data[0], arch = $data[2], relevance=".$match->get_percent(), 3) if DEBUG;
 276             next if $data[0] eq $pkg;
 277             unless ($tmp_results{$data[0]}++) {
 278                 push @order, $data[0];
 279             }
 280         }
 281     }
 282     undef $db;
 283
 284     debug ("ORDER: @order", 2) if DEBUG;
 285     return @order[0..10];
 286 }
 287
 288 sub find_binaries {
 289     my ($pkg, $archive, $suite, $src2bin) = @_;
 290
 291     my $bins = $src2bin->{$pkg} || '';
 292     my %bins;
 293     foreach (split /\000/o, $bins) {
 294         my @data = split /\s/, $_, 5;
 295
 296         debug( "find_binaries: considering @data", 3 ) if DEBUG;
 297         if (($data[0] eq $archive)
 298             && ($data[1] eq $suite)) {
 299             $bins{$data[2]}++;
 300             debug( "find_binaries: using @data", 3 ) if DEBUG;
 301         }
 302     }
 303
 304     return [ keys %bins ];
 305 }
 306
 307
 308 1;