cgi-bin/search_packages.pl

   1 #!/usr/bin/perl -wT
   2 #
   3 # search_packages.pl -- CGI interface to the Packages files on packages.debian.org
   4 #
   5 # Copyright (C) 1998 James Treacy
   6 # Copyright (C) 2000, 2001 Josip Rodin
   7 # Copyright (C) 2001 Adam Heath
   8 # Copyright (C) 2004 Martin Schulze
   9 # Copyright (C) 2004-2006 Frank Lichtenheld
  10 #
  11 # use is allowed under the terms of the GNU Public License (GPL)
  12 # see http://www.fsf.org/copyleft/gpl.html for a copy of the license
  13
  14 use strict;
  15 use CGI qw( -oldstyle_urls );
  16 use CGI::Carp qw( fatalsToBrowser );
  17 use POSIX;
  18 use URI::Escape;
  19 use HTML::Entities;
  20 use DB_File;
  21 use Benchmark;
  22
  23 use lib "../lib";
  24
  25 use Deb::Versions;
  26 use Packages::Search qw( :all );
  27 use Packages::HTML ();
  28
  29 my $thisscript = "search_packages.pl";
  30 my $HOME = "http://www.debian.org";
  31 my $ROOT = "";
  32 my $SEARCHPAGE = "http://packages.debian.org/";
  33 my @SUITES = qw( oldstable stable testing unstable experimental );
  34 my @DISTS = @SUITES;
  35 my @SECTIONS = qw( main contrib non-free );
  36 my @ARCHIVES = qw( us security installer );
  37 my @ARCHITECTURES = qw( alpha amd64 arm hppa hurd-i386 i386 ia64
  38                         kfreebsd-i386 mips mipsel powerpc s390 sparc );
  39 my %SUITES = map { $_ => 1 } @SUITES;
  40 my %SECTIONS = map { $_ => 1 } @SECTIONS;
  41 my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
  42 my %ARCHITECTURES = map { $_ => 1 } @ARCHITECTURES;
  43
  44 $ENV{PATH} = "/bin:/usr/bin";
  45
  46 # Read in all the variables set by the form
  47 my $input = new CGI;
  48
  49 my $pet0 = new Benchmark;
  50 # use this to disable debugging in production mode completly
  51 my $debug_allowed = 1;
  52 my $debug = $debug_allowed && $input->param("debug");
  53 $Search::Param::debug = 1 if $debug > 1;
  54
  55 # If you want, just print out a list of all of the variables and exit.
  56 print $input->header if $debug;
  57 # print $input->dump;
  58 # exit;
  59
  60 if (my $path = $input->param('path')) {
  61     my @components = map { lc $_ } split /\//, $path;
  62
  63     foreach (@components) {
  64         if ($SUITES{$_}) {
  65             $input->param('suite', $_);
  66         } elsif ($SECTIONS{$_}) {
  67             $input->param('section', $_);
  68         } elsif ($ARCHIVES{$_}) {
  69             $input->param('archive', $_);
  70         }elsif ($ARCHITECTURES{$_}) {
  71             $input->param('arch', $_);
  72         }
  73     }
  74 }
  75
  76 my %params_def = ( keywords => { default => undef, match => '^\s*([-+\@\w\/.:]+)\s*$' },
  77                    suite => { default => 'stable', match => '^(\w+)$',
  78                               alias => 'version', array => ',',
  79                               replace => { all => \@SUITES } },
  80                    case => { default => 'insensitive', match => '^(\w+)$' },
  81                    official => { default => 0, match => '^(\w+)$' },
  82                    use_cache => { default => 1, match => '^(\w+)$' },
  83                    subword => { default => 0, match => '^(\w+)$' },
  84                    exact => { default => undef, match => '^(\w+)$' },
  85                    searchon => { default => 'all', match => '^(\w+)$' },
  86                    section => { default => 'all', match => '^([\w-]+)$',
  87                                 alias => 'release', array => ',',
  88                                 replace => { all => \@SECTIONS } },
  89                    arch => { default => 'any', match => '^(\w+)$',
  90                              array => ',', replace =>
  91                              { any => \@ARCHITECTURES } },
  92                    archive => { default => 'all', match => '^(\w+)$',
  93                                 array => ',', replace =>
  94                                 { all => \@ARCHIVES } },
  95                    format => { default => 'html', match => '^(\w+)$' },
  96                    );
  97 my %params = Packages::Search::parse_params( $input, \%params_def );
  98
  99 my $format = $params{values}{format}{final};
 100 #XXX: Don't use alternative output formats yet
 101 $format = 'html';
 102
 103 if ($format eq 'html') {
 104     print $input->header;
 105 } elsif ($format eq 'xml') {
 106 #    print $input->header( -type=>'application/rdf+xml' );
 107     print $input->header( -type=>'text/plain' );
 108 }
 109
 110 if ($params{errors}{keywords}) {
 111     print "Error: keyword not valid or missing" if $format eq 'html';
 112     exit 0;
 113 }
 114 my $keyword = $params{values}{keywords}{final};
 115 my @suites = @{$params{values}{suite}{final}};
 116 my $official = $params{values}{official}{final};
 117 my $use_cache = $params{values}{use_cache}{final};
 118 my $case = $params{values}{case}{final};
 119 my $case_bool = ( $case !~ /insensitive/ );
 120 my $subword = $params{values}{subword}{final};
 121 my $exact = $params{values}{exact}{final};
 122 $exact = !$subword unless defined $exact;
 123 my $searchon = $params{values}{searchon}{final};
 124 my @sections = @{$params{values}{section}{final}};
 125 my @archs = @{$params{values}{arch}{final}};
 126 my $page = $params{values}{page}{final};
 127 my $results_per_page = $params{values}{number}{final};
 128
 129 # for URL construction
 130 my $suites_param = join ',', @{$params{values}{suite}{no_replace}};
 131 my $sections_param = join ',', @{$params{values}{section}{no_replace}};
 132 my $archs_param = join ',', @{$params{values}{arch}{no_replace}};
 133
 134 # for output
 135 my $keyword_enc = encode_entities $keyword;
 136 my $searchon_enc = encode_entities $searchon;
 137 my $suites_enc = encode_entities join ', ', @{$params{values}{suite}{no_replace}};
 138 my $sections_enc = encode_entities join ', ', @{$params{values}{section}{no_replace}};
 139 my $archs_enc = encode_entities join ', ',  @{$params{values}{arch}{no_replace}};
 140 my $pet1 = new Benchmark;
 141 my $petd = timediff($pet1, $pet0);
 142 print "DEBUG: Parameter evaluation took ".timestr($petd)."<br>" if $debug;
 143
 144 if ($format eq 'html') {
 145 print Packages::HTML::header( title => 'Package Search Results' ,
 146                               lang => 'en',
 147                               title_tag => 'Debian Package Search Results',
 148                               print_title_above => 1,
 149                               print_search_field => 'packages',
 150                               search_field_values => {
 151                                   keywords => $keyword_enc,
 152                                   searchon => $searchon,
 153                                   arch => $archs_enc,
 154                                   suite => $suites_enc,
 155                                   section => $sections_enc,
 156                                   subword => $subword,
 157                                   exact => $exact,
 158                                   case => $case,
 159                                   },
 160                               );
 161 }
 162
 163 # read the configuration
 164 my $topdir;
 165 if (!open (C, "../config.sh")) {
 166     print "\nInternal Error: Cannot open configuration file.\n\n"
 167 if $format eq 'html';
 168     exit 0;
 169 }
 170 while (<C>) {
 171     $topdir = $1 if (/^\s*topdir="?(.*)"?\s*$/);
 172 }
 173 close (C);
 174
 175 my $DBDIR = $topdir . "/files/db";
 176 my $search_on_sources = 0;
 177
 178 my $st0 = new Benchmark;
 179 my @results;
 180 my $too_much_hits;
 181 if ($searchon eq 'sourcenames') {
 182     $search_on_sources = 1;
 183 }
 184
 185 my %suites = map { $_ => 1 } @suites;
 186 my %sections = map { $_ => 1 } @sections;
 187 my %archs = map { $_ => 1 } @archs;
 188
 189 print "DEBUG: suites=@suites, sections=@sections, archs=@archs<br>" if $debug > 2;
 190
 191 sub read_entry {
 192     my ($hash, $key, $results) = @_;
 193     my $result = $hash->{$key};
 194     foreach (split /\000/, $result) {
 195         my @data = split ( /\s/, $_, 7 );
 196         print "DEBUG: Considering entry ".join( ':', @data)."<br>" if $debug > 2;
 197         if ($suites{$data[0]} && ($archs{$data[1]} || $data[1] eq 'all')
 198             && $sections{$data[2]}) {
 199             print "DEBUG: Using entry ".join( ':', @data)."<br>" if $debug > 2;
 200             push @$results, [ $key, @data ];
 201         }
 202     }
 203 }
 204 sub read_src_entry {
 205     my ($hash, $key, $results) = @_;
 206     my $result = $hash->{$key};
 207
 208     foreach (split /\000/, $result) {
 209         my @data = split ( /\s/, $_, 5 );
 210         print "DEBUG: Considering entry ".join( ':', @data)."<br>" if $debug > 2;
 211         if ($suites{$data[0]} && $sections{$data[1]}) {
 212             print "DEBUG: Using entry ".join( ':', @data)."<br>" if $debug > 2;
 213             push @$results, [ $key, @data ];
 214         }
 215     }
 216 }
 217
 218
 219 if ($searchon eq 'names') {
 220
 221     $keyword = lc $keyword unless $case_bool;
 222
 223     my $obj = tie my %packages, 'DB_File', "$DBDIR/packages_small.db", O_RDONLY, 0666, $DB_BTREE
 224         or die "couldn't tie DB $DBDIR/packages_small.db: $!";
 225
 226     if ($exact) {
 227         read_entry( \%packages, $keyword, \@results );
 228     } else {
 229         my ($key, $prefixes) = ($keyword, '');
 230         my %pkgs;
 231         my $p_obj = tie my %pref, 'DB_File', "$DBDIR/package_postfixes.db", O_RDONLY, 0666, $DB_BTREE
 232             or die "couldn't tie postfix db $DBDIR/package_postfixes.db: $!";
 233         $p_obj->seq( $key, $prefixes, R_CURSOR );
 234         do {
 235             if ($prefixes =~ /^\001(\d+)/o) {
 236                 $too_much_hits += $1;
 237             } else {
 238                 print "DEBUG: add word $key<br>" if $debug > 2;
 239                 $pkgs{$key}++;
 240                 foreach (split /\000/o, $prefixes) {
 241                     print "DEBUG: add word $_$key<br>" if $debug > 2;
 242                     $pkgs{$_.$key}++;
 243                 }
 244             }
 245         } while (($p_obj->seq( $key, $prefixes, R_NEXT ) == 0)
 246                  && (index($key, $keyword) >= 0)
 247                  && !$too_much_hits
 248                  && (keys %pkgs < 100));
 249
 250         my $no_results = keys %pkgs;
 251         if ($too_much_hits || ($no_results >= 100)) {
 252             $too_much_hits += $no_results;
 253             %pkgs = ( $keyword => 1 );
 254         }
 255         foreach my $pkg (sort keys %pkgs) {
 256             read_entry( \%packages, $pkg, \@results );
 257         }
 258     }
 259 } elsif ($searchon eq 'sourcenames') {
 260
 261     $keyword = lc $keyword unless $case_bool;
 262
 263     my $obj = tie my %packages, 'DB_File', "$DBDIR/sources_small.db", O_RDONLY, 0666, $DB_BTREE
 264         or die "couldn't tie DB $DBDIR/sources_small.db: $!";
 265
 266     if ($exact) {
 267         read_src_entry( \%packages, $keyword, \@results );
 268     } else {
 269         while (my ($pkg, $result) = each %packages) {
 270             #what's faster? I can't really see a difference
 271             (index($pkg, $keyword) >= 0) or next;
 272             #$pkg =~ /\Q$keyword\E/ or next;
 273             foreach (split /\000/, $result) {
 274                 my @data = split ( /\s/, $_, 5 );
 275                 print "DEBUG: Considering entry ".join( ':', @data)."<br>" if $debug > 2;
 276                 if ($suites{$data[0]} && $sections{$data[1]}) {
 277                     print "DEBUG: Using entry ".join( ':', @data)."<br>" if $debug > 2;
 278                     push @results, [ $pkg , @data ];
 279                 }
 280             }
 281         }
 282     }
 283 } else {
 284
 285     my @lines;
 286     my $regex;
 287     if ($case_bool) {
 288         if ($exact) {
 289             $regex = qr/\b\Q$keyword\E\b/o;
 290         } else {
 291             $regex = qr/\Q$keyword\E/o;
 292         }
 293     } else {
 294         if ($exact) {
 295             $regex = qr/\b\Q$keyword\E\b/io;
 296         } else {
 297             $regex = qr/\Q$keyword\E/io;
 298         }
 299     }
 300
 301     open DESC, '<', "$DBDIR/descriptions.txt" or die "couldn't open $DBDIR/descriptions.txt: $!";
 302     while (<DESC>) {
 303         $_ =~ $regex or next;
 304         print "DEBUG: Matched line $.<br>" if $debug > 2;
 305         push @lines, $.;
 306     }
 307     close DESC;
 308
 309     my $obj = tie my %packages, 'DB_File', "$DBDIR/packages_small.db", O_RDONLY, 0666, $DB_BTREE
 310         or die "couldn't tie DB $DBDIR/packages_small.db: $!";
 311     my $obj = tie my %did2pkg, 'DB_File', "$DBDIR/descriptions_packages.db", O_RDONLY, 0666, $DB_BTREE
 312         or die "couldn't tie DB $DBDIR/descriptions_packages.db: $!";
 313
 314     my %tmp_results;
 315     foreach my $l (@lines) {
 316         my $result = $did2pkg{$l};
 317         foreach (split /\000/o, $result) {
 318             my @data = split /\s/, $_, 3;
 319             next unless $archs{$data[2]};
 320             $tmp_results{$data[0]}++;
 321         }
 322     }
 323     foreach my $pkg (keys %tmp_results) {
 324         read_entry( \%packages, $pkg, \@results );
 325     }
 326 }
 327
 328 my $st1 = new Benchmark;
 329 my $std = timediff($st1, $st0);
 330 print "DEBUG: Search took ".timestr($std)."<br>" if $debug;
 331
 332 if ($format eq 'html') {
 333     my $suite_wording = $suites_enc eq "all" ? "all suites"
 334         : "suite(s) <em>$suites_enc</em>";
 335     my $section_wording = $sections_enc eq 'all' ? "all sections"
 336         : "section(s) <em>$sections_enc</em>";
 337     my $arch_wording = $archs_enc eq 'any' ? "all architectures"
 338         : "architecture(s) <em>$archs_enc</em>";
 339     if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 340         my $source_wording = $search_on_sources ? "source " : "";
 341         my $exact_wording = $exact ? "named" : "that names contain";
 342         print "<p>You have searched for ${source_wording}packages $exact_wording <em>$keyword_enc</em> in $suite_wording, $section_wording, and $arch_wording.</p>";
 343     } else {
 344         my $exact_wording = $exact ? "" : " (including subword matching)";
 345         print "<p>You have searched for <em>$keyword_enc</em> in packages names and descriptions in $suite_wording, $section_wording, and $arch_wording$exact_wording.</p>";
 346     }
 347 }
 348
 349 if ($too_much_hits) {
 350 print "<p><strong>Your search was too wide so we will only display exact matches. At least <em>$too_much_hits</em> results have been omitted and will not be displayed. Please consider using a longer keyword or more keywords.</strong></p>";
 351 }
 352
 353 if (!@results) {
 354     if ($format eq 'html') {
 355         my $keyword_esc = uri_escape( $keyword );
 356         my $printed = 0;
 357         if (($searchon eq "names") || ($searchon eq 'sourcenames')) {
 358             if (($suites_enc eq 'all')
 359                 && ($archs_enc eq 'any')
 360                 && ($sections_enc eq 'all')) {
 361                 print "<p><strong>Can't find that package.</strong></p>\n";
 362             } else {
 363                 print "<p><strong>Can't find that package, at least not in that suite ".
 364                     ( $search_on_sources ? "" : " and on that architecture" ).
 365                     ".</strong></p>\n";
 366             }
 367
 368             if ($exact) {
 369                 $printed = 1;
 370                 print "<p>You have searched only for exact matches of the package name. You can try to search for <a href=\"$thisscript?exact=0&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">package names that contain your search string</a>.</p>";
 371             }
 372         } else {
 373             if (($suites_enc eq 'all')
 374                 && ($archs_enc eq 'any')
 375                 && ($sections_enc eq 'all')) {
 376                 print "<p><strong>Can't find that string.</strong></p>\n";
 377             } else {
 378                 print "<p><strong>Can't find that string, at least not in that suite ($suites_enc, section $sections_enc) and on that architecture ($archs_enc).</strong></p>\n";
 379             }
 380
 381             unless ($subword) {
 382                 $printed = 1;
 383                 print "<p>You have searched only for words exactly matching your keywords. You can try to search <a href=\"$thisscript?subword=1&amp;searchon=$searchon&amp;suite=$suites_param&amp;case=$case&amp;section=$sections_param&amp;keywords=$keyword_esc&amp;arch=$archs_param\">allowing subword matching</a>.</p>";
 384             }
 385         }
 386         print "<p>".( $printed ? "Or you" : "You" )." can try a different search on the <a href=\"$SEARCHPAGE#search_packages\">Packages search page</a>.</p>";
 387
 388         &printfooter;
 389     }
 390     exit;
 391 }
 392
 393 my (%pkgs, %sect, %part, %desc, %binaries);
 394
 395 unless ($search_on_sources) {
 396     foreach (@results) {
 397         my ($pkg_t, $suite, $arch, $section, $subsection,
 398             $priority, $version, $desc) = @$_;
 399
 400         my ($package) = $pkg_t =~ m/^(.+)/; # untaint
 401         $pkgs{$package}{$suite}{$version}{$arch} = 1;
 402         $sect{$package}{$suite}{$version} = $subsection;
 403         $part{$package}{$suite}{$version} = $section unless $section eq 'main';
 404
 405         $desc{$package}{$suite}{$version} = $desc;
 406
 407     }
 408
 409     if ($format eq 'html') {
 410         my ($start, $end) = multipageheader( scalar keys %pkgs );
 411         my $count = 0;
 412
 413         foreach my $pkg (sort keys %pkgs) {
 414             $count++;
 415             next if $count < $start or $count > $end;
 416             printf "<h3>Package %s</h3>\n", $pkg;
 417             print "<ul>\n";
 418             foreach my $ver (@SUITES) {
 419                 if (exists $pkgs{$pkg}{$ver}) {
 420                     my @versions = version_sort keys %{$pkgs{$pkg}{$ver}};
 421                     my $part_str = "";
 422                     if ($part{$pkg}{$ver}{$versions[0]}) {
 423                         $part_str = "[<span style=\"color:red\">$part{$pkg}{$ver}{$versions[0]}</span>]";
 424                     }
 425                     printf "<li><a href=\"$ROOT/%s/%s/%s\">%s</a> (%s): %s   %s\n",
 426                     $ver, $sect{$pkg}{$ver}{$versions[0]}, $pkg, $ver, $sect{$pkg}{$ver}{$versions[0]}, $desc{$pkg}{$ver}{$versions[0]}, $part_str;
 427
 428                     foreach my $v (@versions) {
 429                         printf "<br>%s: %s\n",
 430                         $v, join (" ", (sort keys %{$pkgs{$pkg}{$ver}{$v}}) );
 431                     }
 432                     print "</li>\n";
 433                 }
 434             }
 435             print "</ul>\n";
 436         }
 437     } elsif ($format eq 'xml') {
 438         require RDF::Simple::Serialiser;
 439         my $rdf = new RDF::Simple::Serialiser;
 440         $rdf->addns( debpkg => 'http://packages.debian.org/xml/01-debian-packages-rdf' );
 441         my @triples;
 442         foreach my $pkg (sort keys %pkgs) {
 443             foreach my $ver (@DISTS) {
 444                 if (exists $pkgs{$pkg}{$ver}) {
 445                     my @versions = version_sort keys %{$pkgs{$pkg}{$ver}};
 446                     foreach my $version (@versions) {
 447                         my $id = "$ROOT/$ver/$sect{$pkg}{$ver}{$version}/$pkg/$version";
 448                         push @triples, [ $id, 'debpkg:package', $pkg ];
 449                         push @triples, [ $id, 'debpkg:version', $version ];
 450                         push @triples, [ $id, 'debpkg:section', $sect{$pkg}{$ver}{$version}, ];
 451                         push @triples, [ $id, 'debpkg:suite', $ver ];
 452                         push @triples, [ $id, 'debpkg:shortdesc', $desc{$pkg}{$ver}{$version} ];
 453                         push @triples, [ $id, 'debpkg:part', $part{$pkg}{$ver}{$version} || 'main' ];
 454                         foreach my $arch (sort keys %{$pkgs{$pkg}{$ver}{$version}}) {
 455                             push @triples, [ $id, 'debpkg:architecture', $arch ];
 456                         }
 457                     }
 458                 }
 459             }
 460         }
 461
 462         print $rdf->serialise(@triples);
 463     }
 464 } else {
 465     foreach (@results) {
 466         my ($package, $suite, $section, $subsection, $priority,
 467             $version, $binaries) = @$_;
 468
 469         $pkgs{$package}{$suite} = $version;
 470         $sect{$package}{$suite}{source} = $subsection;
 471         $part{$package}{$suite}{source} = $section unless $section eq 'main';
 472
 473         $binaries{$package}{$suite} = [ sort split( /\s*,\s*/, $binaries ) ];
 474     }
 475
 476     if ($format eq 'html') {
 477         my ($start, $end) = multipageheader( scalar keys %pkgs );
 478         my $count = 0;
 479
 480         foreach my $pkg (sort keys %pkgs) {
 481             $count++;
 482             next if ($count < $start) or ($count > $end);
 483             printf "<h3>Source package %s</h3>\n", $pkg;
 484             print "<ul>\n";
 485             foreach my $ver (@SUITES) {
 486                 if (exists $pkgs{$pkg}{$ver}) {
 487                     my $part_str = "";
 488                     if ($part{$pkg}{$ver}{source}) {
 489                         $part_str = "[<span style=\"color:red\">$part{$pkg}{$ver}{source}</span>]";
 490                     }
 491                     printf "<li><a href=\"$ROOT/%s/source/%s\">%s</a> (%s): %s   %s", $ver, $pkg, $ver, $sect{$pkg}{$ver}{source}, $pkgs{$pkg}{$ver}, $part_str;
 492
 493                     print "<br>Binary packages: ";
 494                     my @bp_links;
 495                     foreach my $bp (@{$binaries{$pkg}{$ver}}) {
 496                         my $sect = 'section';
 497
 498                         my $bp_link;
 499                         if ($sect) {
 500                             $bp_link = sprintf( "<a href=\"$ROOT/%s/%s/%s\">%s</a>",
 501                                                 $ver, $sect, uri_escape( $bp ),  $bp );
 502                         } else {
 503                             $bp_link = $bp;
 504                         }
 505                         push @bp_links, $bp_link;
 506                     }
 507                     print join( ", ", @bp_links );
 508                     print "</li>\n";
 509                 }
 510             }
 511             print "</ul>\n";
 512         }
 513     } elsif ($format eq 'xml') {
 514         require RDF::Simple::Serialiser;
 515         my $rdf = new RDF::Simple::Serialiser;
 516         $rdf->addns( debpkg => 'http://packages.debian.org/xml/01-debian-packages-rdf' );
 517         my @triples;
 518         foreach my $pkg (sort keys %pkgs) {
 519             foreach my $ver (@SUITES) {
 520                 if (exists $pkgs{$pkg}{$ver}) {
 521                     my $id = "$ROOT/$ver/source/$pkg";
 522
 523                     push @triples, [ $id, 'debpkg:package', $pkg ];
 524                     push @triples, [ $id, 'debpkg:type', 'source' ];
 525                     push @triples, [ $id, 'debpkg:section', $sect{$pkg}{$ver}{source} ];
 526                     push @triples, [ $id, 'debpkg:version', $pkgs{$pkg}{$ver} ];
 527                     push @triples, [ $id, 'debpkg:part', $part{$pkg}{$ver}{source} || 'main' ];
 528
 529                     foreach my $bp (@{$binaries{$pkg}{$ver}}) {
 530                         push @triples, [ $id, 'debpkg:binary', $bp ];
 531                     }
 532                 }
 533             }
 534         }
 535         print $rdf->serialise(@triples);
 536     }
 537 }
 538
 539 if ($format eq 'html') {
 540     &printindexline( scalar keys %pkgs );
 541     &printfooter;
 542 }
 543
 544 exit;
 545
 546 sub printindexline {
 547     my $no_results = shift;
 548
 549     my $index_line;
 550     if ($no_results > $results_per_page) {
 551
 552         $index_line = prevlink($input,\%params)." | ".
 553             indexline( $input, \%params, $no_results)." | ".
 554             nextlink($input,\%params, $no_results);
 555
 556         print "<p style=\"text-align:center\">$index_line</p>";
 557     }
 558 }
 559
 560 sub multipageheader {
 561     my $no_results = shift;
 562
 563     my ($start, $end);
 564     if ($results_per_page =~ /^all$/i) {
 565         $start = 1;
 566         $end = $no_results;
 567         $results_per_page = $no_results;
 568     } else {
 569         $start = Packages::Search::start( \%params );
 570         $end = Packages::Search::end( \%params );
 571         if ($end > $no_results) { $end = $no_results; }
 572     }
 573
 574     print "<p>Found <em>$no_results</em> matching packages,";
 575     if ($end == $start) {
 576         print " displaying package $end.</p>";
 577     } else {
 578         print " displaying packages $start to $end.</p>";
 579     }
 580
 581     printindexline( $no_results );
 582
 583     if ($no_results > 100) {
 584         print "<p>Results per page: ";
 585         my @resperpagelinks;
 586         for (50, 100, 200) {
 587             if ($results_per_page == $_) {
 588                 push @resperpagelinks, $_;
 589             } else {
 590                 push @resperpagelinks, resperpagelink($input,\%params,$_);
 591             }
 592         }
 593         if ($params{values}{number}{final} =~ /^all$/i) {
 594             push @resperpagelinks, "all";
 595         } else {
 596             push @resperpagelinks, resperpagelink($input, \%params,"all");
 597         }
 598         print join( " | ", @resperpagelinks )."</p>";
 599     }
 600     return ( $start, $end );
 601 }
 602
 603 sub printfooter {
 604 print <<END;
 605 </div>
 606
 607 <hr class="hidecss">
 608 <p style="text-align:right;font-size:small;font-stlye:italic"><a href="$SEARCHPAGE">Packages search page</a></p>
 609
 610 </div>
 611 END
 612
 613 print $input->end_html;
 614 }