lib/Packages/DoSearchContents.pm

   1 package Packages::DoSearchContents;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Benchmark ':hireswallclock';
   7 use DB_File;
   8 use URI::Escape;
   9 use HTML::Entities;
  10 use Exporter;
  11 our @ISA = qw( Exporter );
  12 our @EXPORT = qw( do_search_contents );
  13
  14 use Deb::Versions;
  15 use Packages::I18N::Locale;
  16 use Packages::Search qw( :all );
  17 use Packages::CGI;
  18 use Packages::DB;
  19 use Packages::Config qw( $DBDIR @SUITES @ARCHIVES @ARCHITECTURES $ROOT );
  20
  21 sub do_search_contents {
  22     my ($params, $opts, $page_content) = @_;
  23
  24     if ($params->{errors}{keywords}) {
  25         fatal_error( _g( "keyword not valid or missing" ) );
  26         $opts->{keywords} = [];
  27     } elsif (grep { length($_) < 2 } @{$opts->{keywords}}) {
  28         fatal_error( _g( "keyword too short (keywords need to have at least two characters)" ) );
  29     }
  30     if ($params->{errors}{suite}) {
  31         fatal_error( _g( "suite not valid or not specified" ) );
  32     }
  33
  34     #FIXME: that's extremely hacky atm
  35     if ($params->{values}{suite}{no_replace}[0] eq 'default') {
  36         $params->{values}{suite}{no_replace} =
  37             $params->{values}{suite}{final} = $opts->{suite} = [ 'etch' ];
  38     }
  39
  40     if (@{$opts->{suite}} > 1) {
  41         fatal_error( sprintf( _g( "more than one suite specified for contents search (%s)" ), "@{$opts->{suite}}" ) );
  42     }
  43
  44     my @keywords = @{$opts->{keywords}};
  45     my $mode = $opts->{mode} || '';
  46     my $suite = $opts->{suite}[0];
  47     my $archive = $opts->{archive}[0] ||'';
  48     $Packages::Search::too_many_hits = 0;
  49
  50     my $st0 = new Benchmark;
  51     my (@results);
  52
  53     unless (@Packages::CGI::fatal_errors) {
  54
  55         my $nres = 0;
  56
  57         my $first_kw = lc shift @keywords;
  58         # full filename search is tricky
  59         my $ffn = $mode eq 'filename';
  60
  61         my $reverses = tie my %reverses, 'DB_File', "$DBDIR/contents/reverse_$suite.db",
  62             O_RDONLY, 0666, $DB_BTREE
  63             or die "Failed opening reverse DB: $!";
  64
  65         if ($ffn) {
  66             open FILENAMES, '-|', 'fgrep', '--', $first_kw, "$DBDIR/contents/filenames_$suite.txt"
  67                 or die "Failed opening filename table: $!";
  68
  69           FILENAME:
  70             while (<FILENAMES>) {
  71                 chomp;
  72                 foreach my $kw (@keywords) {
  73                     next FILENAME unless /\Q$kw\E/;
  74                 }
  75                 &searchfile(\@results, reverse($_)."/", \$nres, $reverses);
  76                 last if $Packages::Search::too_many_hits;
  77             }
  78             close FILENAMES or warn "fgrep error: $!\n";
  79         } else {
  80
  81             error(_g("The search mode you selected doesn't support more than one keyword."))
  82                 if @keywords;
  83
  84             my $kw = reverse $first_kw;
  85             $kw =~ s{/+$}{};
  86
  87             # exact filename searching follows trivially:
  88             $kw = "$kw/" if $mode eq 'exactfilename';
  89
  90             &searchfile(\@results, $kw, \$nres, $reverses);
  91         }
  92         $reverses = undef;
  93         untie %reverses;
  94
  95
  96         my $st1 = new Benchmark;
  97         my $std = timediff($st1, $st0);
  98         debug( "Search took ".timestr($std) ) if DEBUG;
  99     }
 100
 101     my (%results,%archs);
 102     foreach my $result (sort { $a->[0] cmp $b->[0] } @results) {
 103         my $file = shift @$result;
 104         my %pkgs;
 105         foreach (@$result) {
 106             my ($pkg, $arch) = split /:/, $_;
 107             next unless $opts->{h_archs}{$arch};
 108             $pkgs{$pkg}{$arch}++;
 109             $archs{$arch}++ unless $arch eq 'all';
 110         }
 111         next unless keys %pkgs;
 112         $results{$file} = \%pkgs;
 113     }
 114     my @all_archs = sort keys %archs;
 115     @all_archs = sort @ARCHITECTURES unless @all_archs;
 116     $page_content->{suite} = $suite;
 117     $page_content->{archive} = $archive;
 118     $page_content->{all_architectures} = \@all_archs;
 119     $page_content->{all_suites} = \@SUITES;
 120     $page_content->{mode} = $mode;
 121     $page_content->{search_architectures} = $opts->{arch};
 122     $page_content->{search_keywords} = $opts->{keywords};
 123     $page_content->{sections} = $opts->{section};
 124     $page_content->{too_many_hits} = $Packages::Search::too_many_hits;
 125
 126     debug( "all_archs = @all_archs", 1 ) if DEBUG;
 127
 128     if (keys %results) {
 129         my $sort_func = sub { $_[0] cmp $_[1] };
 130         $sort_func = sub { (sort keys %{$results{$_[0]}})[0]
 131                            cmp
 132                            (sort keys %{$results{$_[1]}})[0]
 133                          } if $opts->{sort_by} eq 'pkg';
 134
 135         $page_content->{results} = [];
 136         foreach my $file (sort {&$sort_func($a,$b)} keys %results) {
 137             my %result;
 138             $result{file} = "/$file";
 139             $result{packages} = [];
 140             foreach my $pkg (sort keys %{$results{$file}}) {
 141                 my $arch_str = '';
 142                 my @archs = keys %{$results{$file}{$pkg}};
 143                 my $arch_neg = 0;
 144                 unless ($results{$file}{$pkg}{all} ||
 145                         (@archs == @all_archs)) {
 146                     if (@archs >= @all_archs/2) {
 147                         @archs = grep { !$results{$file}{$pkg}{$_} } @all_archs;
 148                         $arch_neg = 1;
 149                     }
 150                 } else {
 151                     @archs = ();
 152                 }
 153                 push @{$result{packages}}, { pkg => $pkg, architectures => \@archs, architectures_are_rev => $arch_neg };
 154             }
 155             push @{$page_content->{results}}, \%result;
 156         }
 157     }
 158 } # sub do_search_contents
 159
 160 sub searchfile
 161 {
 162     my ($results, $kw, $nres, $reverses) = @_;
 163
 164     my ($key, $value) = ($kw, "");
 165     debug( "searchfile: kw=$kw", 1 ) if DEBUG;
 166     for (my $status = $reverses->seq($key, $value, R_CURSOR);
 167         $status == 0;
 168         $status =  $reverses->seq( $key, $value, R_NEXT)) {
 169
 170         # FIXME: what's the most efficient "is prefix of" thingy? We only want to know
 171         # whether $kw is or is not a prefix of $key
 172         last unless index($key, $kw) == 0;
 173         debug( "found $key", 2 ) if DEBUG;
 174
 175         my @hits = split /\0/o, $value;
 176         push @$results, [ scalar reverse($key), @hits ];
 177         last if ($$nres)++ > 100;
 178     }
 179
 180     $Packages::Search::too_many_hits += $$nres - 100 if $$nres > 100;
 181 }
 182
 183
 184 1;