bin/create_index_pages

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX;
   7 use File::Path;
   8 use DB_File;
   9 use Storable;
  10 use HTML::Entities;
  11 use URI::Escape;
  12 use Compress::Zlib;
  13 use IO::Handle;
  14
  15 use lib './lib';
  16
  17 use Packages::CommonCode qw(:all);
  18 use Packages::Config qw( $TOPDIR $DBDIR @ARCHIVES @SUITES @LANGUAGES );
  19 use Packages::Template;
  20 use Packages::I18N::Locale;
  21 use Packages::Page;
  22 use Packages::SrcPage;
  23 use Packages::Sections;
  24 &Packages::Config::init( './' );
  25
  26 use constant DEBUG => 0;
  27
  28 my $wwwdir = "$TOPDIR/www";
  29
  30 tie my %packages, 'DB_File', "$DBDIR/packages_small.db",
  31     O_RDONLY, 0666, $DB_BTREE
  32     or die "couldn't tie DB $DBDIR/packages_small.db: $!";
  33 tie my %src_packages, 'DB_File', "$DBDIR/sources_small.db",
  34     O_RDONLY, 0666, $DB_BTREE
  35     or die "couldn't tie DB $DBDIR/sources_small.db: $!";
  36 tie my %src2bin, 'DB_File', "$DBDIR/sources_packages.db",
  37     O_RDONLY, 0666, $DB_BTREE
  38     or die "couldn't open $DBDIR/sources_packages.db: $!";
  39 tie my %desctrans, 'DB_File', "$DBDIR/descriptions_translated.db",
  40     O_RDONLY, 0666, $DB_BTREE
  41     or die "couldn't tie DB $DBDIR/descriptions_translated.db: $!";
  42
  43 my $sections = retrieve "$DBDIR/sections.info";
  44 my $subsections = retrieve "$DBDIR/subsections.info";
  45 my $priorities = retrieve "$DBDIR/priorities.info";
  46
  47 use Data::Dumper;
  48 #print STDERR Dumper($sections, $subsections, $priorities);
  49
  50 my @PACKAGES = sort keys %packages;
  51 my @SRC_PACKAGES = sort keys %src_packages;
  52
  53 print "Found ".scalar(@PACKAGES)." packages\n";
  54 print "Found ".scalar(@SRC_PACKAGES)." source packages\n";
  55
  56 my $template = new Packages::Template( "$TOPDIR/templates", 'html');
  57 my $txt_template = new Packages::Template( "$TOPDIR/templates", 'txt');
  58
  59 my $charset = 'UTF-8';
  60 my (%cat, %lang_vars, $prov_string, %s, %fh);
  61 foreach my $lang (@LANGUAGES) {
  62     $cat{$lang} = Packages::I18N::Locale->get_handle($lang)
  63         or die "get_handle failed for $lang";
  64     $lang_vars{$lang} = { po_lang => $lang, ddtp_lang => $lang,
  65                           charset => $charset,
  66                           cat => $cat{$lang}, used_langs => \@LANGUAGES };
  67     $s{begin}{$lang} = '['.uc($lang).':';
  68     $s{end}{$lang} = ':'.uc($lang).']';
  69     $prov_string .= $s{begin}{$lang}.$cat{$lang}->g('virtual package provided by').$s{end}{$lang};
  70 }
  71
  72 sub open_file {
  73     my ($key, $vars, $file) = @_;
  74
  75     $file ||= 'index';
  76
  77     print "opening $key\n";
  78     mkdirp ( "$wwwdir/$key" );
  79     if ($fh{$key}) {
  80         warn "filehandle for $key already open\n";
  81         return;
  82     }
  83     open($fh{$key}, '>',
  84          "$wwwdir/$key/$file.slices.new")
  85         or die "Cannot open file $wwwdir/$key/$file.slices.new: $!";
  86
  87     foreach my $lang (@LANGUAGES) {
  88         print {$fh{$key}} "$s{begin}{$lang}\n";
  89         $template->page( 'index_head',
  90                          { %{$lang_vars{$lang}},
  91                            %$vars },
  92                          $fh{$key});
  93         print {$fh{$key}} "\n$s{end}{$lang}\n";
  94     }
  95 }
  96
  97 sub close_file {
  98     my ($key, $vars, $file) = @_;
  99
 100     $file ||= 'index';
 101
 102     print "closing $key\n";
 103     unless ($fh{$key}->opened()) {
 104         warn "filehandle for $key already closed\n";
 105         return;
 106     }
 107
 108     foreach my $lang (@LANGUAGES) {
 109         print {$fh{$key}} "\n$s{begin}{$lang}\n";
 110         $template->page( 'index_foot',
 111                          { %{$lang_vars{$lang}},
 112                            %$vars },
 113                          $fh{$key});
 114         print {$fh{$key}} "\n$s{end}{$lang}\n";
 115     }
 116     close($fh{$key})
 117         or die "Cannot close file $wwwdir/$key/$file.slices.new: $!";
 118
 119     activate("$wwwdir/$key/$file.slices");
 120 }
 121
 122
 123 sub open_txt_file {
 124     my ($key, $vars, $file) = @_;
 125
 126     $file ||= 'allpackages';
 127     my $lang = 'en';
 128
 129     print "opening $key (txt,lang=$lang)\n";
 130     mkdirp ( "$wwwdir/$key" );
 131     $fh{"$key/$lang/txt"} = gzopen("$wwwdir/$key/$file.$lang.txt.gz.new", 'wb9')
 132         or die "Cannot open file $wwwdir/$key/$file.$lang.txt.gz.new: $!";
 133
 134     my $gztxt = $txt_template->page( 'index_head',
 135                                      { %{$lang_vars{$lang}},
 136                                        %$vars });
 137     $fh{"$key/$lang/txt"}->gzwrite($gztxt);
 138 }
 139
 140 sub close_txt_file {
 141     my ($key, $vars, $file) = @_;
 142
 143     $file ||= 'allpackages';
 144     my $lang = 'en';
 145
 146     print "closing $key (txt,lang=$lang)\n";
 147     my $gztxt = $txt_template->page( 'index_foot',
 148                                      { %{$lang_vars{$lang}},
 149                                        %$vars });
 150     $fh{"$key/$lang/txt"}->gzwrite($gztxt);
 151     ($fh{"$key/$lang/txt"}->gzclose == Z_OK) or
 152         warn("can't close text index file $wwwdir/$key/$file.$lang.txt.gz.new: "
 153              . $fh{"$key/$lang/txt"}->gzerror);
 154     activate("$wwwdir/$key/$file.$lang.txt.gz");
 155 }
 156
 157
 158 foreach my $source (("", "source/")) {
 159     print "write headers ...\n";
 160     foreach my $s (@SUITES) {
 161         mkdirp ( "$wwwdir/$source$s" );
 162         my %common_vars = ( suite => $s,
 163                             is_source => $source );
 164
 165         open_file("$source$s", \%common_vars, 'allpackages');
 166         open_txt_file("$source$s", \%common_vars, 'allpackages');
 167
 168         foreach my $sec (keys %{$sections->{$s}}) {
 169             open_file("$source$s/$sec",
 170                       { %common_vars,
 171                         category => { id => N_('Section'),
 172                                       name => $sec }});
 173         }
 174         foreach my $ssec ((keys %{$subsections->{$s}}, 'virtual')) {
 175             next if $ssec eq '-';
 176             open_file("$source$s/$ssec",
 177                       { %common_vars,
 178                         category => { id => N_('Subsection'),
 179                                       name => $ssec }});
 180         }
 181         foreach my $prio (keys %{$priorities->{$s}}) {
 182             next if $prio eq '-';
 183             open_file("$source$s/$prio",
 184                       { %common_vars,
 185                         category => { id => N_('Priority'),
 186                                       name => $prio }});
 187         }
 188     }
 189
 190     if ($source) {
 191         process_source_packages();
 192     } else {
 193         process_packages();
 194     }
 195
 196     print "write footers ...\n";
 197     foreach my $s (@SUITES) {
 198         my %common_vars = ( suite => $s,
 199                             is_source => $source );
 200         my $page_base = "$source$s/";
 201         close_file("$source$s", { %common_vars,
 202                                   page_name => "${page_base}allpackages" },
 203                    'allpackages');
 204         close_txt_file("$source$s", { %common_vars,
 205                                       page_name => "{$page_base}allpackages" },
 206                        'allpackages');
 207
 208         foreach my $sec (keys %{$sections->{$s}}) {
 209             close_file("$source$s/$sec",
 210                        { %common_vars,
 211                          page_name => "$page_base$sec/",
 212                          category => { id => N_('Section'),
 213                                        name => $sec }});
 214         }
 215         foreach my $ssec ((keys %{$subsections->{$s}}, 'virtual')) {
 216             next if $ssec eq '-';
 217             close_file("$source$s/$ssec",
 218                        { %common_vars,
 219                          page_name => "$page_base$ssec/",
 220                          category => { id => N_('Subsection'),
 221                                        name => $ssec }});
 222         }
 223         foreach my $prio (keys %{$priorities->{$s}}) {
 224             next if $prio eq '-';
 225             close_file("$source$s/$prio",
 226                        { %common_vars,
 227                          page_name => "$page_base$prio/",
 228                          category => { id => N_('Priority'),
 229                                        name => $prio }});
 230         }
 231     }
 232 }
 233
 234 sub process_packages {
 235
 236 print "processing package info ...\n";
 237 my $count = 0;
 238 foreach my $pkg (@PACKAGES) {
 239     warn "pkg=$pkg\n" if DEBUG;
 240     print "$count\n" unless ++$count % 1000;
 241
 242     my (%pkg,%virt);
 243     my ($virt, $p_data) = split /\000/o, $packages{$pkg}, 2;
 244     %virt = split /\01/o, $virt;
 245     foreach (split /\000/o, $p_data||'') {
 246         my @data = split ( /\s/o, $_, 9 );
 247         $pkg{$data[1]} ||= new Packages::Page( $pkg );
 248         $pkg{$data[1]}->merge_package( { package => $pkg,
 249                                          archive => $data[0],
 250                                          suite => $data[1],
 251                                          architecture => $data[2],
 252                                          section => $data[3],
 253                                          subsection => $data[4],
 254                                          priority => $data[5],
 255                                          version => $data[6],
 256                                          'description-md5' => $data[7],
 257                                          description => $data[8] } );
 258     }
 259     foreach (keys %virt) {
 260         next if $_ eq '-';
 261         $pkg{$_} ||= new Packages::Page( $pkg );
 262         $pkg{$_}->add_provided_by([split /\s+/, $virt{$_}]);
 263     }
 264
 265     while (my ($suite, $entry) = each %pkg) {
 266
 267         warn "\tsuite=$suite\n" if DEBUG;
 268         my %p = ( name => $pkg, providers => [], versions => '' );
 269         if (my $provided_by = $entry->{provided_by}) {
 270             $p{providers} = $provided_by;
 271         }
 272         $p{subsection} = $p{section} = $p{archive} =
 273             $p{desc} = $p{priority} = '';
 274         unless ($entry->is_virtual) {
 275             (undef, $p{versions}) = $entry->get_version_string;
 276             $p{subsection} = $entry->get_newest( 'subsection' );
 277             $p{section} = $entry->get_newest( 'section' );
 278             $p{archive} = $entry->get_newest( 'archive' );
 279             $p{desc} = $entry->get_newest( 'description' );
 280             my $desc_md5 = $entry->get_newest( 'description-md5' );
 281             my $trans_desc = $desctrans{$desc_md5};
 282             if ($trans_desc) {
 283                 my %sdescs;
 284                 my %trans_desc = split /\000|\001/, $trans_desc;
 285                 while (my ($l, $d) = each %trans_desc) {
 286                     # filter out non-po languages
 287                     next unless exists $lang_vars{$l};
 288
 289                     $d =~ s/\n.*//os;
 290                     $sdescs{$l} = $d;
 291                 }
 292                 $p{trans_desc} = \%sdescs if %sdescs;
 293             }
 294             $p{priority} = $entry->get_newest( 'priority' );
 295         }
 296
 297         my $html = my $txt = "";
 298         my $id = " id='$p{name}'";
 299         if ($p{versions}) {
 300             warn "\tversions=$p{versions}\n" if DEBUG;
 301
 302             $html .= "\n<dt><a href='$p{name}'$id>$p{name}</a> ($p{versions})";
 303             $id = "";
 304             $html .= " [<strong class='pmarker'>$p{section}</strong>]"
 305                 if $p{section} ne 'main';
 306             $html .= " [<strong class='pmarker'>$p{archive}</strong>]"
 307                 if $p{archive} ne 'us';
 308             $html .= "</dt>\n<dd";
 309
 310             $txt .= "\n$p{name} ($p{versions})";
 311             $txt .= " [$p{section}]" if $p{section} ne 'main';
 312             $txt .= " [$p{archive}]" if $p{archive} ne 'us';
 313             $txt .= " ";
 314
 315             if ($p{trans_desc}) {
 316                 foreach my $lang (@LANGUAGES) {
 317                     my ($sdesc, $sdesc_html, $desclang) = ($p{desc},
 318                                                            encode_entities($p{desc}, '<>&"\''),
 319                                                            'en');
 320                     if ($p{trans_desc}{$lang}) {
 321                         $sdesc = $p{trans_desc}{$lang};
 322                         $sdesc_html = encode_entities($sdesc, '<>&"\'');
 323                         $desclang = $lang;
 324                     }
 325
 326                     $html .= $s{begin}{$lang};
 327                     $html .= " lang='$desclang'" if $desclang ne $lang;
 328                     $html .= ">$sdesc_html$s{end}{$lang}";
 329                 }
 330             } else {
 331                 $html .= " lang='en'>".encode_entities($p{desc}, '<>&"\'');
 332             }
 333             $html .= "</dd>";
 334             $txt .= $p{desc};
 335         }
 336
 337         if (@{$p{providers}}) {
 338             warn "\tproviders=@{$p{providers}}\n" if DEBUG;
 339             $html .= "\n<dt><a href='$p{name}'$id>$p{name}</a></dt><dd>$prov_string ";
 340             my @prov;
 341             foreach my $prov (@{$p{providers}}) {
 342                 my $prov_uri = uri_escape($prov);
 343                 push @prov, "<a href='../$prov_uri'>$prov</a>";
 344             }
 345             $html .= join(', ', @prov)."</dd>";
 346             $txt .= "\n$p{name} virtual package provided by ".
 347                 join(', ', @{$p{providers}});
 348         }
 349         warn "HTML=$html\n" if DEBUG > 1;
 350         warn "TXT=$txt\n" if DEBUG > 1;
 351
 352         print {$fh{$suite}} $html;
 353         $fh{"$suite/en/txt"}->gzwrite($txt);
 354         foreach my $key (qw(section subsection priority)) {
 355             next unless $fh{"$suite/$p{$key}"};
 356             warn "\t\t$suite/$p{$key}\n" if DEBUG;
 357             print {$fh{"$suite/$p{$key}"}} $html;
 358         }
 359     }
 360 }
 361
 362 }
 363
 364 sub process_source_packages {
 365
 366 print "collecting source package info ...\n";
 367 my $count = 0;
 368 foreach my $pkg (@SRC_PACKAGES) {
 369     warn "pkg=$pkg\n" if DEBUG;
 370     print "$count\n" unless ++$count % 1000;
 371
 372     my %pkg;
 373     foreach (split /\000/o, $src_packages{$pkg}||'') {
 374         my @data = split ( /\s/o, $_ );
 375         $pkg{$data[1]} ||= new Packages::SrcPage( $pkg );
 376         $pkg{$data[1]}->merge_package( { package => $pkg,
 377                                          archive => $data[0],
 378                                          suite => $data[1],
 379                                          section => $data[2],
 380                                          subsection => $data[3],
 381                                          priority => $data[4],
 382                                          version => $data[5],
 383                                          } );
 384     }
 385
 386     while (my ($suite, $entry) = each %pkg) {
 387         my %p = ( name => $pkg, providers => [], versions => '' );
 388         $p{versions} = $entry->{version};
 389         $p{subsection} = $entry->get_newest( 'subsection' );
 390         $p{section} = $entry->get_newest( 'section' );
 391         $p{archive} = $entry->get_newest( 'archive' );
 392         $p{priority} = $entry->get_newest( 'priority' );
 393
 394         $p{desc} = '';
 395         $p{binaries} = [];
 396 #       my $binaries = find_binaries( $pkg, $p{archive}, $p{suite}, \%src2bin );
 397 #       if ($binaries && @$binaries) {
 398 #           pkg_list( \%packages, $opts, $binaries, 'en', $contents{binaries} );
 399 #       }
 400
 401         my $html = my $txt = "";
 402         warn "\tversions=$p{versions}\n" if DEBUG;
 403
 404         $html .= "\n<dt><a href='$p{name}' id='$p{name}'>$p{name}</a> ($p{versions})";
 405         $html .= " [<strong class='pmarker'>$p{section}</strong>]"
 406             if $p{section} ne 'main';
 407         $html .= " [<strong class='pmarker'>$p{archive}</strong>]"
 408             if $p{archive} ne 'us';
 409         $html .= "</dt>";
 410
 411         $txt .= "\n$p{name} ($p{versions})";
 412         $txt .= " [$p{section}]" if $p{section} ne 'main';
 413         $txt .= " [$p{archive}]" if $p{archive} ne 'us';
 414
 415         warn "HTML=$html\n" if DEBUG > 1;
 416         warn "TXT=$txt\n" if DEBUG > 1;
 417
 418         print {$fh{"source/$suite"}} $html;
 419         $fh{"source/$suite/en/txt"}->gzwrite($txt);
 420         foreach my $key (qw(section subsection priority)) {
 421             next unless $fh{"source/$suite/$p{$key}"};
 422             warn "\t\tsource/$suite/$p{$key}\n" if DEBUG;
 423             print {$fh{"source/$suite/$p{$key}"}} $html;
 424         }
 425     }
 426 }
 427
 428 }
 429
 430 __END__