lib/Packages/DoSearchContents.pm

   1 package Packages::DoSearchContents;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Benchmark ':hireswallclock';
   7 use DB_File;
   8 use Exporter;
   9 our @ISA = qw( Exporter );
  10 our @EXPORT = qw( do_search_contents );
  11
  12 use Deb::Versions;
  13 use Packages::I18N::Locale;
  14 use Packages::Search qw( :all );
  15 use Packages::CGI qw( :DEFAULT error );
  16 use Packages::DB;
  17 use Packages::Config qw( $DBDIR @SUITES @ARCHIVES @ARCHITECTURES $ROOT );
  18
  19 sub do_search_contents {
  20     my ($params, $opts, $page_content) = @_;
  21
  22     if ($params->{errors}{keywords}) {
  23         fatal_error( _g( "keyword not valid or missing" ) );
  24         $opts->{keywords} = [];
  25     } elsif (grep { length($_) < 2 } @{$opts->{keywords}}) {
  26         fatal_error( _g( "keyword too short (keywords need to have at least two characters)" ) );
  27     }
  28     if ($params->{errors}{suite}) {
  29         fatal_error( _g( "suite not valid or not specified" ) );
  30     }
  31
  32     #FIXME: that's extremely hacky atm
  33     if ($params->{values}{suite}{no_replace}[0] eq 'default') {
  34         $params->{values}{suite}{no_replace} =
  35             $params->{values}{suite}{final} = $opts->{suite} = [ 'etch' ];
  36     }
  37
  38     if (@{$opts->{suite}} > 1) {
  39         fatal_error( sprintf( _g( "more than one suite specified for contents search (%s)" ), "@{$opts->{suite}}" ) );
  40     }
  41
  42     my @keywords = @{$opts->{keywords}};
  43     my $mode = $opts->{mode} || '';
  44     my $suite = $opts->{suite}[0];
  45     my $archive = $opts->{archive}[0] ||'';
  46     $Packages::Search::too_many_hits = 0;
  47
  48     my $st0 = new Benchmark;
  49     my (@results);
  50
  51     unless (@Packages::CGI::fatal_errors) {
  52
  53         my $nres = 0;
  54
  55         my $first_kw = lc shift @keywords;
  56         # full filename search is tricky
  57         my $ffn = $mode eq 'filename';
  58
  59         my $reverses = tie my %reverses, 'DB_File', "$DBDIR/contents/reverse_$suite.db",
  60             O_RDONLY, 0666, $DB_BTREE
  61             or die "Failed opening reverse DB: $!";
  62
  63         if ($ffn) {
  64             open FILENAMES, '-|', 'fgrep', '--', $first_kw, "$DBDIR/contents/filenames_$suite.txt"
  65                 or die "Failed opening filename table: $!";
  66
  67           FILENAME:
  68             while (<FILENAMES>) {
  69                 chomp;
  70                 foreach my $kw (@keywords) {
  71                     next FILENAME unless /\Q$kw\E/;
  72                 }
  73                 &searchfile(\@results, reverse($_)."/", \$nres, $reverses);
  74                 last if $Packages::Search::too_many_hits;
  75             }
  76             while (<FILENAMES>) {};
  77             close FILENAMES or warn "fgrep error: $!\n";
  78         } else {
  79
  80             error(_g("The search mode you selected doesn't support more than one keyword."))
  81                 if @keywords;
  82
  83             my $kw = reverse $first_kw;
  84             $kw =~ s{/+$}{};
  85
  86             # exact filename searching follows trivially:
  87             $kw = "$kw/" if $mode eq 'exactfilename';
  88
  89             &searchfile(\@results, $kw, \$nres, $reverses);
  90         }
  91         $reverses = undef;
  92         untie %reverses;
  93
  94
  95         my $st1 = new Benchmark;
  96         my $std = timediff($st1, $st0);
  97         debug( "Search took ".timestr($std) ) if DEBUG;
  98     }
  99
 100     my (%results,%archs);
 101     foreach my $result (sort { $a->[0] cmp $b->[0] } @results) {
 102         my $file = shift @$result;
 103         my %pkgs;
 104         foreach (@$result) {
 105             my ($pkg, $arch) = split /:/, $_;
 106             next unless $opts->{h_archs}{$arch};
 107             $pkgs{$pkg}{$arch}++;
 108             $archs{$arch}++ unless $arch eq 'all';
 109         }
 110         next unless keys %pkgs;
 111         $results{$file} = \%pkgs;
 112     }
 113     my @all_archs = sort keys %archs;
 114     @all_archs = sort @ARCHITECTURES unless @all_archs;
 115     $page_content->{suite} = $suite;
 116     $page_content->{archive} = $archive;
 117     $page_content->{all_architectures} = \@all_archs;
 118     $page_content->{all_suites} = \@SUITES;
 119     $page_content->{mode} = $mode;
 120     $page_content->{search_architectures} = $opts->{arch};
 121     $page_content->{search_keywords} = $opts->{keywords};
 122     $page_content->{sections} = $opts->{section};
 123     $page_content->{too_many_hits} = $Packages::Search::too_many_hits;
 124
 125     debug( "all_archs = @all_archs", 1 ) if DEBUG;
 126
 127     if (keys %results) {
 128         my $sort_func = sub { $_[0] cmp $_[1] };
 129         $sort_func = sub { (sort keys %{$results{$_[0]}})[0]
 130                            cmp
 131                            (sort keys %{$results{$_[1]}})[0]
 132                          } if $opts->{sort_by} eq 'pkg';
 133
 134         $page_content->{results} = [];
 135         foreach my $file (sort {&$sort_func($a,$b)} keys %results) {
 136             my %result;
 137             $result{file} = "/$file";
 138             $result{packages} = [];
 139             foreach my $pkg (sort keys %{$results{$file}}) {
 140                 my $arch_str = '';
 141                 my @archs = keys %{$results{$file}{$pkg}};
 142                 my $arch_neg = 0;
 143                 unless ($results{$file}{$pkg}{all} ||
 144                         (@archs == @all_archs)) {
 145                     if (@archs >= @all_archs/2) {
 146                         @archs = grep { !$results{$file}{$pkg}{$_} } @all_archs;
 147                         $arch_neg = 1;
 148                     }
 149                 } else {
 150                     @archs = ();
 151                 }
 152                 push @{$result{packages}}, { pkg => $pkg, architectures => \@archs, architectures_are_rev => $arch_neg };
 153             }
 154             push @{$page_content->{results}}, \%result;
 155         }
 156     }
 157 } # sub do_search_contents
 158
 159 sub searchfile
 160 {
 161     my ($results, $kw, $nres, $reverses) = @_;
 162
 163     my ($key, $value) = ($kw, "");
 164     debug( "searchfile: kw=$kw", 1 ) if DEBUG;
 165     for (my $status = $reverses->seq($key, $value, R_CURSOR);
 166         $status == 0;
 167         $status =  $reverses->seq( $key, $value, R_NEXT)) {
 168
 169         # FIXME: what's the most efficient "is prefix of" thingy? We only want to know
 170         # whether $kw is or is not a prefix of $key
 171         last unless index($key, $kw) == 0;
 172         debug( "found $key", 2 ) if DEBUG;
 173
 174         my @files = split /\001/o, $value;
 175         foreach my $f (@files) {
 176             my @hits = split /\0/o, $f;
 177             my $file = shift @hits;
 178             if ($file eq '-') {
 179                 $file = reverse($key);
 180             }
 181             push @$results, [ $file, @hits ];
 182         }
 183         last if ($$nres)++ > 100;
 184     }
 185
 186     $Packages::Search::too_many_hits += $$nres - 100 if $$nres > 100;
 187 }
 188
 189
 190 1;