bin/parse-packages

   1 #!/usr/bin/perl -w
   2 # Convert Packages.gz files into Sleepycat db files for efficient usage of
   3 # data
   4 #
   5 # Copyright (C) 2006  Jeroen van Wolffelaar <jeroen@wolffelaar.nl>
   6 # Copyright (C) 2006-2007 Frank Lichtenheld <frank@lichtenheld.de>
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or
  11 # (at your option) any later version.
  12
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  21
  22 use strict;
  23 use warnings;
  24 use lib './lib';
  25
  26 $| = 1;
  27
  28 my $what = $ARGV[0] ? "non-free" : "*";
  29 # max. distinct results for a given package postfix
  30 my $MAX_PACKAGE_POSTFIXES = 100;
  31
  32 use DB_File;
  33 use Storable;
  34 use File::Path;
  35 use Digest::MD5;
  36 use Deb::Versions;
  37 use Lingua::Stem v0.82;
  38 use Search::Xapian;
  39 use Packages::Config qw( $TOPDIR $DBDIR @ARCHIVES @SUITES );
  40 &Packages::Config::init( './' );
  41 my %packages_small = ();
  42 my %virtual_packages = ();
  43 my %package_names = ();
  44 my %package_postfixes = ();
  45 my %sources_packages = ();
  46 my %descriptions = ();
  47 my @descriptions = ("we count lines one-based\000");
  48 my %packages_descriptions = ();
  49 my %descriptions_packages = ();
  50
  51 my %sections = ();
  52 my %subsections = ();
  53 my %priorities = ();
  54
  55 $/ = "";
  56
  57 -d $DBDIR || mkpath( $DBDIR );
  58 -d "$DBDIR/xapian.new" && rmtree("$DBDIR/xapian.new");
  59 -d "$DBDIR/xapian.old" && rmtree("$DBDIR/xapian.old");
  60 mkpath( "$DBDIR/xapian.new" );
  61
  62 for my $suite (@SUITES) {
  63     my %package_names_suite = ();
  64     my %packages_all_db;
  65     tie %packages_all_db, "DB_File", "$DBDIR/packages_all_$suite.db.new",
  66             O_RDWR|O_CREAT, 0666, $DB_BTREE
  67             or die "Error creating DB: $!";
  68
  69     for my $archive (@ARCHIVES) {
  70         print "Reading $archive/$suite...\n";
  71         my $suite_dir = "$TOPDIR/archive/$archive/$suite";
  72         if (!-d $suite_dir) {
  73                 print "\tseems not to exist, skipping...\n";
  74                 next;
  75         }
  76         open PKG, "zcat $suite_dir/$what/binary-*/Packages.gz $suite_dir/$what/debian-installer/binary-*/Packages.gz|";
  77         while (<PKG>) {
  78                 next if /^\s*$/;
  79                 my $data = "";
  80                 my %data = ();
  81                 chomp;
  82                 s/\n /\377/g;
  83                 while (/^(\S+):\s*(.*)\s*$/mg) {
  84                         my ($key, $value) = ($1, $2);
  85                         $value =~ s/\377/\n /g;
  86                         $key =~ tr [A-Z] [a-z];
  87                         $data{$key} = $value;
  88                 }
  89                 # Skip double package
  90                 next if exists($packages_all_db{"$data{'package'} $data{'architecture'} $data{'version'}"});
  91                 # Skip arch:all for amd64 & debports, any non-redundancy is
  92                 # usually a bug anyway
  93                 next if ($archive eq 'amd64' or $archive eq 'debports')
  94                     and $data{architecture} eq 'all';
  95
  96                 if ($data{'provides'}) {
  97                     foreach (split /\s*,\s*/, $data{'provides'}) {
  98                         $virtual_packages{$_}{$suite}{$data{'package'}}++;
  99                         $packages_small{$_} ||= {};
 100                     }
 101                 }
 102                 $package_names{$data{'package'}} = 1;
 103                 $package_names_suite{$data{'package'}} = 1;
 104                 my $src = $data{'package'};
 105                 my $src_version = '';
 106                 if ($data{'source'}) {
 107                         $src = $data{'source'};
 108                         $src =~ s/\s+.*//o; # strip version info
 109                 }
 110                 $data{'source'} = $src;
 111
 112                 # expand tags like devel::{lang:c,lang:c++}
 113                 if ($data{'tag'} && $data{'tag'} =~ /\{/) {
 114                     my @complete_tags = split(/, /, $data{'tag'});
 115                     my @tags;
 116                     foreach (@complete_tags) {
 117                         my ($facet, $tag) = split( /::/, $_, 2);
 118                         if ($tag =~ s/^\{(.+)\}$/$1/) {
 119                             foreach (split( /,/, $tag )) {
 120                                 push @tags, "${facet}::$_";
 121                             }
 122                         } else {
 123                             push @tags, "${facet}::$tag";
 124                         }
 125                     }
 126                     my $old = $data{tag};
 127                     $data{'tag'} = join ", ", @tags;
 128                 }
 129
 130                 # we add some additional data here
 131                 my $descr = "$data{'description'}\000$data{'package'}\000"
 132                     .($data{'tag'}||'');
 133                 my $sdescr = $data{'description'};
 134                 $sdescr =~ s/\n.*//os;
 135                 my $did = undef;
 136                 if (exists($descriptions{$descr})) {
 137                         $did  = $descriptions{$descr};
 138                 } else {
 139                         $did = 1 + $#descriptions;
 140                         $descriptions[$did] = $descr;
 141                         $descriptions{$descr} = $did;
 142                 }
 143                 $data{'description-md5'} = Digest::MD5::md5_hex($data{'description'}, "\n");
 144                 $data{'description'} = $did;
 145                 $packages_descriptions{"$data{'package'} $data{'version'} $data{'architecture'}"} = $did;
 146                 $descriptions_packages{$did} .=
 147                         "$data{'package'} $data{'version'} $data{'architecture'}\000";
 148
 149                 my $section = 'main';
 150                 my $subsection = $data{section} || '-';
 151                 if ($data{section} && ($data{section} =~ m=/=o)) {
 152                     ($section, $subsection) = split m=/=o, $data{section}, 2;
 153                 }
 154                 $data{'section'} = $section;
 155                 $data{'subsection'} = $subsection;
 156                 $data{'priority'} ||= '-';
 157                 $sections{$suite}{$section}++;
 158                 $subsections{$suite}{$subsection}++;
 159                 $priorities{$suite}{$data{priority}}++;
 160                 my $pkgitem = "$archive $suite $data{'architecture'} ".
 161                         "$section $subsection $data{'priority'} $data{'version'} $data{'description-md5'} $sdescr\0";
 162                 my $previtem = ($packages_small{$data{'package'}}{$suite}{$data{'architecture'}}
 163                     ||= $pkgitem);
 164                 $packages_small{$data{'package'}}{$suite}{$data{'architecture'}} = $pkgitem
 165                     if version_cmp($data{'version'}, (split /\s/o, $previtem)[6]) > 0;
 166                 $previtem = ($packages_small{$data{'package'}}{$suite}{'any'}
 167                     ||= $pkgitem);
 168                 $packages_small{$data{'package'}}{$suite}{'any'} = $pkgitem
 169                     if version_cmp($data{'version'}, (split /\s/o, $previtem)[6]) > 0;
 170                 $sources_packages{$src} .=
 171                         "$archive $suite $data{'package'} $data{'version'} $data{'architecture'}\000";
 172                 $data{archive} = $archive;
 173                 while (my ($key, $value) = each (%data)) {
 174                         next if $key eq 'package' or $key eq 'version' or $key eq 'architecture'
 175                                 or $key eq 'maintainer';
 176                         print STDERR "WARN: $key ($suite/$archive/$data{package}/$data{architecture}\n" unless defined $value;
 177                         $data .= "$key\00$value\00";
 178                 }
 179                 $data =~ s/.$//s;
 180                 $packages_all_db{"$data{'package'} $data{'architecture'} $data{'version'}"}
 181                         = $data;
 182         }
 183     }
 184
 185     open NAMES, '>', "$DBDIR/package_names_$suite.txt.new"
 186         or die "Error creating package names list: $!";
 187     foreach (sort keys %package_names_suite) {
 188         print NAMES "$_\n";
 189     }
 190     close NAMES;
 191
 192     untie %packages_all_db;
 193 }
 194
 195 print "Writing databases...\n";
 196 my %packages_small_db;
 197 tie %packages_small_db, "DB_File", "$DBDIR/packages_small.db.new",
 198         O_RDWR|O_CREAT, 0666, $DB_BTREE
 199         or die "Error creating DB: $!";
 200 while (my ($pkg, $v) = each(%packages_small)) {
 201         my ($res1, $res2, $res3) = ("", "", "");
 202         while (my ($suite, $v2) = each %$v) {
 203             $res2 .= $v2->{'any'};
 204             while (my ($arch, $v3) = each %$v2) {
 205                 next if $arch eq 'any' or $v3 eq $v2->{'any'};
 206                 $res3 .= $v3;
 207             }
 208         }
 209
 210         if (exists $virtual_packages{$pkg}) {
 211                 while (my ($suite, $v2) = each %{$virtual_packages{$pkg}}) {
 212                         $res1 .= "$suite\01".(join ' ', keys %$v2)."\01";
 213                 }
 214         } else {
 215                 $res1 .= "-\01-\01";
 216         }
 217         $res1 =~ s/.$/\0/s;
 218
 219         my $res = "$res1$res2$res3";
 220         $res =~ s/.$//s;
 221         $packages_small_db{$pkg} = $res;
 222 }
 223 untie %packages_small_db;
 224
 225 my %sources_packages_db;
 226 tie %sources_packages_db, "DB_File", "$DBDIR/sources_packages.db.new",
 227         O_RDWR|O_CREAT, 0666, $DB_BTREE
 228         or die "Error creating DB: $!";
 229 while (my ($k, $v) = each(%sources_packages)) {
 230         $v =~ s/.$//s;
 231         $sources_packages_db{$k} = $v;
 232 }
 233 untie %sources_packages_db;
 234
 235 my %packages_descriptions_db;
 236 tie %packages_descriptions_db, "DB_File", "$DBDIR/packages_descriptions.db.new",
 237         O_RDWR|O_CREAT, 0666, $DB_BTREE
 238         or die "Error creating DB: $!";
 239 while (my ($k, $v) = each(%packages_descriptions)) {
 240         $packages_descriptions_db{$k} = $v;
 241 }
 242 untie %packages_descriptions_db;
 243
 244 my %descriptions_packages_db;
 245 tie %descriptions_packages_db, "DB_File", "$DBDIR/descriptions_packages.db.new",
 246         O_RDWR|O_CREAT, 0666, $DB_BTREE
 247         or die "Error creating DB: $!";
 248 while (my ($k, $v) = each(%descriptions_packages)) {
 249         $v =~ s/.$//s;
 250         $descriptions_packages_db{$k} = $v;
 251 }
 252 untie %descriptions_packages_db;
 253
 254 my $stemmer = Lingua::Stem->new();
 255 $stemmer->stem_caching({ -level => 2 });
 256 my $xapian_db;
 257 eval {
 258     $xapian_db = Search::Xapian::WritableDatabase->new("$DBDIR/xapian.new",
 259                                                        Search::Xapian::DB_CREATE_OR_OPEN)
 260         or die "can't create write-able db object: $!\n";
 261 };
 262 die $@ if $@;
 263 my %descriptions_db;
 264 tie %descriptions_db, "DB_File", "$DBDIR/descriptions.db.new",
 265         O_RDWR|O_CREAT, 0666, $DB_BTREE
 266         or die "Error creating DB: $!";
 267 print "Index $#descriptions descriptions\n";
 268 for (my $i=1; $i<= $#descriptions; $i++) {
 269         # strip away additional data
 270         my ($only_desc, $pkg, $tags) = split /\000/o, $descriptions[$i], 3;
 271         my $orig_desc = $only_desc;
 272 # WARNING: This needs to correspond with what happens in
 273 # Packages/Search.pm:do_xapian_search
 274         $only_desc =~ s#[^\w/+]+# #og;
 275
 276         #XAPIAN
 277         eval {
 278             my @words = split /\s+/, $only_desc;
 279             unshift @words, $pkg;
 280
 281             my $doc = Search::Xapian::Document->new()
 282                 or die "can't create doc object for $i: $!\n";
 283             if ($doc->set_data($i)){
 284                 warn "can't set_data in doc object for $i: $!\n";
 285             }
 286
 287             # package with prefix
 288             if ($doc->add_term("P$pkg")) {
 289                 warn "can't add term P$pkg: $!\n";
 290             }
 291             # description, unstemmed with positional info
 292             for my $j (0 .. (@words-1)) {
 293                 next if $words[$j] =~ /^\s*$/o;
 294                 if ($doc->add_posting($words[$j], $j)) {
 295                     warn "can't add posting $words[$j] at $j: $!\n";
 296                 }
 297             }
 298             # description, stemmed
 299             my $stem_words = $stemmer->stem( \@words );
 300             foreach my $w (@$stem_words) {
 301                 next if $w =~ /^\s*$/o;
 302                 if ($doc->add_term($w)) {
 303                     warn "can't add term $w: $!\n";
 304                 }
 305             }
 306             if ($tags) {
 307                 foreach my $t (split m/, /, $tags) {
 308                     if ($doc->add_term($t)) {
 309                         warn "can't add term $t: $!\n";
 310                     }
 311                 }
 312             }
 313
 314             $xapian_db->add_document($doc)
 315                 or warn "failed to add document: $i\n";
 316         };
 317         die $@ if $@;
 318
 319         $descriptions_db{$i} = $orig_desc;
 320 }
 321 untie %descriptions_db;
 322 $xapian_db->flush;
 323 undef $xapian_db;
 324
 325 # package names stuff:
 326 for my $pkg (keys %package_names) {
 327         for (my $i=0;$i<length($pkg)-1;$i++) {
 328                 my $before = substr($pkg, 0, $i);
 329                 my $after = substr($pkg, $i);
 330                 $before = "^" if $before eq ""; # otherwise split doesn't work properly
 331                 $package_postfixes{$after} .= "$before\0";
 332         }
 333 }
 334 my %package_postfixes_db;
 335 tie %package_postfixes_db, "DB_File", "$DBDIR/package_postfixes.db.new",
 336         O_RDWR|O_CREAT, 0666, $DB_BTREE
 337         or die "Error creating DB: $!";
 338 while (my ($k, $v) = each(%package_postfixes)) {
 339         $v =~ s/.$//s;
 340         my $nr = ($v =~ tr/\000/\000/) + 1;
 341         if ($nr > $MAX_PACKAGE_POSTFIXES) {
 342             $v = ($v =~ /\^/) ? "^\001" . $nr
 343                 : "\001" . $nr;
 344         }
 345         $package_postfixes_db{$k} = $v;
 346 }
 347 untie %package_postfixes_db;
 348
 349 store \%sections, "$DBDIR/sections.info";
 350 store \%subsections, "$DBDIR/subsections.info";
 351 store \%priorities, "$DBDIR/priorities.info";
 352
 353 rename("$DBDIR/packages_small.db.new", "$DBDIR/packages_small.db");
 354 rename("$DBDIR/sources_packages.db.new", "$DBDIR/sources_packages.db");
 355 for my $suite (@SUITES) {
 356         rename("$DBDIR/packages_all_$suite.db.new",
 357                "$DBDIR/packages_all_$suite.db");
 358         rename("$DBDIR/package_names_$suite.txt.new",
 359                "$DBDIR/package_names_$suite.txt");
 360 }
 361 rename("$DBDIR/xapian", "$DBDIR/xapian.old");
 362 rename("$DBDIR/xapian.new","$DBDIR/xapian");
 363 rmtree("$DBDIR/xapian.old");
 364 rename("$DBDIR/packages_descriptions.db.new",
 365        "$DBDIR/packages_descriptions.db");
 366 rename("$DBDIR/descriptions_packages.db.new",
 367        "$DBDIR/descriptions_packages.db");
 368 rename("$DBDIR/descriptions.db.new", "$DBDIR/descriptions.db");
 369 rename("$DBDIR/package_postfixes.db.new", "$DBDIR/package_postfixes.db");