lib/Packages/Dispatcher.pm

   1 #!/usr/bin/perl -T
   2 # Packages::Dispatcher -- CGI interface for packages.debian.org
   3 #
   4 # Copyright (C) 2004-2007 Frank Lichtenheld
   5 #
   6 #    This program is free software; you can redistribute it and/or modify
   7 #    it under the terms of the GNU General Public License as published by
   8 #    the Free Software Foundation; either version 1 of the License, or
   9 #    (at your option) any later version.
  10 #
  11 #    This program is distributed in the hope that it will be useful,
  12 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #    GNU General Public License for more details.
  15 #
  16 #    You should have received a copy of the GNU General Public License
  17 #    along with this program; if not, write to the Free Software
  18 #    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  19
  20 package Packages::Dispatcher;
  21
  22 use strict;
  23 use warnings;
  24
  25 use CGI;
  26 use POSIX;
  27 use File::Basename;
  28 use URI::Escape;
  29 use HTML::Entities;
  30 use Template;
  31 use DB_File;
  32 use Benchmark ':hireswallclock';
  33 use I18N::AcceptLanguage;
  34 use Locale::gettext;
  35
  36 use Deb::Versions;
  37 use Packages::Config qw( $DBDIR $ROOT $TEMPLATEDIR $CACHEDIR
  38                          @SUITES @SECTIONS @ARCHIVES @ARCHITECTURES @PRIORITIES
  39                          @LANGUAGES @DDTP_LANGUAGES $LOCALES );
  40 use Packages::CGI qw( :DEFAULT error get_all_messages );
  41 use Packages::DB;
  42 use Packages::Search qw( :all );
  43 use Packages::Template ();
  44 use Packages::Sections;
  45 use Packages::I18N::Locale;
  46
  47 use Packages::DoSearch;
  48 use Packages::DoSearchContents;
  49 use Packages::DoShow;
  50 use Packages::DoIndex;
  51 use Packages::DoNewPkg;
  52 use Packages::DoDownload;
  53 use Packages::DoFilelist;
  54
  55
  56 sub do_dispatch {
  57
  58     &Packages::CGI::reset;
  59     $Packages::Search::too_many_hits = 0;
  60
  61     # clean up env
  62     $ENV{PATH} = "/bin:/usr/bin";
  63     delete $ENV{'LANGUAGE'};
  64     delete $ENV{'LANG'};
  65     delete $ENV{'LC_ALL'};
  66     delete $ENV{'LC_MESSAGES'};
  67
  68     # Read in all the variables set by the form
  69     my $input;
  70     if ($ARGV[0] && ($ARGV[0] eq 'php')) {
  71         $input = new CGI(\*STDIN);
  72     } else {
  73         $input = new CGI;
  74     }
  75     my $cgi_error = $input->cgi_error;
  76     if ($cgi_error) {
  77         fatal_error( "Error parsing the request", $cgi_error );
  78     }
  79
  80     my $pet0 = new Benchmark;
  81     my $tet0 = new Benchmark;
  82     my $debug = DEBUG && $input->param("debug");
  83     $debug = 0 if !defined($debug) || $debug !~ /^\d+$/o;
  84     $Packages::CGI::debug = $debug;
  85
  86     my $homedir = dirname($ENV{SCRIPT_FILENAME}).'/../';
  87     &Packages::Config::init( $homedir );
  88     &Packages::DB::init();
  89
  90     my $acc = I18N::AcceptLanguage->new();
  91     my %all_langs = map { $_ => 1 } (@LANGUAGES, @DDTP_LANGUAGES);
  92     my @all_langs = sort keys %all_langs;
  93     my $http_lang = $acc->accepts( $input->http("Accept-Language"),
  94                                    \@all_langs ) || 'en';
  95     debug( "LANGUAGES=@all_langs header=".
  96            ($input->http("Accept-Language")||'').
  97            " http_lang=$http_lang", 2 ) if DEBUG;
  98     bindtextdomain ( 'pdo', $LOCALES );
  99     textdomain( 'pdo' );
 100
 101     # backwards compatibility stuff
 102     debug( "SCRIPT_URL=$ENV{SCRIPT_URL} SCRIPT_URI=$ENV{SCRIPT_URI}" ) if DEBUG;
 103
 104     if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_|) {
 105         error( "You reached this site over an old URL. ".
 106                "Depending on the exact parameters your search might work or not." );
 107         # contents search changed a lot
 108         if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_contents|) {
 109             $input->param('keywords',$input->param('word')) if $input->param('word');
 110             $input->param('searchon','contents');
 111             for ($input->param('searchmode')) {
 112                 /^searchfiles/ && do {
 113                     $input->param('mode','filename');
 114                     last;
 115                 };
 116                 /^filelist/ && do {
 117                     $ENV{PATH_INFO} = '/'.join('/',($input->param('version')||'stable',
 118                                                     $input->param('keywords'),
 119                                                     $input->param('arch')||'i386',
 120                                                     'filelist' ));
 121                     $input->delete('searchon','version','keywords','arch');
 122                     last;
 123                 };
 124             }
 125         }
 126     }
 127     if ($ENV{is_reportbug}) {
 128         $input->param('exact', 1);
 129         debug( "reportbug detected, set paramater exact to '1'" ) if DEBUG;
 130     }
 131
 132     my $what_to_do = 'show';
 133     my $source = 0;
 134     if (my $path = $input->path_info() || $input->param('PATH_INFO')) {
 135         my @components = grep { $_ } map { lc $_ } split /\/+/, $path;
 136
 137         debug( "PATH_INFO=$path components=@components", 3) if DEBUG;
 138
 139         push @components, 'index' if @components && $path =~ m,/$,;
 140
 141         my %LANGUAGES = map { $_ => 1 } @all_langs;
 142         if (@components > 0 and $LANGUAGES{$components[0]}
 143             and !$input->param('lang')) {
 144             $input->param( 'lang', shift(@components) );
 145         }
 146         if (@components > 0 and $components[0] eq 'source') {
 147             shift @components;
 148             $input->param( 'source', 1 );
 149         }
 150         if (@components > 0 and $components[0] eq 'search') {
 151             shift @components;
 152             $what_to_do = 'search';
 153             # Done
 154             fatal_error( _g( "search doesn't take any more path elements" ) )
 155                 if @components;
 156         } elsif (@components == 0) {
 157             fatal_error( _g( "We're supposed to display the homepage here, instead of getting dispatch.pl" ) );
 158         } elsif (@components == 1) {
 159             $what_to_do = 'search';
 160         } else {
 161
 162             for ($components[-1]) {
 163                 /^(index|allpackages|newpkg|changelog|copyright|download|filelist)$/ && do {
 164                     pop @components;
 165                     $what_to_do = $1;
 166                     last;
 167                 };
 168             }
 169
 170             my %SUITES = map { $_ => 1 } @SUITES;
 171             my %SUITES_ALIAS = ( sarge => 'oldstable',
 172                                  etch => 'stable',
 173                                  lenny => 'testing',
 174                                  sid => 'unstable', );
 175             my %SECTIONS = map { $_ => 1 } @SECTIONS;
 176             my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
 177             my %ARCHITECTURES = map { $_ => 1 } (@ARCHITECTURES, 'all', 'any');
 178             my %PRIORITIES = map { $_ => 1 } @PRIORITIES;
 179             my %params_set;
 180             sub set_param_once {
 181                 my ($cgi, $params_set, $key, $val) = @_;
 182                 debug("set_param_once key=$key val=$val",4) if DEBUG;
 183                 if ($params_set->{$key}++) {
 184                     fatal_error( sprintf( _g( "%s set more than once in path" ), $key ) );
 185                 } else {
 186                     $cgi->param( $key, $val );
 187                 }
 188             }
 189
 190             my (@pkg, $need_pkg);
 191             foreach (reverse @components) {
 192                 $need_pkg = !@pkg
 193                     && ($what_to_do !~ /^(index|allpackages|newpkg)$/);
 194                 debug("need_pkg=$need_pkg component=$_",4) if DEBUG;
 195                 if (!$need_pkg && $SUITES{$_}) {
 196                     set_param_once( $input, \%params_set, 'suite', $_);
 197                 } elsif (!$need_pkg && (my $s = $SUITES_ALIAS{$_})) {
 198                     set_param_once( $input, \%params_set, 'suite', $s);
 199                 } elsif (!$need_pkg && $SECTIONS{$_}) {
 200                     set_param_once( $input, \%params_set, 'section', $_);
 201                 } elsif (!$need_pkg && $ARCHIVES{$_}) {
 202                     set_param_once( $input, \%params_set, 'archive', $_);
 203                 } elsif (!$need_pkg && $sections_descs{$_}) {
 204                     set_param_once( $input, \%params_set, 'subsection', $_);
 205                 } elsif (!$need_pkg && ($_ eq 'non-us')) { # non-US hack
 206                     set_param_once( $input, \%params_set, 'subsection', 'non-US');
 207                 } elsif (!$need_pkg && ($_ eq 'source')) {
 208                     set_param_once( $input, \%params_set, 'source', 1);
 209                 } elsif ($ARCHITECTURES{$_}) {
 210                     set_param_once( $input, \%params_set, 'arch', $_)
 211                         unless $_ eq 'any';
 212                 } elsif ($PRIORITIES{$_}) {
 213                     set_param_once( $input, \%params_set, 'priority', $_);
 214                 } else {
 215                     push @pkg, $_;
 216                 }
 217             }
 218             @components = @pkg;
 219
 220             if (@components > 1) {
 221                 fatal_error( sprintf( _g( "two or more packages specified (%s)" ), "@components" ) );
 222             }
 223         } # else if (@components == 1)
 224
 225         if (@components) {
 226             $input->param( 'keywords', $components[0] );
 227             $input->param( 'package', $components[0] );
 228         }
 229     }
 230
 231     my ( $pkg, @suites, @sections, @subsections, @archives, @archs );
 232
 233     my %params_def = ( keywords => { default => undef,
 234                                      array => '\s+',
 235                                      match => '^([-+\@\w\/.:]+)$',
 236                                  },
 237                        package => { default => undef,
 238                                     match => '^([\w.+-]+)$',
 239                                     var => \$pkg },
 240                        suite => { default => 'default', match => '^([\w-]+)$',
 241                                   array => ',', var => \@suites,
 242                                   replace => { all => \@SUITES,
 243                                                default => \@SUITES } },
 244                        archive => { default => ($what_to_do eq 'search') ?
 245                                         'all' : 'default',
 246                                         match => '^([\w-]+)$',
 247                                         array => ',', var => \@archives,
 248                                         replace => { all => \@ARCHIVES,
 249                                                      default => \@ARCHIVES} },
 250                        exact => { default => 0, match => '^(\w+)$',  },
 251                        lang => { default => $http_lang, match => '^(\w+)$',  },
 252                        source => { default => 0, match => '^(\d+)$',  },
 253                        debug => { default => 0, match => '^(\d+)$',  },
 254                        searchon => { default => 'names', match => '^(\w+)$', },
 255                        section => { default => 'all', match => '^([\w-]+)$',
 256                                     alias => 'release', array => ',',
 257                                     var => \@sections,
 258                                     replace => { all => \@SECTIONS } },
 259                        subsection => { default => 'default', match => '^([\w-]+)$',
 260                                        array => ',', var => \@subsections,
 261                                        replace => { default => [] } },
 262                        priority => { default => 'default', match => '^([\w-]+)$',
 263                                      array => ',',
 264                                      replace => { default => [] } },
 265                        arch => { default => 'any', match => '^([\w-]+)$',
 266                                  array => ',', var => \@archs, replace =>
 267                                  { any => \@ARCHITECTURES } },
 268                        format => { default => 'html', match => '^([\w.]+)$',  },
 269                    mode => { default => undef, match => '^(\w+)$',  },
 270                    sort_by => { default => 'file', match => '^(\w+)$', },
 271                    );
 272     my %opts;
 273     my %params = Packages::CGI::parse_params( $input, \%params_def, \%opts );
 274 Packages::CGI::init_url( $input, \%params, \%opts );
 275
 276     my $locale = get_locale($opts{lang});
 277     my $charset = get_charset($opts{lang});
 278     setlocale ( LC_ALL, $locale )
 279         or do { debug( "couldn't set locale $locale, using default" ) if DEBUG;
 280                 setlocale( LC_ALL, get_locale() )
 281                     or do {
 282                         debug( "couldn't set default locale either" ) if DEBUG;
 283                         setlocale( LC_ALL, "C" );
 284                     };
 285             };
 286     debug( "locale=$locale charset=$charset", 2 ) if DEBUG;
 287
 288     $opts{h_suites} = { map { $_ => 1 } @suites };
 289     $opts{h_sections} = { map { $_ => 1 } @sections };
 290     $opts{h_archives} = { map { $_ => 1 } @archives };
 291     $opts{h_archs} = { map { $_ => 1 } @archs };
 292
 293     if ((($opts{searchon} eq 'names') && $opts{source}) ||
 294         ($opts{searchon} eq 'sourcenames')) {
 295         $opts{source} = 1;
 296         $opts{searchon} = 'names',
 297         $opts{searchon_form} = 'sourcenames';
 298     } else {
 299         $opts{searchon_form} = $opts{searchon};
 300     }
 301     if ($opts{searchon} eq 'contents' or $opts{searchon} eq 'filenames') {
 302         $what_to_do = 'search_contents';
 303     }
 304
 305     my $pet1 = new Benchmark;
 306     my $petd = timediff($pet1, $pet0);
 307     debug( "Parameter evaluation took ".timestr($petd) ) if DEBUG;
 308
 309     my $template = new Packages::Template( $TEMPLATEDIR, $opts{format},
 310                                            { lang => $opts{lang}, charset => $charset,
 311                                              debug => ( DEBUG ? $opts{debug} : 0 ) },
 312                                            ( $CACHEDIR ? { COMPILE_DIR => $CACHEDIR } : {} ) );
 313
 314     unless (-e "$TEMPLATEDIR/$opts{format}/${what_to_do}.tmpl") {
 315         fatal_error( "requested format not available for this document",
 316                      "406 requested format not available");
 317     }
 318
 319     my (%page_content);
 320     unless (@Packages::CGI::fatal_errors) {
 321         no strict 'refs';
 322         &{"do_$what_to_do"}( \%params, \%opts, \%page_content );
 323     }
 324
 325     $page_content{opts} = \%opts;
 326     $page_content{params} = \%params;
 327
 328     $page_content{make_search_url} = sub { return &Packages::CGI::make_search_url(@_) };
 329     $page_content{make_url} = sub { return &Packages::CGI::make_url(@_) };
 330     # needed to work around the limitations of the the FILTER syntax
 331     $page_content{html_encode} = sub { return HTML::Entities::encode_entities(@_,'<>&"') };
 332     $page_content{uri_escape} = sub { return URI::Escape::uri_escape(@_) };
 333     $page_content{quotemeta} = sub { return quotemeta($_[0]) };
 334     $page_content{string2id} = sub { return &Packages::CGI::string2id(@_) };
 335
 336     unless (@Packages::CGI::fatal_errors) {
 337         print $input->header(-charset => $charset, -type => get_mime($opts{format}) );
 338         #use Data::Dumper;
 339         #print '<pre>'.Dumper(\%ENV, \%page_content, get_all_messages()).'</pre>';
 340         print $template->page( $what_to_do, { %page_content, %{ get_all_messages() } } );
 341     } elsif ($Packages::CGI::http_code && $Packages::CGI::http_code !~ /^2\d\d/) {
 342         print $input->header( -charset => $charset, -status => $Packages::CGI::http_code );
 343     } else {
 344         # We currently have only an error page in html
 345         # so no format support here
 346         print $input->header( -charset => $charset );
 347         print $template->error_page( get_all_messages() );
 348     }
 349 }
 350
 351 1;
 352 # vim: ts=8 sw=4