lib/Packages/Dispatcher.pm

   1 #!/usr/bin/perl -T
   2 # Packages::Dispatcher -- CGI interface for packages.debian.org
   3 #
   4 # Copyright (C) 2004-2008 Frank Lichtenheld
   5 #
   6 #    This program is free software; you can redistribute it and/or modify
   7 #    it under the terms of the GNU General Public License as published by
   8 #    the Free Software Foundation; either version 1 of the License, or
   9 #    (at your option) any later version.
  10 #
  11 #    This program is distributed in the hope that it will be useful,
  12 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 #    GNU General Public License for more details.
  15 #
  16 #    You should have received a copy of the GNU General Public License
  17 #    along with this program; if not, write to the Free Software
  18 #    Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 package Packages::Dispatcher;
  21
  22 use strict;
  23 use warnings;
  24
  25 use CGI;
  26 use POSIX;
  27 use File::Basename;
  28 use Template;
  29 use DB_File;
  30 use URI::Escape;
  31 use Benchmark ':hireswallclock';
  32 use I18N::AcceptLanguage;
  33 use Date::Parse;
  34
  35 use Deb::Versions;
  36 use Packages::Config qw( $DBDIR $ROOT $TEMPLATEDIR $CACHEDIR
  37                          @SUITES @SECTIONS @ARCHIVES @ARCHITECTURES @PRIORITIES
  38                          @LANGUAGES @DDTP_LANGUAGES );
  39 use Packages::CGI qw( :DEFAULT error get_all_messages );
  40 use Packages::DB;
  41 use Packages::Search qw( :all );
  42 use Packages::Template ();
  43 use Packages::Sections;
  44 use Packages::I18N::Locale;
  45
  46 use Packages::DoSearch;
  47 use Packages::DoSearchContents;
  48 use Packages::DoShow;
  49 use Packages::DoIndex;
  50 use Packages::DoNewPkg;
  51 use Packages::DoDownload;
  52 use Packages::DoFilelist;
  53
  54
  55 sub do_dispatch {
  56
  57     &Packages::CGI::reset;
  58     $Packages::Search::too_many_hits = 0;
  59
  60     # clean up env
  61     $ENV{PATH} = "/bin:/usr/bin";
  62     delete $ENV{'LANGUAGE'};
  63     delete $ENV{'LANG'};
  64     delete $ENV{'LC_ALL'};
  65     delete $ENV{'LC_MESSAGES'};
  66
  67     my %SUITES_ALIAS = ( oldstable => 'sarge',
  68                          stable => 'etch',
  69                          testing => 'lenny',
  70                          unstable => 'sid',
  71                          '3.1' => 'sarge',
  72                          '4.0' => 'etch' );
  73
  74     # Read in all the variables set by the form
  75     my $input;
  76     if ($ARGV[0] && ($ARGV[0] eq 'php')) {
  77         $input = new CGI(\*STDIN);
  78     } else {
  79         $input = new CGI;
  80     }
  81     my $cgi_error = $input->cgi_error;
  82     if ($cgi_error) {
  83         fatal_error( "Error parsing the request", $cgi_error );
  84     }
  85
  86     my $pet0 = new Benchmark;
  87     my $tet0 = new Benchmark;
  88     my $debug = DEBUG && $input->param("debug");
  89     $debug = 0 if !defined($debug) || $debug !~ /^\d+$/o;
  90     $Packages::CGI::debug = $debug;
  91
  92     my $homedir = dirname($ENV{SCRIPT_FILENAME}).'/../';
  93     &Packages::Config::init( $homedir );
  94     &Packages::DB::init();
  95     my $last_modified = $Packages::DB::db_read_time;
  96     my $now = time;
  97     # allow some fudge, since the db mod time is not the end of
  98     # the cron job
  99     $last_modified = $now if $last_modified - $now < 3600;
 100
 101     if ($input->http('If-Modified-Since') and
 102         (my $modtime = str2time($input->http('If-Modified-Since'), 'UTC'))) {
 103         if ($modtime <= $last_modified) {
 104             print $input->header(-status => 304);
 105             exit;
 106         }
 107     }
 108
 109     my %PO_LANGUAGES = map { $_ => 1 } @LANGUAGES;
 110     my %DDTP_LANGUAGES = map { $_ => 1 } @DDTP_LANGUAGES;
 111     my $acc = I18N::AcceptLanguage->new(defaultLanguage => 'en');
 112     my $ddtp_lang = $acc->accepts( $input->http("Accept-Language"),
 113                                    \@DDTP_LANGUAGES );
 114     my $po_lang = $acc->accepts( $input->http("Accept-Language"),
 115                                  \@LANGUAGES );
 116     debug( "LANGS=@LANGUAGES DDTP_LANGS=@DDTP_LANGUAGES header=".
 117            ($input->http("Accept-Language")||'').
 118            " po_lang=$po_lang ddtp_lang=$ddtp_lang", 1 ) if DEBUG;
 119
 120     # backwards compatibility stuff
 121     debug( "SCRIPT_URL=$ENV{SCRIPT_URL} SCRIPT_URI=$ENV{SCRIPT_URI}" ) if DEBUG;
 122
 123     if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_|) {
 124         error( "You reached this site over an old URL. ".
 125                "Depending on the exact parameters your search might work or not." );
 126         # contents search changed a lot
 127         if ($ENV{SCRIPT_URL} =~ m|^/cgi-bin/search_contents|) {
 128             $input->param('keywords',$input->param('word')) if $input->param('word');
 129             $input->param('searchon','contents');
 130             for ($input->param('searchmode')) {
 131                 /^searchfiles/ && do {
 132                     $input->param('mode','filename');
 133                     last;
 134                 };
 135                 /^filelist/ && do {
 136                     $ENV{PATH_INFO} = '/'.join('/',($input->param('version')||'stable',
 137                                                     $input->param('keywords'),
 138                                                     $input->param('arch')||'i386',
 139                                                     'filelist' ));
 140                     $input->delete('searchon','version','keywords','arch');
 141                     last;
 142                 };
 143             }
 144         }
 145     }
 146     if ($ENV{is_reportbug}) {
 147         $input->param('exact', 1);
 148         debug( "reportbug detected, set paramater exact to '1'" ) if DEBUG;
 149     }
 150
 151     my $what_to_do = 'show';
 152     my $source = 0;
 153     if (my $path = $ENV{'PATH_INFO'} || $input->param('PATH_INFO')) {
 154         my @components = grep { $_ } map { lc $_ } split /\/+/, $path;
 155
 156         debug( "PATH_INFO=$path components=@components", 3) if DEBUG;
 157
 158         push @components, 'index' if @components && $path =~ m,/$,;
 159
 160         my %LANGUAGES = map { $_ => 1 } (@LANGUAGES, @DDTP_LANGUAGES);
 161         if (@components > 1 and $LANGUAGES{$components[0]}
 162             and !$input->param('lang')) {
 163             $input->param( 'lang', shift(@components) );
 164         }
 165         if (@components > 1 and $components[0] eq 'source') {
 166             shift @components;
 167             $input->param( 'source', 1 );
 168         }
 169         if (@components > 0 and $components[0] eq 'search') {
 170             shift @components;
 171             $what_to_do = 'search';
 172             # Done
 173             fatal_error( "search doesn't take any more path elements" )
 174                 if @components;
 175         } elsif (@components == 0) {
 176             fatal_error( "We're supposed to display the homepage here, instead of getting dispatch.pl" );
 177         } elsif (@components == 1) {
 178             $what_to_do = 'search';
 179         } else {
 180
 181             for ($components[-1]) {
 182                 /^(index|allpackages|newpkg|changelog|copyright|download|filelist)$/ && do {
 183                     pop @components;
 184                     $what_to_do = $1;
 185                     last;
 186                 };
 187             }
 188
 189             my %SUITES = map { $_ => 1 } @SUITES;
 190             my %SECTIONS = map { $_ => 1 } @SECTIONS;
 191             my %ARCHIVES = map { $_ => 1 } @ARCHIVES;
 192             my %ARCHITECTURES = map { $_ => 1 } (@ARCHITECTURES, 'all', 'any');
 193             my %PRIORITIES = map { $_ => 1 } @PRIORITIES;
 194             my %params_set;
 195             sub set_param_once {
 196                 my ($cgi, $params_set, $key, $val) = @_;
 197                 debug("set_param_once key=$key val=$val",4) if DEBUG;
 198                 if ($params_set->{$key}++) {
 199                     fatal_error( "$key set more than once in path" );
 200                 } else {
 201                     $cgi->param( $key, $val );
 202                 }
 203             }
 204
 205             my (@pkg, $need_pkg);
 206             foreach (reverse @components) {
 207                 $need_pkg = !@pkg
 208                     && ($what_to_do !~ /^(index|allpackages|newpkg)$/);
 209                 debug("need_pkg=$need_pkg component=$_",4) if DEBUG;
 210                 if (!$need_pkg && $SUITES{$_}) {
 211                     set_param_once( $input, \%params_set, 'suite', $_);
 212                 } elsif (!$need_pkg && (my $s = $SUITES_ALIAS{$_})) {
 213                     set_param_once( $input, \%params_set, 'suite', $s);
 214                 } elsif (!$need_pkg && $SECTIONS{$_}) {
 215                     set_param_once( $input, \%params_set, 'section', $_);
 216                 } elsif (!$need_pkg && $sections_descs{$_}) {
 217                     set_param_once( $input, \%params_set, 'subsection', $_);
 218                 } elsif (!$need_pkg && ($_ eq 'source')) {
 219                     set_param_once( $input, \%params_set, 'source', 1);
 220                 } elsif ($ARCHITECTURES{$_}) {
 221                     set_param_once( $input, \%params_set, 'arch', $_)
 222                         unless $_ eq 'any';
 223                 } elsif (!$need_pkg && $ARCHIVES{$_}) {
 224                     set_param_once( $input, \%params_set, 'archive', $_);
 225                 } elsif ($PRIORITIES{$_}) {
 226                     set_param_once( $input, \%params_set, 'priority', $_);
 227                 } else {
 228                     push @pkg, $_;
 229                 }
 230             }
 231             @components = @pkg;
 232
 233             if (@components > 1) {
 234                 fatal_error( "two or more packages specified (@components)" );
 235             }
 236         } # else if (@components == 1)
 237
 238         if (@components) {
 239             my $c = uri_unescape($components[0]);
 240             $input->param( 'keywords', $c );
 241             $input->param( 'package', $c );
 242         }
 243     }
 244
 245     my ( $pkg, @suites, @sections, @subsections, @archives, @archs );
 246
 247     my %params_def = ( keywords => { default => undef,
 248                                      array => '\s+',
 249                                      match => '^([-+\@\w\/.:]+)$',
 250                                  },
 251                        'package' => { default => undef,
 252                                       match => '^([\w.+-]+)$',
 253                                       var => \$pkg },
 254                        suite => { default => 'default', match => '^([\w-]+)$',
 255                                   array => ',', var => \@suites,
 256                                   replace => { all => \@SUITES,
 257                                                default => \@SUITES,
 258                                                %SUITES_ALIAS } },
 259                        archive => { default => ($what_to_do eq 'search') ?
 260                                         'all' : 'default',
 261                                         match => '^([\w-]+)$',
 262                                         array => ',', var => \@archives,
 263                                         replace => { all => \@ARCHIVES,
 264                                                      default => \@ARCHIVES} },
 265                        exact => { default => 0, match => '^(\w+)$',  },
 266                        lang => { default => undef, match => '^([\w-]+)$',  },
 267                        source => { default => 0, match => '^(\d+)$',  },
 268                        debug => { default => 0, match => '^(\d+)$',  },
 269                        searchon => { default => 'names', match => '^(\w+)$', },
 270                        section => { default => 'all', match => '^([\w-]+)$',
 271                                     alias => 'release', array => ',',
 272                                     var => \@sections,
 273                                     replace => { all => \@SECTIONS } },
 274                        subsection => { default => 'default', match => '^([\w-]+)$',
 275                                        array => ',', var => \@subsections,
 276                                        replace => { default => [] } },
 277                        priority => { default => 'default', match => '^([\w-]+)$',
 278                                      array => ',',
 279                                      replace => { default => [] } },
 280                        arch => { default => 'any', match => '^([\w-]+)$',
 281                                  array => ',', var => \@archs, replace =>
 282                                  { any => \@ARCHITECTURES } },
 283                        'format' => { default => 'html', match => '^([\w.]+)$',  },
 284                        mode => { default => '', match => '^(\w+)$',  },
 285                        sort_by => { default => 'file', match => '^(\w+)$', },
 286                        );
 287     my %opts;
 288     my %params = Packages::CGI::parse_params( $input, \%params_def, \%opts );
 289     Packages::CGI::init_url( $input, \%params, \%opts );
 290
 291     if (defined($opts{lang})) {
 292         $opts{po_lang} = $PO_LANGUAGES{$opts{lang}} ? $opts{lang} : 'en';
 293         $opts{ddtp_lang} = $DDTP_LANGUAGES{$opts{lang}} ? $opts{lang} : 'en';
 294     } else {
 295         $opts{po_lang} = $po_lang;
 296         $opts{ddtp_lang} = $ddtp_lang;
 297     }
 298     my $charset = "UTF-8";
 299     my $cat = Packages::I18N::Locale->get_handle( $opts{po_lang}, 'en' )
 300         or die "get_handle failed for $opts{po_lang}";
 301     $opts{cat} = $cat;
 302
 303     $opts{h_suites} = { map { $_ => 1 } @suites };
 304     $opts{h_sections} = { map { $_ => 1 } @sections };
 305     $opts{h_archives} = { map { $_ => 1 } @archives };
 306     $opts{h_archs} = { map { $_ => 1 } @archs };
 307
 308     if ((($opts{searchon} eq 'names') && $opts{source}) ||
 309         ($opts{searchon} eq 'sourcenames')) {
 310         $opts{source} = 1;
 311         $opts{searchon} = 'names',
 312         $opts{searchon_form} = 'sourcenames';
 313     } else {
 314         $opts{searchon_form} = $opts{searchon};
 315     }
 316     if ($opts{searchon} eq 'contents' or $opts{searchon} eq 'filenames') {
 317         $what_to_do = 'search_contents';
 318     }
 319
 320     my $pet1 = new Benchmark;
 321     my $petd = timediff($pet1, $pet0);
 322     debug( "Parameter evaluation took ".timestr($petd) ) if DEBUG;
 323
 324     my $template = new Packages::Template( $TEMPLATEDIR, $opts{format},
 325                                            { po_lang => $opts{po_lang}, ddtp_lang => $opts{ddtp_lang},
 326                                              charset => $charset, cat => $cat,
 327                                              debug => ( DEBUG ? $opts{debug} : 0 ) },
 328                                            ( $CACHEDIR ? { COMPILE_DIR => $CACHEDIR } : {} ) );
 329
 330     #FIXME: ugly hack
 331     unless (($what_to_do eq 'allpackages' and $opts{format} =~ /^(html|txt\.gz)/)
 332             || ($what_to_do eq 'index' and $opts{format} eq 'html')
 333             || -e "$TEMPLATEDIR/$opts{format}/${what_to_do}.tmpl") {
 334         fatal_error( $cat->g("requested format not available for this document"),
 335                      "406 requested format not available");
 336     }
 337
 338     my (%page_content);
 339     unless (@Packages::CGI::fatal_errors) {
 340         no strict 'refs';
 341         &{"do_$what_to_do"}( \%params, \%opts, \%page_content );
 342     }
 343
 344     $page_content{opts} = \%opts;
 345     $page_content{params} = \%params;
 346
 347     unless (@Packages::CGI::fatal_errors) {
 348         print $input->header(-charset => $charset,
 349                              -type => get_mime($opts{format}),
 350                              -vary => 'negotiate,accept-language',
 351                              -last_modified => strftime("%a, %d %b %Y %T %z",
 352                                                         localtime($last_modified)),
 353                              );
 354         #use Data::Dumper;
 355         #print '<pre>'.Dumper(\%ENV, \%page_content, get_all_messages()).'</pre>';
 356         print $template->page( $what_to_do, { %page_content, %{ get_all_messages() } } );
 357     } elsif ($Packages::CGI::http_code && $Packages::CGI::http_code !~ /^2\d\d/) {
 358         print $input->header( -charset => $charset, -status => $Packages::CGI::http_code );
 359     } else {
 360         # We currently have only an error page in html
 361         # so no format support here
 362         print $input->header( -charset => $charset );
 363         print $template->error_page( get_all_messages() );
 364     }
 365 }
 366
 367 1;
 368 # vim: ts=8 sw=4