lib/Packages/Dispatcher.pm

   1 #!/usr/bin/perl -T
   2 # Packages::Dispatcher -- CGI interface for packages.debian.org
   3 #
   4 # Copyright (C) 2004-2007 Frank Lichtenheld
   5 #
   6 #    This program is free software; you can redistribute it and/or modify
   7 #    it under the terms of the GNU General Public License as published by
   8 #    the Free Software Foundation; either version 1 of the License, or
   9 #    (at your option) any later version.
  10 #
  11 #    This program is distributed in the hope that it will be useful,
  12 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #    GNU General Public License for more details.
  15 #
  16 #    You should have received a copy of the GNU General Public License
  17 #    along with this program; if not, write to the Free Software
  18 #    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 package Packages::Dispatcher;
  21
  22 use strict;
  23 use warnings;
  24
  25 use CGI;
  26 use POSIX;
  27 use File::Basename;
  28 use Template;
  29 use DB_File;
  30 use URI::Escape;
  31 use Benchmark ':hireswallclock';
  32 use I18N::AcceptLanguage;
  33 use Locale::gettext;
  34
  35 use Deb::Versions;
  36 use Packages::Config qw( $DBDIR $ROOT $TEMPLATEDIR $CACHEDIR
  37                          @SUITES @SECTIONS @ARCHIVES @ARCHITECTURES @PRIORITIES
  38                          @LANGUAGES @DDTP_LANGUAGES $LOCALES );
  39 use Packages::CGI qw( :DEFAULT error get_all_messages );
  40 use Packages::DB;
  41 use Packages::Search qw( :all );
  42 use Packages::Template ();
  43 use Packages::Sections;
  44 use Packages::I18N::Locale;
  45
  46 use Packages::DoSearch;
  47 use Packages::DoSearchContents;
  48 use Packages::DoShow;
  49 use Packages::DoIndex;
  50 use Packages::DoNewPkg;
  51 use Packages::DoDownload;
  52 use Packages::DoFilelist;
  53
  54
  55 sub do_dispatch {
  56
  57     &Packages::CGI::reset;
  58     $Packages::Search::too_many_hits = 0;
  59
  60     # clean up env
  61     $ENV{PATH} = "/bin:/usr/bin";
  62     delete $ENV{'LANGUAGE'};
  63     delete $ENV{'LANG'};
  64     delete $ENV{'LC_ALL'};
  65     delete $ENV{'LC_MESSAGES'};
  66
  67     my %SUITES_ALIAS = ( oldstable => 'sarge',
  68                          stable => 'etch',
  69                          testing => 'lenny',
  70                          unstable => 'sid',
  71                          '3.1' => 'sarge',
  72                          '4.0' => 'etch' );
  73
  74     # Read in all the variables set by the form
  75     my $input;
  76     if ($ARGV[0] && ($ARGV[0] eq 'php')) {
  77         $input = new CGI(\*STDIN);
  78     } else {
  79         $input = new CGI;
  80     }
  81     my $cgi_error = $input->cgi_error;
  82     if ($cgi_error) {
  83         fatal_error( "Error parsing the request", $cgi_error );
  84     }
  85
  86     my $pet0 = new Benchmark;
  87     my $tet0 = new Benchmark;
  88     my $debug = DEBUG && $input->param("debug");
  89     $debug = 0 if !defined($debug) || $debug !~ /^\d+$/o;
  90     $Packages::CGI::debug = $debug;
  91
  92     my $homedir = dirname($ENV{SCRIPT_FILENAME}).'/../';
  93     &Packages::Config::init( $homedir );
  94     &Packages::DB::init();
  95
  96     my $acc = I18N::AcceptLanguage->new();
  97     my %all_langs = map { $_ => 1 } (@LANGUAGES, @DDTP_LANGUAGES);
  98     my @all_langs = sort keys %all_langs;
  99     my $http_lang = $acc->accepts( $input->http("Accept-Language"),
 100                                    \@all_langs ) || 'en';
 101     debug( "LANGUAGES=@all_langs header=".
 102            ($input->http("Accept-Language")||'').
 103            " http_lang=$http_lang", 1 ) if DEBUG;
 104     bindtextdomain ( 'pdo', $LOCALES );
 105     bindtextdomain ( 'templates', $LOCALES );
 106     bindtextdomain ( 'langs', $LOCALES );
 107     textdomain( 'pdo' );
 108
 109     # backwards compatibility stuff
 110     debug( "SCRIPT_URL=$ENV{SCRIPT_URL} SCRIPT_URI=$ENV{SCRIPT_URI}" ) if DEBUG;
 111
 112     if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_|) {
 113         error( "You reached this site over an old URL. ".
 114                "Depending on the exact parameters your search might work or not." );
 115         # contents search changed a lot
 116         if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_contents|) {
 117             $input->param('keywords',$input->param('word')) if $input->param('word');
 118             $input->param('searchon','contents');
 119             for ($input->param('searchmode')) {
 120                 /^searchfiles/ && do {
 121                     $input->param('mode','filename');
 122                     last;
 123                 };
 124                 /^filelist/ && do {
 125                     $ENV{PATH_INFO} = '/'.join('/',($input->param('version')||'stable',
 126                                                     $input->param('keywords'),
 127                                                     $input->param('arch')||'i386',
 128                                                     'filelist' ));
 129                     $input->delete('searchon','version','keywords','arch');
 130                     last;
 131                 };
 132             }
 133         }
 134     }
 135     if ($ENV{is_reportbug}) {
 136         $input->param('exact', 1);
 137         debug( "reportbug detected, set paramater exact to '1'" ) if DEBUG;
 138     }
 139
 140     my $what_to_do = 'show';
 141     my $source = 0;
 142     if (my $path = $input->path_info() || $input->param('PATH_INFO')) {
 143         my @components = grep { $_ } map { lc $_ } split /\/+/, $path;
 144
 145         debug( "PATH_INFO=$path components=@components", 3) if DEBUG;
 146
 147         push @components, 'index' if @components && $path =~ m,/$,;
 148
 149         my %LANGUAGES = map { $_ => 1 } @all_langs;
 150         if (@components > 0 and $LANGUAGES{$components[0]}
 151             and !$input->param('lang')) {
 152             $input->param( 'lang', shift(@components) );
 153         }
 154         if (@components > 0 and $components[0] eq 'source') {
 155             shift @components;
 156             $input->param( 'source', 1 );
 157         }
 158         if (@components > 0 and $components[0] eq 'search') {
 159             shift @components;
 160             $what_to_do = 'search';
 161             # Done
 162             fatal_error( _g( "search doesn't take any more path elements" ) )
 163                 if @components;
 164         } elsif (@components == 0) {
 165             fatal_error( _g( "We're supposed to display the homepage here, instead of getting dispatch.pl" ) );
 166         } elsif (@components == 1) {
 167             $what_to_do = 'search';
 168         } else {
 169
 170             for ($components[-1]) {
 171                 /^(index|allpackages|newpkg|changelog|copyright|download|filelist)$/ && do {
 172                     pop @components;
 173                     $what_to_do = $1;
 174                     last;
 175                 };
 176             }
 177
 178             my %SUITES = map { $_ => 1 } @SUITES;
 179             my %SECTIONS = map { $_ => 1 } @SECTIONS;
 180             my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
 181             my %ARCHITECTURES = map { $_ => 1 } (@ARCHITECTURES, 'all', 'any');
 182             my %PRIORITIES = map { $_ => 1 } @PRIORITIES;
 183             my %params_set;
 184             sub set_param_once {
 185                 my ($cgi, $params_set, $key, $val) = @_;
 186                 debug("set_param_once key=$key val=$val",4) if DEBUG;
 187                 if ($params_set->{$key}++) {
 188                     fatal_error( sprintf( _g( "%s set more than once in path" ), $key ) );
 189                 } else {
 190                     $cgi->param( $key, $val );
 191                 }
 192             }
 193
 194             my (@pkg, $need_pkg);
 195             foreach (reverse @components) {
 196                 $need_pkg = !@pkg
 197                     && ($what_to_do !~ /^(index|allpackages|newpkg)$/);
 198                 debug("need_pkg=$need_pkg component=$_",4) if DEBUG;
 199                 if (!$need_pkg && $SUITES{$_}) {
 200                     set_param_once( $input, \%params_set, 'suite', $_);
 201                 } elsif (!$need_pkg && (my $s = $SUITES_ALIAS{$_})) {
 202                     set_param_once( $input, \%params_set, 'suite', $s);
 203                 } elsif (!$need_pkg && $SECTIONS{$_}) {
 204                     set_param_once( $input, \%params_set, 'section', $_);
 205                 } elsif (!$need_pkg && $ARCHIVES{$_}) {
 206                     set_param_once( $input, \%params_set, 'archive', $_);
 207                 } elsif (!$need_pkg && $sections_descs{$_}) {
 208                     set_param_once( $input, \%params_set, 'subsection', $_);
 209                 } elsif (!$need_pkg && ($_ eq 'source')) {
 210                     set_param_once( $input, \%params_set, 'source', 1);
 211                 } elsif ($ARCHITECTURES{$_}) {
 212                     set_param_once( $input, \%params_set, 'arch', $_)
 213                         unless $_ eq 'any';
 214                 } elsif ($PRIORITIES{$_}) {
 215                     set_param_once( $input, \%params_set, 'priority', $_);
 216                 } else {
 217                     push @pkg, $_;
 218                 }
 219             }
 220             @components = @pkg;
 221
 222             if (@components > 1) {
 223                 fatal_error( sprintf( _g( "two or more packages specified (%s)" ), "@components" ) );
 224             }
 225         } # else if (@components == 1)
 226
 227         if (@components) {
 228             my $c = uri_unescape($components[0]);
 229             $input->param( 'keywords', $c );
 230             $input->param( 'package', $c );
 231         }
 232     }
 233
 234     my ( $pkg, @suites, @sections, @subsections, @archives, @archs );
 235
 236     my %params_def = ( keywords => { default => undef,
 237                                      array => '\s+',
 238                                      match => '^([-+\@\w\/.:]+)$',
 239                                  },
 240                        'package' => { default => undef,
 241                                       match => '^([\w.+-]+)$',
 242                                       var => \$pkg },
 243                        suite => { default => 'default', match => '^([\w-]+)$',
 244                                   array => ',', var => \@suites,
 245                                   replace => { all => \@SUITES,
 246                                                default => \@SUITES,
 247                                                %SUITES_ALIAS } },
 248                        archive => { default => ($what_to_do eq 'search') ?
 249                                         'all' : 'default',
 250                                         match => '^([\w-]+)$',
 251                                         array => ',', var => \@archives,
 252                                         replace => { all => \@ARCHIVES,
 253                                                      default => \@ARCHIVES} },
 254                        exact => { default => 0, match => '^(\w+)$',  },
 255                        lang => { default => $http_lang, match => '^(\w+)$',  },
 256                        source => { default => 0, match => '^(\d+)$',  },
 257                        debug => { default => 0, match => '^(\d+)$',  },
 258                        searchon => { default => 'names', match => '^(\w+)$', },
 259                        section => { default => 'all', match => '^([\w-]+)$',
 260                                     alias => 'release', array => ',',
 261                                     var => \@sections,
 262                                     replace => { all => \@SECTIONS } },
 263                        subsection => { default => 'default', match => '^([\w-]+)$',
 264                                        array => ',', var => \@subsections,
 265                                        replace => { default => [] } },
 266                        priority => { default => 'default', match => '^([\w-]+)$',
 267                                      array => ',',
 268                                      replace => { default => [] } },
 269                        arch => { default => 'any', match => '^([\w-]+)$',
 270                                  array => ',', var => \@archs, replace =>
 271                                  { any => \@ARCHITECTURES } },
 272                        'format' => { default => 'html', match => '^([\w.]+)$',  },
 273                        mode => { default => '', match => '^(\w+)$',  },
 274                        sort_by => { default => 'file', match => '^(\w+)$', },
 275                        );
 276     my %opts;
 277     my %params = Packages::CGI::parse_params( $input, \%params_def, \%opts );
 278     Packages::CGI::init_url( $input, \%params, \%opts );
 279
 280     my $locale = get_locale($opts{lang});
 281     my $charset = get_charset($opts{lang});
 282     setlocale ( LC_ALL, $locale )
 283         or do { debug( "couldn't set locale $locale, using default" ) if DEBUG;
 284                 setlocale( LC_ALL, get_locale() )
 285                     or do {
 286                         debug( "couldn't set default locale either" ) if DEBUG;
 287                         setlocale( LC_ALL, "C" );
 288                     };
 289             };
 290     debug( "locale=$locale charset=$charset", 1 ) if DEBUG;
 291
 292     $opts{h_suites} = { map { $_ => 1 } @suites };
 293     $opts{h_sections} = { map { $_ => 1 } @sections };
 294     $opts{h_archives} = { map { $_ => 1 } @archives };
 295     $opts{h_archs} = { map { $_ => 1 } @archs };
 296
 297     if ((($opts{searchon} eq 'names') && $opts{source}) ||
 298         ($opts{searchon} eq 'sourcenames')) {
 299         $opts{source} = 1;
 300         $opts{searchon} = 'names',
 301         $opts{searchon_form} = 'sourcenames';
 302     } else {
 303         $opts{searchon_form} = $opts{searchon};
 304     }
 305     if ($opts{searchon} eq 'contents' or $opts{searchon} eq 'filenames') {
 306         $what_to_do = 'search_contents';
 307     }
 308
 309     my $pet1 = new Benchmark;
 310     my $petd = timediff($pet1, $pet0);
 311     debug( "Parameter evaluation took ".timestr($petd) ) if DEBUG;
 312
 313     my $template = new Packages::Template( $TEMPLATEDIR, $opts{format},
 314                                            { lang => $opts{lang}, charset => $charset,
 315                                              debug => ( DEBUG ? $opts{debug} : 0 ) },
 316                                            ( $CACHEDIR ? { COMPILE_DIR => $CACHEDIR } : {} ) );
 317
 318     #FIXME: ugly hack
 319     unless (($what_to_do eq 'allpackages' and $opts{format} =~ /^(html|txt\.gz)/)
 320             || -e "$TEMPLATEDIR/$opts{format}/${what_to_do}.tmpl") {
 321         fatal_error( _g("requested format not available for this document"),
 322                      "406 requested format not available");
 323     }
 324
 325     my (%page_content);
 326     unless (@Packages::CGI::fatal_errors) {
 327         no strict 'refs';
 328         &{"do_$what_to_do"}( \%params, \%opts, \%page_content );
 329     }
 330
 331     $page_content{opts} = \%opts;
 332     $page_content{params} = \%params;
 333
 334     unless (@Packages::CGI::fatal_errors) {
 335         print $input->header(-charset => $charset, -type => get_mime($opts{format}) );
 336         #use Data::Dumper;
 337         #print '<pre>'.Dumper(\%ENV, \%page_content, get_all_messages()).'</pre>';
 338         print $template->page( $what_to_do, { %page_content, %{ get_all_messages() } } );
 339     } elsif ($Packages::CGI::http_code && $Packages::CGI::http_code !~ /^2\d\d/) {
 340         print $input->header( -charset => $charset, -status => $Packages::CGI::http_code );
 341     } else {
 342         # We currently have only an error page in html
 343         # so no format support here
 344         print $input->header( -charset => $charset );
 345         print $template->error_page( get_all_messages() );
 346     }
 347 }
 348
 349 1;
 350 # vim: ts=8 sw=4